9bd9b2939a98f1ec090b7edad616ad2d146715a5
[charm.git] / src / langs / charj / src / charj / translator / CharjSemantics.g
1 /**
2  * The semantic phase walks the tree and builds the symbol table, handles
3  * all the imports, and does the semantic checks. The resulting tree and
4  * symbol table are used by the emitter to generate the output. 
5  */
6
7 tree grammar CharjSemantics;
8
9 options {
10     backtrack = true; 
11     memoize = true;
12     tokenVocab = Charj;
13     ASTLabelType = CharjAST;
14 }
15
16 scope ScopeStack {
17     Scope current;
18 }
19
20 @header {
21 package charj.translator;
22 }
23
24 @members {
25     SymbolTable symtab = null;
26     PackageScope currentPackage = null;
27     ClassSymbol currentClass = null;
28     MethodSymbol currentMethod = null;
29     LocalScope currentLocalScope = null;
30     Translator translator;
31
32     /**
33      *  Test a list of CharjAST nodes to see if any of them has the given token
34      *  type.
35      */
36     public boolean listContainsToken(List<CharjAST> list, int tokenType) {
37         if (list == null) return false;
38         for (CharjAST node : list) {
39             if (node.token.getType() == tokenType) {
40                 return true;
41             }
42         }
43         return false;
44     }
45
46     public void importPackages(ClassSymbol cs, List<CharjAST> imports) {
47         if (imports == null) {
48             return;
49         }
50
51         for (CharjAST pkg : imports) {
52             String pkgName = input.getTokenStream().toString(
53                     pkg.getTokenStartIndex(),
54                     pkg.getTokenStopIndex());
55             // find imported class and add to cs.imports
56             PackageScope p = cs.importPackage(pkgName);
57             if (p == null) {
58                 translator.error(
59                     this, 
60                     "package " + pkgName + " not found.",
61                     pkg);
62             }
63         }
64     }
65 }
66
67
68 // Replace default ANTLR generated catch clauses with this action, allowing early failure.
69 @rulecatch {
70     catch (RecognitionException re) {
71         reportError(re);
72         throw re;
73     }
74 }
75
76
77 // Starting point for parsing a Charj file.
78 charjSource[SymbolTable _symtab] returns [ClassSymbol cs]
79 scope ScopeStack; // default scope
80 @init {
81     symtab = _symtab;
82     $ScopeStack::current = symtab.getDefaultPkg();
83 }
84     // TODO: go back to allowing multiple type definitions per file, check that
85     // there is exactly one public type and return that one.
86     :   ^(CHARJ_SOURCE 
87         (packageDeclaration)? 
88         (importDeclarations) 
89         (typeDeclaration[$importDeclarations.packageNames]))
90         { $cs = $typeDeclaration.sym; }
91     ;
92
93 // note: no new scope here--this replaces the default scope
94 packageDeclaration
95 @init { 
96     List<String> names = null; 
97 }
98     :   ^(PACKAGE (ids+=IDENT)+)  
99         {
100             String packageName = "";
101             for(Object o : $ids) packageName += '.' + ((CharjAST)o).getText();
102             packageName = packageName.substring(1);
103             PackageScope ps = symtab.resolvePackage(packageName);
104             if (ps == null) {
105                 ps = symtab.definePackage(packageName);
106                 symtab.addScope(ps);
107             }
108             currentPackage = ps;
109             $ScopeStack::current = ps;
110 //            $qualifiedIdentifier.start.symbol = ps; ----- commented out while dealing with the namespaces issue (Minas)
111         }
112     ;
113     
114 importDeclarations returns [List<CharjAST> packageNames]
115 @init {
116     packageNames = new ArrayList<CharjAST>();
117 }
118     :   (^(IMPORT qualifiedIdentifier '.*'?)
119                 { packageNames.add($qualifiedIdentifier.start); })*
120     ;
121
122
123 typeDeclaration[List<CharjAST> imports] returns [ClassSymbol sym]
124 scope ScopeStack; // top-level type scope
125     :   ^(TYPE (CLASS | chareType) IDENT
126             (^('extends' parent=type))? (^('implements' type+))?
127             {
128                 Scope outerScope = $ScopeStack[-1]::current;
129                 $sym = new ClassSymbol(symtab, $IDENT.text, outerScope.resolveType($parent.text), outerScope);
130                 outerScope.define($sym.name, $sym);
131                 currentClass = $sym;
132                 $sym.definition = $typeDeclaration.start;
133                 $sym.definitionTokenStream = input.getTokenStream();
134                 $IDENT.symbol = $sym;
135                 $ScopeStack::current = $sym;
136                 importPackages($sym, $imports);
137             }
138             classScopeDeclaration*)
139             {
140                 //System.out.println("Members for type " + $sym.name + ":");
141                 //for (Map.Entry<String, Symbol> entry : $sym.members.entrySet()) {
142                 //    System.out.println(entry.getKey());
143                 //}
144             }
145     |   ^('interface' IDENT (^('extends' type+))?  interfaceScopeDeclaration*)
146     |   ^('enum' IDENT (^('implements' type+))? enumConstant+ classScopeDeclaration*)
147     ;
148
149 chareType
150     :   CHARE
151     |   GROUP
152     |   NODEGROUP
153     |   MAINCHARE
154     |   ^(CHARE_ARRAY ARRAY_DIMENSION)
155     ;
156
157 enumConstant
158     :   ^(IDENT arguments?)
159     ;
160     
161 classScopeDeclaration
162 scope ScopeStack;
163     :   ^(FUNCTION_METHOD_DECL m=modifierList? g=genericTypeParameterList? 
164             ty=type IDENT f=formalParameterList a=arrayDeclaratorList? 
165             b=block?)
166         {
167             ClassSymbol returnType = currentClass.resolveType($ty.text);
168             MethodSymbol sym = new MethodSymbol(symtab, $IDENT.text, currentClass, returnType);
169             currentMethod = sym;
170             sym.definition = $classScopeDeclaration.start;
171             sym.definitionTokenStream = input.getTokenStream();
172             currentClass.define($IDENT.text, sym);
173             $FUNCTION_METHOD_DECL.symbol = sym;
174         }
175     |   ^(PRIMITIVE_VAR_DECLARATION modifierList? simpleType variableDeclaratorList)
176     |   ^(OBJECT_VAR_DECLARATION modifierList? objectType variableDeclaratorList)
177     |   ^(CONSTRUCTOR_DECL m=modifierList? g=genericTypeParameterList? IDENT f=formalParameterList 
178             b=block)
179     ;
180     
181 interfaceScopeDeclaration
182     :   ^(FUNCTION_METHOD_DECL modifierList? genericTypeParameterList? 
183             type IDENT formalParameterList arrayDeclaratorList?)
184         // Interface constant declarations have been switched to variable
185         // declarations by Charj.g; the parser has already checked that
186         // there's an obligatory initializer.
187     |   ^(PRIMITIVE_VAR_DECLARATION modifierList? simpleType variableDeclaratorList)
188     |   ^(OBJECT_VAR_DECLARATION modifierList? objectType variableDeclaratorList)
189     ;
190
191 variableDeclaratorList
192     :   ^(VAR_DECLARATOR_LIST variableDeclarator+)
193     ;
194
195 variableDeclarator
196     :   ^(VAR_DECLARATOR variableDeclaratorId variableInitializer?)
197     ;
198     
199 variableDeclaratorId
200     :   ^(IDENT arrayDeclaratorList?)
201     ;
202
203 variableInitializer
204     :   arrayInitializer
205     |   expression
206     ;
207
208 arrayDeclaratorList
209     :   ^(ARRAY_DECLARATOR_LIST ARRAY_DECLARATOR*)  
210     ;
211     
212 arrayInitializer
213     :   ^(ARRAY_INITIALIZER variableInitializer*)
214     ;
215
216 genericTypeParameterList
217     :   ^(GENERIC_TYPE_PARAM_LIST genericTypeParameter+)
218     ;
219
220 genericTypeParameter
221     :   ^(IDENT bound?)
222     ;
223         
224 bound
225     :   ^(EXTENDS_BOUND_LIST type+)
226     ;
227
228 modifierList
229     :   ^(MODIFIER_LIST modifier+)
230     ;
231
232 modifier
233     :   PUBLIC
234     |   PROTECTED
235     |   ENTRY
236     |   PRIVATE
237     |   ABSTRACT
238     |   NATIVE
239     |   localModifier
240     ;
241
242 localModifierList
243     :   ^(LOCAL_MODIFIER_LIST localModifier+)
244     ;
245
246 localModifier
247     :   FINAL
248     |   STATIC
249     |   VOLATILE
250     ;
251
252 type
253     :   simpleType
254     |   objectType
255     |   VOID
256     ;
257
258 simpleType
259     :   ^(TYPE primitiveType arrayDeclaratorList?)
260     ;
261     
262 objectType
263     :   ^(TYPE qualifiedTypeIdent arrayDeclaratorList?)
264     ;
265
266 qualifiedTypeIdent
267     :   ^(QUALIFIED_TYPE_IDENT typeIdent+) 
268     ;
269
270 typeIdent
271     :   ^(IDENT genericTypeArgumentList?)
272     ;
273
274 primitiveType
275     :   BOOLEAN     { $start.symbol = new Symbol(symtab, "bool_primitive", symtab.resolveBuiltinType("bool")); }
276     |   CHAR        { $start.symbol = new Symbol(symtab, "char_primitive", symtab.resolveBuiltinType("char")); }
277     |   BYTE        { $start.symbol = new Symbol(symtab, "byte_primitive", symtab.resolveBuiltinType("char")); }
278     |   SHORT       { $start.symbol = new Symbol(symtab, "short_primitive", symtab.resolveBuiltinType("short")); }
279     |   INT         { $start.symbol = new Symbol(symtab, "int_primitive", symtab.resolveBuiltinType("int")); }
280     |   LONG        { $start.symbol = new Symbol(symtab, "long_primitive", symtab.resolveBuiltinType("long")); }
281     |   FLOAT       { $start.symbol = new Symbol(symtab, "float_primitive", symtab.resolveBuiltinType("float")); }
282     |   DOUBLE      { $start.symbol = new Symbol(symtab, "double_primitive", symtab.resolveBuiltinType("double")); }
283     ;
284
285 genericTypeArgumentList
286     :   ^(GENERIC_TYPE_ARG_LIST genericTypeArgument+)
287     ;
288     
289 genericTypeArgument
290     :   type
291     |   '?'
292     ;
293
294 formalParameterList
295     :   ^(FORMAL_PARAM_LIST formalParameterStandardDecl* formalParameterVarargDecl?) 
296     ;
297     
298 formalParameterStandardDecl
299     :   ^(FORMAL_PARAM_STD_DECL localModifierList? type variableDeclaratorId)
300     ;
301     
302 formalParameterVarargDecl
303     :   ^(FORMAL_PARAM_VARARG_DECL localModifierList? type variableDeclaratorId)
304     ;
305     
306 // FIXME: is this rule right? Verify that this is ok, I expected something like:
307 // IDENT (^('.' qualifiedIdentifier IDENT))*
308 qualifiedIdentifier
309     :   IDENT
310     |   ^('.' qualifiedIdentifier IDENT)
311     ;
312     
313 block
314     :   ^(BLOCK (blockStatement)*)
315     ;
316     
317 blockStatement
318     :   localVariableDeclaration
319     |   statement
320     ;
321     
322 localVariableDeclaration
323     :   ^(PRIMITIVE_VAR_DECLARATION localModifierList? simpleType variableDeclaratorList)
324     |   ^(OBJECT_VAR_DECLARATION localModifierList? objectType variableDeclaratorList)
325     ;
326
327 statement
328     : nonBlockStatement
329     | block
330     ;
331
332 nonBlockStatement
333     :   ^(ASSERT expression expression?)
334     |   ^(IF parenthesizedExpression block block?)
335     |   ^(FOR forInit? FOR_EXPR expression? FOR_UPDATE expression* block)
336     |   ^(FOR_EACH localModifierList? type IDENT expression block) 
337     |   ^(WHILE parenthesizedExpression block)
338     |   ^(DO block parenthesizedExpression)
339     |   ^(SWITCH parenthesizedExpression switchCaseLabel*)
340     |   ^(RETURN expression?)
341     |   ^(THROW expression)
342     |   ^(BREAK IDENT?) {
343             if ($IDENT != null) {
344                 translator.error(this, "Labeled break not supported yet, ignoring.", $IDENT);
345             }
346         }
347     |   ^(CONTINUE IDENT?) {
348             if ($IDENT != null) {
349                 translator.error(this, "Labeled continue not supported yet, ignoring.", $IDENT);
350             }
351         }
352     |   ^(LABELED_STATEMENT IDENT statement)
353     |   expression
354     |   ^('delete' qualifiedIdentifier)
355     |   ^(EMBED STRING_LITERAL EMBED_BLOCK)
356     |   ';' // Empty statement.
357     ;
358         
359 switchCaseLabel
360     :   ^(CASE expression blockStatement*)
361     |   ^(DEFAULT blockStatement*)
362     ;
363     
364 forInit
365     :   localVariableDeclaration 
366     |   expression+
367     ;
368     
369 // EXPRESSIONS
370
371 parenthesizedExpression
372     :   ^(PAREN_EXPR expression)
373     ;
374     
375 expression
376     :   ^(EXPR expr)
377     ;
378
379 expr
380     :   ^(ASSIGNMENT expr expr)
381     |   ^(PLUS_EQUALS expr expr)
382     |   ^(MINUS_EQUALS expr expr)
383     |   ^(TIMES_EQUALS expr expr)
384     |   ^(DIVIDE_EQUALS expr expr)
385     |   ^(AND_EQUALS expr expr)
386     |   ^(OR_EQUALS expr expr)
387     |   ^(POWER_EQUALS expr expr)
388     |   ^(MOD_EQUALS expr expr)
389     |   ^('>>>=' expr expr)
390     |   ^('>>=' expr expr)
391     |   ^('<<=' expr expr)
392     |   ^('?' expr expr expr)
393     |   ^(OR expr expr)
394     |   ^(AND expr expr)
395     |   ^(BITWISE_OR expr expr)
396     |   ^(POWER expr expr)
397     |   ^(BITWISE_AND expr expr)
398     |   ^(EQUALS expr expr)
399     |   ^(NOT_EQUALS expr expr)
400     |   ^(INSTANCEOF expr type)
401     |   ^(LTE expr expr)
402     |   ^(GTE expr expr)
403     |   ^('>>>' expr expr)
404     |   ^('>>' expr expr)
405     |   ^(GT expr expr)
406     |   ^('<<' expr expr)
407     |   ^(LT expr expr)
408     |   ^(PLUS expr expr)
409     |   ^(MINUS expr expr)
410     |   ^(TIMES expr expr)
411     |   ^(DIVIDE expr expr)
412     |   ^(MOD expr expr)
413     |   ^(UNARY_PLUS expr)
414     |   ^(UNARY_MINUS expr)
415     |   ^(PRE_INC expr)
416     |   ^(PRE_DEC expr)
417     |   ^(POST_INC expr)
418     |   ^(POST_DEC expr)
419     |   ^(TILDA expr)
420     |   ^(NOT expr)
421     |   ^(CAST_EXPR type expr)
422     |   primaryExpression
423     ;
424     
425 primaryExpression
426     :   ^(  '.' primaryExpression
427                 (   IDENT
428                 |   THIS
429                 |   SUPER
430                 )
431         )
432     |   parenthesizedExpression
433     |   IDENT
434     |   ^(METHOD_CALL primaryExpression genericTypeArgumentList? arguments)
435     |   explicitConstructorCall
436     |   ^(ARRAY_ELEMENT_ACCESS primaryExpression expression)
437     |   literal
438     |   newExpression
439     |   THIS
440     |   arrayTypeDeclarator
441     |   SUPER
442     ;
443     
444 explicitConstructorCall
445     :   ^(THIS_CONSTRUCTOR_CALL genericTypeArgumentList? arguments)
446     |   ^(SUPER_CONSTRUCTOR_CALL primaryExpression? genericTypeArgumentList? arguments)
447     ;
448
449 arrayTypeDeclarator
450     :   ^(ARRAY_DECLARATOR (arrayTypeDeclarator | qualifiedIdentifier | primitiveType))
451     ;
452
453 newExpression
454     :   ^(  STATIC_ARRAY_CREATOR
455             (   primitiveType newArrayConstruction
456             |   genericTypeArgumentList? qualifiedTypeIdent newArrayConstruction
457             )
458         )
459     |   ^('new' qualifiedTypeIdent arguments)
460     ;
461
462 newArrayConstruction
463     :   arrayDeclaratorList arrayInitializer
464     |   expression+ arrayDeclaratorList?
465     ;
466
467 arguments
468     :   ^(ARGUMENT_LIST expression*)
469     ;
470
471 literal 
472     :   HEX_LITERAL
473     |   OCTAL_LITERAL
474     |   DECIMAL_LITERAL
475     |   FLOATING_POINT_LITERAL
476     |   CHARACTER_LITERAL
477     |   STRING_LITERAL          
478     |   TRUE
479     |   FALSE
480     |   NULL 
481     ;
482