e51d637ac96aaa723ea3d82f656e8dbac8dab231
[charm.git] / src / langs / charj / src / charj / translator / CharjSemantics.g
1 /**
2  * The semantic phase walks the tree and builds the symbol table, handles
3  * all the imports, and does the semantic checks. The resulting tree and
4  * symbol table are used by the emitter to generate the output. 
5  */
6
7 tree grammar CharjSemantics;
8
9 options {
10     backtrack = true; 
11     memoize = true;
12     tokenVocab = Charj;
13     ASTLabelType = CharjAST;
14 }
15
16 scope ScopeStack {
17     Scope current;
18 }
19
20 @header {
21 package charj.translator;
22 }
23
24 @members {
25     SymbolTable symtab = null;
26     PackageScope currentPackage = null;
27     ClassSymbol currentClass = null;
28     MethodSymbol currentMethod = null;
29     LocalScope currentLocalScope = null;
30     Translator translator;
31
32     /**
33      *  Test a list of CharjAST nodes to see if any of them has the given token
34      *  type.
35      */
36     public boolean listContainsToken(List<CharjAST> list, int tokenType) {
37         if (list == null) return false;
38         for (CharjAST node : list) {
39             if (node.token.getType() == tokenType) {
40                 return true;
41             }
42         }
43         return false;
44     }
45
46     public void importPackages(ClassSymbol cs, List<CharjAST> imports) {
47         if (imports == null) {
48             return;
49         }
50
51         for (CharjAST pkg : imports) {
52             String pkgName = input.getTokenStream().toString(
53                     pkg.getTokenStartIndex(),
54                     pkg.getTokenStopIndex());
55             // find imported class and add to cs.imports
56             PackageScope p = cs.importPackage(pkgName);
57             if (p == null) {
58                 translator.error(
59                     this, 
60                     "package " + pkgName + " not found.",
61                     pkg);
62             }
63         }
64     }
65 }
66
67
68 // Replace default ANTLR generated catch clauses with this action, allowing early failure.
69 @rulecatch {
70     catch (RecognitionException re) {
71         reportError(re);
72         throw re;
73     }
74 }
75
76
77 // Starting point for parsing a Charj file.
78 charjSource[SymbolTable _symtab] returns [ClassSymbol cs]
79 scope ScopeStack; // default scope
80 @init {
81     symtab = _symtab;
82     $ScopeStack::current = symtab.getDefaultPkg();
83 }
84     // TODO: go back to allowing multiple type definitions per file, check that
85     // there is exactly one public type and return that one.
86     :   ^(CHARJ_SOURCE 
87         (packageDeclaration)? 
88         (importDeclarations) 
89         (typeDeclaration[$importDeclarations.packageNames]))
90         { $cs = $typeDeclaration.sym; }
91     ;
92
93 // note: no new scope here--this replaces the default scope
94 packageDeclaration
95 @init { 
96     List<String> names = null; 
97 }
98     :   ^(PACKAGE (ids+=IDENT)+)  
99         {
100             String packageName = "";
101             for(Object o : $ids) packageName += '.' + ((CharjAST)o).getText();
102             packageName = packageName.substring(1);
103             PackageScope ps = symtab.resolvePackage(packageName);
104             if (ps == null) {
105                 ps = symtab.definePackage(packageName);
106                 symtab.addScope(ps);
107             }
108             currentPackage = ps;
109             $ScopeStack::current = ps;
110 //            $qualifiedIdentifier.start.symbol = ps; ----- commented out while dealing with the namespaces issue (Minas)
111         }
112     ;
113     
114 importDeclarations returns [List<CharjAST> packageNames]
115 @init {
116     packageNames = new ArrayList<CharjAST>();
117 }
118     :   (^(IMPORT qualifiedIdentifier '.*'?)
119                 { packageNames.add($qualifiedIdentifier.start); })*
120     ;
121
122
123 typeDeclaration[List<CharjAST> imports] returns [ClassSymbol sym]
124 scope ScopeStack; // top-level type scope
125     :   ^(TYPE (CLASS | chareType) IDENT
126             (^('extends' parent=type))? (^('implements' type+))?
127             {
128                 Scope outerScope = $ScopeStack[-1]::current;
129                 $sym = new ClassSymbol(symtab, $IDENT.text, outerScope.resolveType($parent.text), outerScope);
130                 outerScope.define($sym.name, $sym);
131                 currentClass = $sym;
132                 $sym.definition = $typeDeclaration.start;
133                 $sym.definitionTokenStream = input.getTokenStream();
134                 $IDENT.symbol = $sym;
135                 $ScopeStack::current = $sym;
136                 importPackages($sym, $imports);
137             }
138             classScopeDeclaration*)
139             {
140                 //System.out.println("Members for type " + $sym.name + ":");
141                 //for (Map.Entry<String, Symbol> entry : $sym.members.entrySet()) {
142                 //    System.out.println(entry.getKey());
143                 //}
144             }
145     |   ^('interface' IDENT (^('extends' type+))?  interfaceScopeDeclaration*)
146     |   ^('enum' IDENT (^('implements' type+))? enumConstant+ classScopeDeclaration*)
147     ;
148
149 chareType
150     :   CHARE
151     |   GROUP
152     |   NODEGROUP
153     |   MAINCHARE
154     |   ^(CHARE_ARRAY ARRAY_DIMENSION)
155     ;
156
157 enumConstant
158     :   ^(IDENT arguments?)
159     ;
160     
161 classScopeDeclaration
162 scope ScopeStack;
163     :   ^(FUNCTION_METHOD_DECL m=modifierList? g=genericTypeParameterList? 
164             ty=type IDENT f=formalParameterList a=arrayDeclaratorList? 
165             b=block?)
166         {
167             ClassSymbol returnType = currentClass.resolveType($ty.text);
168             MethodSymbol sym = new MethodSymbol(symtab, $IDENT.text, currentClass, returnType);
169             currentMethod = sym;
170             sym.definition = $classScopeDeclaration.start;
171             sym.definitionTokenStream = input.getTokenStream();
172             currentClass.define($IDENT.text, sym);
173             $FUNCTION_METHOD_DECL.symbol = sym;
174         }
175     |   ^(PRIMITIVE_VAR_DECLARATION modifierList? simpleType variableDeclaratorList)
176     |   ^(OBJECT_VAR_DECLARATION modifierList? objectType variableDeclaratorList)
177     |   ^(CONSTRUCTOR_DECL m=modifierList? g=genericTypeParameterList? IDENT f=formalParameterList 
178             b=block)
179     ;
180     
181 interfaceScopeDeclaration
182     :   ^(FUNCTION_METHOD_DECL modifierList? genericTypeParameterList? 
183             type IDENT formalParameterList arrayDeclaratorList?)
184         // Interface constant declarations have been switched to variable
185         // declarations by Charj.g; the parser has already checked that
186         // there's an obligatory initializer.
187     |   ^(PRIMITIVE_VAR_DECLARATION modifierList? simpleType variableDeclaratorList)
188     |   ^(OBJECT_VAR_DECLARATION modifierList? objectType variableDeclaratorList)
189     ;
190
191 variableDeclaratorList
192     :   ^(VAR_DECLARATOR_LIST variableDeclarator+)
193     ;
194
195 variableDeclarator
196     :   ^(VAR_DECLARATOR variableDeclaratorId variableInitializer?)
197     ;
198     
199 variableDeclaratorId
200     :   ^(IDENT arrayDeclaratorList?)
201     ;
202
203 variableInitializer
204     :   arrayInitializer
205     |   expression
206     ;
207
208 arrayDeclaratorList
209     :   ^(ARRAY_DECLARATOR_LIST ARRAY_DECLARATOR*)  
210     ;
211     
212 arrayInitializer
213     :   ^(ARRAY_INITIALIZER variableInitializer*)
214     ;
215
216 genericTypeParameterList
217     :   ^(GENERIC_TYPE_PARAM_LIST genericTypeParameter+)
218     ;
219
220 genericTypeParameter
221     :   ^(IDENT bound?)
222     ;
223         
224 bound
225     :   ^(EXTENDS_BOUND_LIST type+)
226     ;
227
228 modifierList
229     :   ^(MODIFIER_LIST modifier+)
230     ;
231
232 modifier
233     :   PUBLIC
234     |   PROTECTED
235     |   ENTRY
236     |   PRIVATE
237     |   ABSTRACT
238     |   NATIVE
239     |   localModifier
240     ;
241
242 localModifierList
243     :   ^(LOCAL_MODIFIER_LIST localModifier+)
244     ;
245
246 localModifier
247     :   FINAL
248     |   STATIC
249     |   VOLATILE
250     ;
251
252 type
253     :   simpleType
254     |   objectType
255     |   VOID
256     ;
257
258 simpleType
259     :   ^(SIMPLE_TYPE primitiveType arrayDeclaratorList?)
260     ;
261     
262 objectType
263     :   ^(OBJECT_TYPE qualifiedTypeIdent arrayDeclaratorList?)
264     |   ^(REFERENCE_TYPE qualifiedTypeIdent arrayDeclaratorList?)
265     |   ^(POINTER_TYPE qualifiedTypeIdent arrayDeclaratorList?)
266     ;
267
268 qualifiedTypeIdent
269     :   ^(QUALIFIED_TYPE_IDENT typeIdent+) 
270     ;
271
272 typeIdent
273     :   ^(IDENT genericTypeArgumentList?)
274     ;
275
276 primitiveType
277     :   BOOLEAN     { $start.symbol = new Symbol(symtab, "bool_primitive", symtab.resolveBuiltinType("bool")); }
278     |   CHAR        { $start.symbol = new Symbol(symtab, "char_primitive", symtab.resolveBuiltinType("char")); }
279     |   BYTE        { $start.symbol = new Symbol(symtab, "byte_primitive", symtab.resolveBuiltinType("char")); }
280     |   SHORT       { $start.symbol = new Symbol(symtab, "short_primitive", symtab.resolveBuiltinType("short")); }
281     |   INT         { $start.symbol = new Symbol(symtab, "int_primitive", symtab.resolveBuiltinType("int")); }
282     |   LONG        { $start.symbol = new Symbol(symtab, "long_primitive", symtab.resolveBuiltinType("long")); }
283     |   FLOAT       { $start.symbol = new Symbol(symtab, "float_primitive", symtab.resolveBuiltinType("float")); }
284     |   DOUBLE      { $start.symbol = new Symbol(symtab, "double_primitive", symtab.resolveBuiltinType("double")); }
285     ;
286
287 genericTypeArgumentList
288     :   ^(GENERIC_TYPE_ARG_LIST genericTypeArgument+)
289     ;
290     
291 genericTypeArgument
292     :   type
293     |   '?'
294     ;
295
296 formalParameterList
297     :   ^(FORMAL_PARAM_LIST formalParameterStandardDecl* formalParameterVarargDecl?) 
298     ;
299     
300 formalParameterStandardDecl
301     :   ^(FORMAL_PARAM_STD_DECL localModifierList? type variableDeclaratorId)
302     ;
303     
304 formalParameterVarargDecl
305     :   ^(FORMAL_PARAM_VARARG_DECL localModifierList? type variableDeclaratorId)
306     ;
307     
308 // FIXME: is this rule right? Verify that this is ok, I expected something like:
309 // IDENT (^('.' qualifiedIdentifier IDENT))*
310 qualifiedIdentifier
311     :   IDENT
312     |   ^('.' qualifiedIdentifier IDENT)
313     ;
314     
315 block
316     :   ^(BLOCK (blockStatement)*)
317     ;
318     
319 blockStatement
320     :   localVariableDeclaration
321     |   statement
322     ;
323     
324 localVariableDeclaration
325     :   ^(PRIMITIVE_VAR_DECLARATION localModifierList? simpleType variableDeclaratorList)
326     |   ^(OBJECT_VAR_DECLARATION localModifierList? objectType variableDeclaratorList)
327     ;
328
329 statement
330     : nonBlockStatement
331     | block
332     ;
333
334 nonBlockStatement
335     :   ^(ASSERT expression expression?)
336     |   ^(IF parenthesizedExpression block block?)
337     |   ^(FOR forInit? FOR_EXPR expression? FOR_UPDATE expression* block)
338     |   ^(FOR_EACH localModifierList? type IDENT expression block) 
339     |   ^(WHILE parenthesizedExpression block)
340     |   ^(DO block parenthesizedExpression)
341     |   ^(SWITCH parenthesizedExpression switchCaseLabel*)
342     |   ^(RETURN expression?)
343     |   ^(THROW expression)
344     |   ^(BREAK IDENT?) {
345             if ($IDENT != null) {
346                 translator.error(this, "Labeled break not supported yet, ignoring.", $IDENT);
347             }
348         }
349     |   ^(CONTINUE IDENT?) {
350             if ($IDENT != null) {
351                 translator.error(this, "Labeled continue not supported yet, ignoring.", $IDENT);
352             }
353         }
354     |   ^(LABELED_STATEMENT IDENT statement)
355     |   expression
356     |   ^('delete' qualifiedIdentifier)
357     |   ^(EMBED STRING_LITERAL EMBED_BLOCK)
358     |   ';' // Empty statement.
359     ;
360         
361 switchCaseLabel
362     :   ^(CASE expression blockStatement*)
363     |   ^(DEFAULT blockStatement*)
364     ;
365     
366 forInit
367     :   localVariableDeclaration 
368     |   expression+
369     ;
370     
371 // EXPRESSIONS
372
373 parenthesizedExpression
374     :   ^(PAREN_EXPR expression)
375     ;
376     
377 expression
378     :   ^(EXPR expr)
379     ;
380
381 expr
382     :   ^(ASSIGNMENT expr expr)
383     |   ^(PLUS_EQUALS expr expr)
384     |   ^(MINUS_EQUALS expr expr)
385     |   ^(TIMES_EQUALS expr expr)
386     |   ^(DIVIDE_EQUALS expr expr)
387     |   ^(AND_EQUALS expr expr)
388     |   ^(OR_EQUALS expr expr)
389     |   ^(POWER_EQUALS expr expr)
390     |   ^(MOD_EQUALS expr expr)
391     |   ^('>>>=' expr expr)
392     |   ^('>>=' expr expr)
393     |   ^('<<=' expr expr)
394     |   ^('?' expr expr expr)
395     |   ^(OR expr expr)
396     |   ^(AND expr expr)
397     |   ^(BITWISE_OR expr expr)
398     |   ^(POWER expr expr)
399     |   ^(BITWISE_AND expr expr)
400     |   ^(EQUALS expr expr)
401     |   ^(NOT_EQUALS expr expr)
402     |   ^(INSTANCEOF expr type)
403     |   ^(LTE expr expr)
404     |   ^(GTE expr expr)
405     |   ^('>>>' expr expr)
406     |   ^('>>' expr expr)
407     |   ^(GT expr expr)
408     |   ^('<<' expr expr)
409     |   ^(LT expr expr)
410     |   ^(PLUS expr expr)
411     |   ^(MINUS expr expr)
412     |   ^(TIMES expr expr)
413     |   ^(DIVIDE expr expr)
414     |   ^(MOD expr expr)
415     |   ^(UNARY_PLUS expr)
416     |   ^(UNARY_MINUS expr)
417     |   ^(PRE_INC expr)
418     |   ^(PRE_DEC expr)
419     |   ^(POST_INC expr)
420     |   ^(POST_DEC expr)
421     |   ^(TILDA expr)
422     |   ^(NOT expr)
423     |   ^(CAST_EXPR type expr)
424     |   primaryExpression
425     ;
426     
427 primaryExpression
428     :   ^(  '.' primaryExpression
429                 (   IDENT
430                 |   THIS
431                 |   SUPER
432                 )
433         )
434     |   parenthesizedExpression
435     |   IDENT
436     |   ^(METHOD_CALL primaryExpression genericTypeArgumentList? arguments)
437     |   explicitConstructorCall
438     |   ^(ARRAY_ELEMENT_ACCESS primaryExpression expression)
439     |   literal
440     |   newExpression
441     |   THIS
442     |   arrayTypeDeclarator
443     |   SUPER
444     ;
445     
446 explicitConstructorCall
447     :   ^(THIS_CONSTRUCTOR_CALL genericTypeArgumentList? arguments)
448     |   ^(SUPER_CONSTRUCTOR_CALL primaryExpression? genericTypeArgumentList? arguments)
449     ;
450
451 arrayTypeDeclarator
452     :   ^(ARRAY_DECLARATOR (arrayTypeDeclarator | qualifiedIdentifier | primitiveType))
453     ;
454
455 newExpression
456     :   ^(  STATIC_ARRAY_CREATOR
457             (   primitiveType newArrayConstruction
458             |   genericTypeArgumentList? qualifiedTypeIdent newArrayConstruction
459             )
460         )
461     |   ^(NEW qualifiedTypeIdent arguments)
462     ;
463
464 newArrayConstruction
465     :   arrayDeclaratorList arrayInitializer
466     |   expression+ arrayDeclaratorList?
467     ;
468
469 arguments
470     :   ^(ARGUMENT_LIST expression*)
471     ;
472
473 literal 
474     :   HEX_LITERAL
475     |   OCTAL_LITERAL
476     |   DECIMAL_LITERAL
477     |   FLOATING_POINT_LITERAL
478     |   CHARACTER_LITERAL
479     |   STRING_LITERAL          
480     |   TRUE
481     |   FALSE
482     |   NULL 
483     ;
484