a036085725c3d8f3b473861f2c727f67a72d8ec9
[charm.git] / src / langs / charj / src / charj / translator / CharjSemantics.g
1 /**
2  * The semantic phase walks the tree and builds the symbol table, handles
3  * all the imports, and does the semantic checks. The resulting tree and
4  * symbol table are used by the emitter to generate the output. 
5  */
6
7 tree grammar CharjSemantics;
8
9 options {
10     backtrack = true; 
11     memoize = true;
12     tokenVocab = Charj;
13     ASTLabelType = CharjAST;
14 }
15
16 scope ScopeStack {
17     Scope current;
18 }
19
20 @header {
21 package charj.translator;
22 }
23
24 @members {
25     SymbolTable symtab = null;
26     PackageScope currentPackage = null;
27     ClassSymbol currentClass = null;
28     MethodSymbol currentMethod = null;
29     LocalScope currentLocalScope = null;
30     Translator translator;
31
32     /**
33      *  Test a list of CharjAST nodes to see if any of them has the given token
34      *  type.
35      */
36     public boolean listContainsToken(List<CharjAST> list, int tokenType) {
37         if (list == null) return false;
38         for (CharjAST node : list) {
39             if (node.token.getType() == tokenType) {
40                 return true;
41             }
42         }
43         return false;
44     }
45
46     public void importPackages(ClassSymbol cs, List<CharjAST> imports) {
47         if (imports == null) {
48             return;
49         }
50
51         for (CharjAST pkg : imports) {
52             String pkgName = input.getTokenStream().toString(
53                     pkg.getTokenStartIndex(),
54                     pkg.getTokenStopIndex());
55             // find imported class and add to cs.imports
56             PackageScope p = cs.importPackage(pkgName);
57             if (p == null) {
58                 translator.error(
59                     this, 
60                     "package " + pkgName + " not found.",
61                     pkg);
62             }
63         }
64     }
65 }
66
67
68 // Replace default ANTLR generated catch clauses with this action, allowing early failure.
69 @rulecatch {
70     catch (RecognitionException re) {
71         reportError(re);
72         throw re;
73     }
74 }
75
76
77 // Starting point for parsing a Charj file.
78 charjSource[SymbolTable _symtab] returns [ClassSymbol cs]
79 scope ScopeStack; // default scope
80 @init {
81     symtab = _symtab;
82     $ScopeStack::current = symtab.getDefaultPkg();
83 }
84     // TODO: go back to allowing multiple type definitions per file, check that
85     // there is exactly one public type and return that one.
86     :   ^(CHARJ_SOURCE 
87         (packageDeclaration)? 
88         (importDeclarations) 
89         (typeDeclaration[$importDeclarations.packageNames]))
90         { $cs = $typeDeclaration.sym; }
91     ;
92
93 // note: no new scope here--this replaces the default scope
94 packageDeclaration
95 @init { 
96     List<String> names = null; 
97 }
98     :   ^('package' (ids+=IDENT)+)  
99         {
100             String packageName = "";
101             for(Object o : $ids) packageName += '.' + ((CharjAST)o).getText();
102             packageName = packageName.substring(1);
103             PackageScope ps = symtab.resolvePackage(packageName);
104             if (ps == null) {
105                 ps = symtab.definePackage(packageName);
106                 symtab.addScope(ps);
107             }
108             currentPackage = ps;
109             $ScopeStack::current = ps;
110 //            $qualifiedIdentifier.start.symbol = ps; ----- commented out while dealing with the namespaces issue (Minas)
111         }
112     ;
113     
114 importDeclarations returns [List<CharjAST> packageNames]
115 @init {
116     packageNames = new ArrayList<CharjAST>();
117 }
118     :   (^('import' qualifiedIdentifier '.*'?)
119                 { packageNames.add($qualifiedIdentifier.start); })*
120     ;
121
122
123 typeDeclaration[List<CharjAST> imports] returns [ClassSymbol sym]
124 scope ScopeStack; // top-level type scope
125     :   ^(TYPE ('class' | chareType) IDENT
126             (^('extends' parent=type))? (^('implements' type+))?
127             {
128                 Scope outerScope = $ScopeStack[-1]::current;
129                 $sym = new ClassSymbol(symtab, $IDENT.text, outerScope.resolveType($parent.text), outerScope);
130                 outerScope.define($sym.name, $sym);
131                 currentClass = $sym;
132                 $sym.definition = $typeDeclaration.start;
133                 $sym.definitionTokenStream = input.getTokenStream();
134                 $IDENT.symbol = $sym;
135                 $ScopeStack::current = $sym;
136                 importPackages($sym, $imports);
137             }
138             classScopeDeclaration*)
139     |   ^('interface' IDENT (^('extends' type+))?  interfaceScopeDeclaration*)
140     |   ^('enum' IDENT (^('implements' type+))? enumConstant+ classScopeDeclaration*)
141     ;
142
143 chareType
144     :   'chare'
145     |   'group'
146     |   'nodegroup'
147     |   ^('chare_array' ARRAY_DIMENSION)
148     ;
149
150 enumConstant
151     :   ^(IDENT arguments?)
152     ;
153     
154 classScopeDeclaration
155 scope ScopeStack;
156     :   ^(FUNCTION_METHOD_DECL m=modifierList? g=genericTypeParameterList? 
157             ty=type IDENT f=formalParameterList a=arrayDeclaratorList? 
158             b=block?)
159         {
160             ClassSymbol returnType = currentClass.resolveType($ty.text);
161             MethodSymbol sym = new MethodSymbol(symtab, $IDENT.text, currentClass, returnType);
162             currentMethod = sym;
163             sym.definition = $classScopeDeclaration.start;
164             sym.definitionTokenStream = input.getTokenStream();
165             currentClass.members.put($IDENT.text, sym);
166             $FUNCTION_METHOD_DECL.symbol = sym;
167         }
168     |   ^(PRIMITIVE_VAR_DECLARATION modifierList? simpleType variableDeclaratorList)
169     |   ^(OBJECT_VAR_DECLARATION modifierList? objectType variableDeclaratorList)
170     |   ^(CONSTRUCTOR_DECL m=modifierList? g=genericTypeParameterList? IDENT f=formalParameterList 
171             b=block)
172     ;
173     
174 interfaceScopeDeclaration
175     :   ^(FUNCTION_METHOD_DECL modifierList? genericTypeParameterList? 
176             type IDENT formalParameterList arrayDeclaratorList?)
177         // Interface constant declarations have been switched to variable
178         // declarations by Charj.g; the parser has already checked that
179         // there's an obligatory initializer.
180     |   ^(PRIMITIVE_VAR_DECLARATION modifierList? simpleType variableDeclaratorList)
181     |   ^(OBJECT_VAR_DECLARATION modifierList? objectType variableDeclaratorList)
182     ;
183
184 variableDeclaratorList
185     :   ^(VAR_DECLARATOR_LIST variableDeclarator+)
186     ;
187
188 variableDeclarator
189     :   ^(VAR_DECLARATOR variableDeclaratorId variableInitializer?)
190     ;
191     
192 variableDeclaratorId
193     :   ^(IDENT arrayDeclaratorList?)
194     ;
195
196 variableInitializer
197     :   arrayInitializer
198     |   expression
199     ;
200
201 arrayDeclaratorList
202     :   ^(ARRAY_DECLARATOR_LIST ARRAY_DECLARATOR*)  
203     ;
204     
205 arrayInitializer
206     :   ^(ARRAY_INITIALIZER variableInitializer*)
207     ;
208
209 genericTypeParameterList
210     :   ^(GENERIC_TYPE_PARAM_LIST genericTypeParameter+)
211     ;
212
213 genericTypeParameter
214     :   ^(IDENT bound?)
215     ;
216         
217 bound
218     :   ^(EXTENDS_BOUND_LIST type+)
219     ;
220
221 modifierList
222     :   ^(MODIFIER_LIST modifier+)
223     ;
224
225 modifier
226     :   'public'
227     |   'protected'
228     |   'private'
229     |   'entry'
230     |   'abstract'
231     |   'native'
232     |   localModifier
233     ;
234
235 localModifierList
236     :   ^(LOCAL_MODIFIER_LIST localModifier+)
237     ;
238
239 localModifier
240     :   'final'
241     |   'static'
242     |   'volatile'
243     ;
244
245 type
246     :   simpleType
247     |   objectType 
248     |   'void'
249     ;
250
251 simpleType
252     :   ^(TYPE primitiveType arrayDeclaratorList?)
253     ;
254     
255 objectType
256     :   ^(TYPE qualifiedTypeIdent arrayDeclaratorList?)
257     ;
258
259 qualifiedTypeIdent
260     :   ^(QUALIFIED_TYPE_IDENT typeIdent+) 
261     ;
262
263 typeIdent
264     :   ^(IDENT genericTypeArgumentList?)
265     ;
266
267 primitiveType
268     :   'boolean'     { $start.symbol = new Symbol(symtab, "bool_primitive", symtab.resolveBuiltinType("bool")); }
269     |   'char'        { $start.symbol = new Symbol(symtab, "char_primitive", symtab.resolveBuiltinType("char")); }
270     |   'byte'        { $start.symbol = new Symbol(symtab, "byte_primitive", symtab.resolveBuiltinType("char")); }
271     |   'short'       { $start.symbol = new Symbol(symtab, "short_primitive", symtab.resolveBuiltinType("short")); }
272     |   'int'         { $start.symbol = new Symbol(symtab, "int_primitive", symtab.resolveBuiltinType("int")); }
273     |   'long'        { $start.symbol = new Symbol(symtab, "long_primitive", symtab.resolveBuiltinType("long")); }
274     |   'float'       { $start.symbol = new Symbol(symtab, "float_primitive", symtab.resolveBuiltinType("float")); }
275     |   'double'      { $start.symbol = new Symbol(symtab, "double_primitive", symtab.resolveBuiltinType("double")); }
276     ;
277
278 genericTypeArgumentList
279     :   ^(GENERIC_TYPE_ARG_LIST genericTypeArgument+)
280     ;
281     
282 genericTypeArgument
283     :   type
284     |   '?'
285     ;
286
287 formalParameterList
288     :   ^(FORMAL_PARAM_LIST formalParameterStandardDecl* formalParameterVarargDecl?) 
289     ;
290     
291 formalParameterStandardDecl
292     :   ^(FORMAL_PARAM_STD_DECL localModifierList? type variableDeclaratorId)
293     ;
294     
295 formalParameterVarargDecl
296     :   ^(FORMAL_PARAM_VARARG_DECL localModifierList? type variableDeclaratorId)
297     ;
298     
299 // FIXME: is this rule right? Verify that this is ok, I expected something like:
300 // IDENT (^('.' qualifiedIdentifier IDENT))*
301 qualifiedIdentifier
302     :   IDENT
303     |   ^('.' qualifiedIdentifier IDENT)
304     ;
305     
306 block
307     :   ^(BLOCK (blockStatement)*)
308     ;
309     
310 blockStatement
311     :   localVariableDeclaration
312     |   statement
313     ;
314     
315 localVariableDeclaration
316     :   ^(PRIMITIVE_VAR_DECLARATION localModifierList? simpleType variableDeclaratorList)
317     |   ^(OBJECT_VAR_DECLARATION localModifierList? objectType variableDeclaratorList)
318     ;
319
320 statement
321     :   block
322     |   ^('assert' expression expression?)
323     |   ^('if' parenthesizedExpression statement statement?)
324     |   ^('for' forInit? FOR_EXPR expression? FOR_UPDATE expression* statement)
325     |   ^(FOR_EACH localModifierList? type IDENT expression statement) 
326     |   ^('while' parenthesizedExpression statement)
327     |   ^('do' statement parenthesizedExpression)
328     |   ^('switch' parenthesizedExpression switchCaseLabel*)
329     |   ^('return' expression?)
330     |   ^('throw' expression)
331     |   ^('break' IDENT?) {
332             if ($IDENT != null) {
333                 translator.error(this, "Labeled break not supported yet, ignoring.", $IDENT);
334             }
335         }
336     |   ^('continue' IDENT?) {
337             if ($IDENT != null) {
338                 translator.error(this, "Labeled continue not supported yet, ignoring.", $IDENT);
339             }
340         }
341     |   ^(LABELED_STATEMENT IDENT statement)
342     |   expression
343     |   ^('embed' STRING_LITERAL EMBED_BLOCK)
344     |   ';' // Empty statement.
345     ;
346         
347 switchCaseLabel
348     :   ^('case' expression blockStatement*)
349     |   ^('default' blockStatement*)
350     ;
351     
352 forInit
353     :   localVariableDeclaration 
354     |   expression+
355     ;
356     
357 // EXPRESSIONS
358
359 parenthesizedExpression
360     :   ^(PAREN_EXPR expression)
361     ;
362     
363 expression
364     :   ^(EXPR expr)
365     ;
366
367 expr
368     :   ^('=' expr expr)
369     |   ^('+=' expr expr)
370     |   ^('-=' expr expr)
371     |   ^('*=' expr expr)
372     |   ^('/=' expr expr)
373     |   ^('&=' expr expr)
374     |   ^('|=' expr expr)
375     |   ^('^=' expr expr)
376     |   ^('%=' expr expr)
377     |   ^('>>>=' expr expr)
378     |   ^('>>=' expr expr)
379     |   ^('<<=' expr expr)
380     |   ^('?' expr expr expr)
381     |   ^('||' expr expr)
382     |   ^('&&' expr expr)
383     |   ^('|' expr expr)
384     |   ^('^' expr expr)
385     |   ^('&' expr expr)
386     |   ^('==' expr expr)
387     |   ^('!=' expr expr)
388     |   ^('instanceof' expr type)
389     |   ^('<=' expr expr)
390     |   ^('>=' expr expr)
391     |   ^('>>>' expr expr)
392     |   ^('>>' expr expr)
393     |   ^('>' expr expr)
394     |   ^('<<' expr expr)
395     |   ^('<' expr expr)
396     |   ^('+' expr expr)
397     |   ^('-' expr expr)
398     |   ^('*' expr expr)
399     |   ^('/' expr expr)
400     |   ^('%' expr expr)
401     |   ^(UNARY_PLUS expr)
402     |   ^(UNARY_MINUS expr)
403     |   ^(PRE_INC expr)
404     |   ^(PRE_DEC expr)
405     |   ^(POST_INC expr)
406     |   ^(POST_DEC expr)
407     |   ^('~' expr)
408     |   ^('!' expr)
409     |   ^(CAST_EXPR type expr)
410     |   primaryExpression
411     ;
412     
413 primaryExpression
414     :   ^(  '.' primaryExpression
415                 (   IDENT
416                 |   'this'
417                 |   'super'
418                 )
419         )
420     |   parenthesizedExpression
421     |   IDENT
422     |   ^(METHOD_CALL primaryExpression genericTypeArgumentList? arguments)
423     |   explicitConstructorCall
424     |   ^(ARRAY_ELEMENT_ACCESS primaryExpression expression)
425     |   literal
426     |   newExpression
427     |   'this'
428     |   arrayTypeDeclarator
429     |   'super'
430     ;
431     
432 explicitConstructorCall
433     :   ^(THIS_CONSTRUCTOR_CALL genericTypeArgumentList? arguments)
434     |   ^(SUPER_CONSTRUCTOR_CALL primaryExpression? genericTypeArgumentList? arguments)
435     ;
436
437 arrayTypeDeclarator
438     :   ^(ARRAY_DECLARATOR (arrayTypeDeclarator | qualifiedIdentifier | primitiveType))
439     ;
440
441 newExpression
442     :   ^(  STATIC_ARRAY_CREATOR
443             (   primitiveType newArrayConstruction
444             |   genericTypeArgumentList? qualifiedTypeIdent newArrayConstruction
445             )
446         )
447     ;
448
449 newArrayConstruction
450     :   arrayDeclaratorList arrayInitializer
451     |   expression+ arrayDeclaratorList?
452     ;
453
454 arguments
455     :   ^(ARGUMENT_LIST expression*)
456     ;
457
458 literal 
459     :   HEX_LITERAL
460     |   OCTAL_LITERAL
461     |   DECIMAL_LITERAL
462     |   FLOATING_POINT_LITERAL
463     |   CHARACTER_LITERAL
464     |   STRING_LITERAL          
465     |   'true'
466     |   'false'
467     |   'null'
468     ;
469