b5ff63f26104a326ef9ba7355ac0333062027ca2
[charm.git] / src / langs / charj / src / charj / translator / CharjSemantics.g
1 /**
2  * The semantic phase walks the tree and builds the symbol table, handles
3  * all the imports, and does the semantic checks. The resulting tree and
4  * symbol table are used by the emitter to generate the output. 
5  */
6
7 tree grammar CharjSemantics;
8
9 options {
10     backtrack = true; 
11     memoize = true;
12     tokenVocab = Charj;
13     ASTLabelType = CharjAST;
14 }
15
16 scope ScopeStack {
17     Scope current;
18 }
19
20 @header {
21 package charj.translator;
22 }
23
24 @members {
25     SymbolTable symtab = null;
26     PackageScope currentPackage = null;
27     ClassSymbol currentClass = null;
28     MethodSymbol currentMethod = null;
29     LocalScope currentLocalScope = null;
30     Translator translator;
31
32     /**
33      *  Test a list of CharjAST nodes to see if any of them has the given token
34      *  type.
35      */
36     public boolean listContainsToken(List<CharjAST> list, int tokenType) {
37         if (list == null) return false;
38         for (CharjAST node : list) {
39             if (node.token.getType() == tokenType) {
40                 return true;
41             }
42         }
43         return false;
44     }
45
46     public void importPackages(ClassSymbol cs, List<CharjAST> imports) {
47         if (imports == null) {
48             return;
49         }
50
51         for (CharjAST pkg : imports) {
52             String pkgName = input.getTokenStream().toString(
53                     pkg.getTokenStartIndex(),
54                     pkg.getTokenStopIndex());
55             // find imported class and add to cs.imports
56             PackageScope p = cs.importPackage(pkgName);
57             if (p == null) {
58                 translator.error(
59                     this, 
60                     "package " + pkgName + " not found.",
61                     pkg);
62             }
63         }
64     }
65 }
66
67
68 // Replace default ANTLR generated catch clauses with this action, allowing early failure.
69 @rulecatch {
70     catch (RecognitionException re) {
71         reportError(re);
72         throw re;
73     }
74 }
75
76
77 // Starting point for parsing a Charj file.
78 charjSource[SymbolTable _symtab] returns [ClassSymbol cs]
79 scope ScopeStack; // default scope
80 @init {
81     symtab = _symtab;
82     $ScopeStack::current = symtab.getDefaultPkg();
83 }
84     // TODO: go back to allowing multiple type definitions per file, check that
85     // there is exactly one public type and return that one.
86     :   ^(CHARJ_SOURCE 
87         (packageDeclaration)? 
88         (importDeclarations) 
89         (typeDeclaration[$importDeclarations.packageNames]))
90         { $cs = $typeDeclaration.sym; }
91     ;
92
93 // note: no new scope here--this replaces the default scope
94 packageDeclaration
95 @init { 
96     List<String> names = null; 
97 }
98     :   ^('package' qualifiedIdentifier)  {
99             String packageName = $qualifiedIdentifier.text;
100             PackageScope ps = symtab.resolvePackage(packageName);
101             if (ps == null) {
102                 ps = symtab.definePackage(packageName);
103                 symtab.addScope(ps);
104             }
105             currentPackage = ps;
106             $ScopeStack::current = ps;
107             $qualifiedIdentifier.start.symbol = ps;
108         }
109     ;
110     
111 importDeclarations returns [List<CharjAST> packageNames]
112 @init {
113         packageNames = new ArrayList<CharjAST>();
114 }
115     :   (^('import' qualifiedIdentifier './*'?)
116                 { packageNames.add($qualifiedIdentifier.start); })*
117     ;
118
119
120 typeDeclaration[List<CharjAST> imports] returns [ClassSymbol sym]
121 scope ScopeStack; // top-level type scope
122     :   ^(TYPE ('class' | chareType) IDENT
123             (^('extends' parent=type))? (^('implements' type+))? classScopeDeclaration*)
124         {
125             Scope outerScope = $ScopeStack[-1]::current;
126             $sym = new ClassSymbol(symtab, $IDENT.text, outerScope.resolveType($parent.text), outerScope);
127             outerScope.define($sym.name, $sym);
128             currentClass = $sym;
129             $sym.definition = $typeDeclaration.start;
130             $sym.definitionTokenStream = input.getTokenStream();
131             $IDENT.symbol = $sym;
132             $ScopeStack::current = $sym;
133             importPackages($sym, $imports);
134         }
135     |   ^('interface' IDENT (^('extends' type+))?  interfaceScopeDeclaration*)
136     |   ^('enum' IDENT (^('implements' type+))? enumConstant+ classScopeDeclaration*)
137     ;
138
139 chareType
140     :   'chare'
141     |   'group'
142     |   'nodegroup'
143     |   ^('chare_array' ARRAY_DIMENSION)
144     ;
145
146 enumConstant
147     :   ^(IDENT arguments?)
148     ;
149     
150 classScopeDeclaration
151     :   ^(FUNCTION_METHOD_DECL m=modifierList? g=genericTypeParameterList? 
152             ty=type IDENT f=formalParameterList a=arrayDeclaratorList? 
153             b=block?)
154     |   ^(VOID_METHOD_DECL m=modifierList? g=genericTypeParameterList? IDENT 
155             f=formalParameterList b=block?)
156     |   ^(PRIMITIVE_VAR_DECLARATION modifierList? simpleType variableDeclaratorList)
157     |   ^(OBJECT_VAR_DECLARATION modifierList? objectType variableDeclaratorList)
158     |   ^(CONSTRUCTOR_DECL m=modifierList? g=genericTypeParameterList? IDENT f=formalParameterList 
159             b=block)
160     ;
161     
162 interfaceScopeDeclaration
163     :   ^(FUNCTION_METHOD_DECL modifierList? genericTypeParameterList? 
164             type IDENT formalParameterList arrayDeclaratorList?)
165     |   ^(VOID_METHOD_DECL modifierList? genericTypeParameterList? IDENT formalParameterList)
166         // Interface constant declarations have been switched to variable
167         // declarations by Charj.g; the parser has already checked that
168         // there's an obligatory initializer.
169     |   ^(PRIMITIVE_VAR_DECLARATION modifierList? simpleType variableDeclaratorList)
170     |   ^(OBJECT_VAR_DECLARATION modifierList? objectType variableDeclaratorList)
171     ;
172
173 variableDeclaratorList
174     :   ^(VAR_DECLARATOR_LIST variableDeclarator+)
175     ;
176
177 variableDeclarator
178     :   ^(VAR_DECLARATOR variableDeclaratorId variableInitializer?)
179     ;
180     
181 variableDeclaratorId
182     :   ^(IDENT arrayDeclaratorList?)
183     ;
184
185 variableInitializer
186     :   arrayInitializer
187     |   expression
188     ;
189
190 arrayDeclaratorList
191     :   ^(ARRAY_DECLARATOR_LIST ARRAY_DECLARATOR*)  
192     ;
193     
194 arrayInitializer
195     :   ^(ARRAY_INITIALIZER variableInitializer*)
196     ;
197
198 genericTypeParameterList
199     :   ^(GENERIC_TYPE_PARAM_LIST genericTypeParameter+)
200     ;
201
202 genericTypeParameter
203     :   ^(IDENT bound?)
204     ;
205         
206 bound
207     :   ^(EXTENDS_BOUND_LIST type+)
208     ;
209
210 modifierList
211     :   ^(MODIFIER_LIST modifier+)
212     ;
213
214 modifier
215     :   'public'
216     |   'protected'
217     |   'private'
218     |   'entry'
219     |   'abstract'
220     |   'native'
221     |   localModifier
222     ;
223
224 localModifierList
225     :   ^(LOCAL_MODIFIER_LIST localModifier+)
226     ;
227
228 localModifier
229     :   'final'
230     |   'static'
231     |   'volatile'
232     ;
233
234 type
235     :   simpleType
236     |   objectType 
237     ;
238
239 simpleType
240     :   ^(TYPE primitiveType arrayDeclaratorList?)
241     ;
242     
243 objectType
244     :   ^(TYPE qualifiedTypeIdent arrayDeclaratorList?)
245     ;
246
247 qualifiedTypeIdent
248     :   ^(QUALIFIED_TYPE_IDENT typeIdent+) 
249     ;
250
251 typeIdent
252     :   ^(IDENT genericTypeArgumentList?)
253     ;
254
255 primitiveType
256     :   'boolean'     { $start.symbol = new Symbol(symtab, "bool_primitive", symtab.resolveBuiltinType("bool")); }
257     |   'char'        { $start.symbol = new Symbol(symtab, "char_primitive", symtab.resolveBuiltinType("char")); }
258     |   'byte'        { $start.symbol = new Symbol(symtab, "byte_primitive", symtab.resolveBuiltinType("char")); }
259     |   'short'       { $start.symbol = new Symbol(symtab, "short_primitive", symtab.resolveBuiltinType("short")); }
260     |   'int'         { $start.symbol = new Symbol(symtab, "int_primitive", symtab.resolveBuiltinType("int")); }
261     |   'long'        { $start.symbol = new Symbol(symtab, "long_primitive", symtab.resolveBuiltinType("long")); }
262     |   'float'       { $start.symbol = new Symbol(symtab, "float_primitive", symtab.resolveBuiltinType("float")); }
263     |   'double'      { $start.symbol = new Symbol(symtab, "double_primitive", symtab.resolveBuiltinType("double")); }
264     ;
265
266 genericTypeArgumentList
267     :   ^(GENERIC_TYPE_ARG_LIST genericTypeArgument+)
268     ;
269     
270 genericTypeArgument
271     :   type
272     |   '?'
273     ;
274
275 formalParameterList
276     :   ^(FORMAL_PARAM_LIST formalParameterStandardDecl* formalParameterVarargDecl?) 
277     ;
278     
279 formalParameterStandardDecl
280     :   ^(FORMAL_PARAM_STD_DECL localModifierList? type variableDeclaratorId)
281     ;
282     
283 formalParameterVarargDecl
284     :   ^(FORMAL_PARAM_VARARG_DECL localModifierList? type variableDeclaratorId)
285     ;
286     
287 // FIXME: is this rule right? Verify that this is ok, I expected something like:
288 // IDENT (^('.' qualifiedIdentifier IDENT))*
289 qualifiedIdentifier
290     :   IDENT
291     |   ^('.' qualifiedIdentifier IDENT)
292     ;
293     
294 block
295     :   ^(BLOCK (blockStatement)*)
296     ;
297     
298 blockStatement
299     :   localVariableDeclaration
300     |   statement
301     ;
302     
303 localVariableDeclaration
304     :   ^(PRIMITIVE_VAR_DECLARATION localModifierList? simpleType variableDeclaratorList)
305     |   ^(OBJECT_VAR_DECLARATION localModifierList? objectType variableDeclaratorList)
306     ;
307
308 statement
309     :   block
310     |   ^('assert' expression expression?)
311     |   ^('if' parenthesizedExpression statement statement?)
312     |   ^('for' forInit? FOR_EXPR expression? FOR_UPDATE expression* statement)
313     |   ^(FOR_EACH localModifierList? type IDENT expression statement) 
314     |   ^('while' parenthesizedExpression statement)
315     |   ^('do' statement parenthesizedExpression)
316     |   ^('switch' parenthesizedExpression switchCaseLabel*)
317     |   ^('return' expression?)
318     |   ^('throw' expression)
319     |   ^('break' IDENT?) {
320             if ($IDENT != null) {
321                 translator.error(this, "Labeled break not supported yet, ignoring.", $IDENT);
322             }
323         }
324     |   ^('continue' IDENT?) {
325             if ($IDENT != null) {
326                 translator.error(this, "Labeled continue not supported yet, ignoring.", $IDENT);
327             }
328         }
329     |   ^(LABELED_STATEMENT IDENT statement)
330     |   expression
331     |   ^('embed' STRING_LITERAL EMBED_BLOCK)
332     |   ';' // Empty statement.
333     ;
334         
335 switchCaseLabel
336     :   ^('case' expression blockStatement*)
337     |   ^('default' blockStatement*)
338     ;
339     
340 forInit
341     :   localVariableDeclaration 
342     |   expression+
343     ;
344     
345 // EXPRESSIONS
346
347 parenthesizedExpression
348     :   ^(PAREN_EXPR expression)
349     ;
350     
351 expression
352     :   ^(EXPR expr)
353     ;
354
355 expr
356     :   ^('=' expr expr)
357     |   ^('+=' expr expr)
358     |   ^('-=' expr expr)
359     |   ^('*=' expr expr)
360     |   ^('/=' expr expr)
361     |   ^('&=' expr expr)
362     |   ^('|=' expr expr)
363     |   ^('^=' expr expr)
364     |   ^('%=' expr expr)
365     |   ^('>>>=' expr expr)
366     |   ^('>>=' expr expr)
367     |   ^('<<=' expr expr)
368     |   ^('?' expr expr expr)
369     |   ^('||' expr expr)
370     |   ^('&&' expr expr)
371     |   ^('|' expr expr)
372     |   ^('^' expr expr)
373     |   ^('&' expr expr)
374     |   ^('==' expr expr)
375     |   ^('!=' expr expr)
376     |   ^('instanceof' expr type)
377     |   ^('<=' expr expr)
378     |   ^('>=' expr expr)
379     |   ^('>>>' expr expr)
380     |   ^('>>' expr expr)
381     |   ^('>' expr expr)
382     |   ^('<<' expr expr)
383     |   ^('<' expr expr)
384     |   ^('+' expr expr)
385     |   ^('-' expr expr)
386     |   ^('*' expr expr)
387     |   ^('/' expr expr)
388     |   ^('%' expr expr)
389     |   ^(UNARY_PLUS expr)
390     |   ^(UNARY_MINUS expr)
391     |   ^(PRE_INC expr)
392     |   ^(PRE_DEC expr)
393     |   ^(POST_INC expr)
394     |   ^(POST_DEC expr)
395     |   ^('~' expr)
396     |   ^('!' expr)
397     |   ^(CAST_EXPR type expr)
398     |   primaryExpression
399     ;
400     
401 primaryExpression
402     :   ^(  '.' primaryExpression
403                 (   IDENT
404                 |   'this'
405                 |   'super'
406                 )
407         )
408     |   parenthesizedExpression
409     |   IDENT
410     |   ^(METHOD_CALL primaryExpression genericTypeArgumentList? arguments)
411     |   explicitConstructorCall
412     |   ^(ARRAY_ELEMENT_ACCESS primaryExpression expression)
413     |   literal
414     |   newExpression
415     |   'this'
416     |   arrayTypeDeclarator
417     |   'super'
418     ;
419     
420 explicitConstructorCall
421     :   ^(THIS_CONSTRUCTOR_CALL genericTypeArgumentList? arguments)
422     |   ^(SUPER_CONSTRUCTOR_CALL primaryExpression? genericTypeArgumentList? arguments)
423     ;
424
425 arrayTypeDeclarator
426     :   ^(ARRAY_DECLARATOR (arrayTypeDeclarator | qualifiedIdentifier | primitiveType))
427     ;
428
429 newExpression
430     :   ^(  STATIC_ARRAY_CREATOR
431             (   primitiveType newArrayConstruction
432             |   genericTypeArgumentList? qualifiedTypeIdent newArrayConstruction
433             )
434         )
435     ;
436
437 newArrayConstruction
438     :   arrayDeclaratorList arrayInitializer
439     |   expression+ arrayDeclaratorList?
440     ;
441
442 arguments
443     :   ^(ARGUMENT_LIST expression*)
444     ;
445
446 literal 
447     :   HEX_LITERAL
448     |   OCTAL_LITERAL
449     |   DECIMAL_LITERAL
450     |   FLOATING_POINT_LITERAL
451     |   CHARACTER_LITERAL
452     |   STRING_LITERAL          
453     |   'true'
454     |   'false'
455     |   'null'
456     ;
457