Charj: Simplified method handling, methods now registered with parents
[charm.git] / src / langs / charj / src / charj / translator / CharjSemantics.g
1 /**
2  * The semantic phase walks the tree and builds the symbol table, handles
3  * all the imports, and does the semantic checks. The resulting tree and
4  * symbol table are used by the emitter to generate the output. 
5  */
6
7 tree grammar CharjSemantics;
8
9 options {
10     backtrack = true; 
11     memoize = true;
12     tokenVocab = Charj;
13     ASTLabelType = CharjAST;
14 }
15
16 scope ScopeStack {
17     Scope current;
18 }
19
20 @header {
21 package charj.translator;
22 }
23
24 @members {
25     SymbolTable symtab = null;
26     PackageScope currentPackage = null;
27     ClassSymbol currentClass = null;
28     MethodSymbol currentMethod = null;
29     LocalScope currentLocalScope = null;
30     Translator translator;
31
32     /**
33      *  Test a list of CharjAST nodes to see if any of them has the given token
34      *  type.
35      */
36     public boolean listContainsToken(List<CharjAST> list, int tokenType) {
37         if (list == null) return false;
38         for (CharjAST node : list) {
39             if (node.token.getType() == tokenType) {
40                 return true;
41             }
42         }
43         return false;
44     }
45
46     public void importPackages(ClassSymbol cs, List<CharjAST> imports) {
47         if (imports == null) {
48             return;
49         }
50
51         for (CharjAST pkg : imports) {
52             String pkgName = input.getTokenStream().toString(
53                     pkg.getTokenStartIndex(),
54                     pkg.getTokenStopIndex());
55             // find imported class and add to cs.imports
56             PackageScope p = cs.importPackage(pkgName);
57             if (p == null) {
58                 translator.error(
59                     this, 
60                     "package " + pkgName + " not found.",
61                     pkg);
62             }
63         }
64     }
65 }
66
67
68 // Replace default ANTLR generated catch clauses with this action, allowing early failure.
69 @rulecatch {
70     catch (RecognitionException re) {
71         reportError(re);
72         throw re;
73     }
74 }
75
76
77 // Starting point for parsing a Charj file.
78 charjSource[SymbolTable _symtab] returns [ClassSymbol cs]
79 scope ScopeStack; // default scope
80 @init {
81     symtab = _symtab;
82     $ScopeStack::current = symtab.getDefaultPkg();
83 }
84     // TODO: go back to allowing multiple type definitions per file, check that
85     // there is exactly one public type and return that one.
86     :   ^(CHARJ_SOURCE 
87         (packageDeclaration)? 
88         (importDeclarations) 
89         (typeDeclaration[$importDeclarations.packageNames]))
90         { $cs = $typeDeclaration.sym; }
91     ;
92
93 // note: no new scope here--this replaces the default scope
94 packageDeclaration
95 @init { 
96     List<String> names = null; 
97 }
98     :   ^('package' qualifiedIdentifier)  {
99             String packageName = $qualifiedIdentifier.text;
100             PackageScope ps = symtab.resolvePackage(packageName);
101             if (ps == null) {
102                 ps = symtab.definePackage(packageName);
103                 symtab.addScope(ps);
104             }
105             currentPackage = ps;
106             $ScopeStack::current = ps;
107             $qualifiedIdentifier.start.symbol = ps;
108         }
109     ;
110     
111 importDeclarations returns [List<CharjAST> packageNames]
112 @init {
113         packageNames = new ArrayList<CharjAST>();
114 }
115     :   (^('import' qualifiedIdentifier './*'?)
116                 { packageNames.add($qualifiedIdentifier.start); })*
117     ;
118
119
120 typeDeclaration[List<CharjAST> imports] returns [ClassSymbol sym]
121 scope ScopeStack; // top-level type scope
122     :   ^(TYPE ('class' | chareType) IDENT
123             (^('extends' parent=type))? (^('implements' type+))? classScopeDeclaration*)
124         {
125             Scope outerScope = $ScopeStack[-1]::current;
126             $sym = new ClassSymbol(symtab, $IDENT.text, outerScope.resolveType($parent.text), outerScope);
127             outerScope.define($sym.name, $sym);
128             currentClass = $sym;
129             $sym.definition = $typeDeclaration.start;
130             $sym.definitionTokenStream = input.getTokenStream();
131             $IDENT.symbol = $sym;
132             $ScopeStack::current = $sym;
133             importPackages($sym, $imports);
134         }
135     |   ^('interface' IDENT (^('extends' type+))?  interfaceScopeDeclaration*)
136     |   ^('enum' IDENT (^('implements' type+))? enumConstant+ classScopeDeclaration*)
137     ;
138
139 chareType
140     :   'chare'
141     |   'group'
142     |   'nodegroup'
143     |   ^('chare_array' ARRAY_DIMENSION)
144     ;
145
146 enumConstant
147     :   ^(IDENT arguments?)
148     ;
149     
150 classScopeDeclaration
151 scope ScopeStack;
152     :   ^(FUNCTION_METHOD_DECL m=modifierList? g=genericTypeParameterList? 
153             ty=type IDENT f=formalParameterList a=arrayDeclaratorList? 
154             b=block?)
155         {
156             ClassSymbol returnType = currentClass.resolveType($ty.text);
157             MethodSymbol sym = new MethodSymbol(symtab, $IDENT.text, currentClass, returnType);
158             currentMethod = sym;
159             sym.definition = $classScopeDeclaration.start;
160             sym.definitionTokenStream = input.getTokenStream();
161             currentClass.members.put($IDENT.text, sym);
162             $FUNCTION_METHOD_DECL.symbol = sym;
163         }
164     |   ^(PRIMITIVE_VAR_DECLARATION modifierList? simpleType variableDeclaratorList)
165     |   ^(OBJECT_VAR_DECLARATION modifierList? objectType variableDeclaratorList)
166     |   ^(CONSTRUCTOR_DECL m=modifierList? g=genericTypeParameterList? IDENT f=formalParameterList 
167             b=block)
168     ;
169     
170 interfaceScopeDeclaration
171     :   ^(FUNCTION_METHOD_DECL modifierList? genericTypeParameterList? 
172             type IDENT formalParameterList arrayDeclaratorList?)
173         // Interface constant declarations have been switched to variable
174         // declarations by Charj.g; the parser has already checked that
175         // there's an obligatory initializer.
176     |   ^(PRIMITIVE_VAR_DECLARATION modifierList? simpleType variableDeclaratorList)
177     |   ^(OBJECT_VAR_DECLARATION modifierList? objectType variableDeclaratorList)
178     ;
179
180 variableDeclaratorList
181     :   ^(VAR_DECLARATOR_LIST variableDeclarator+)
182     ;
183
184 variableDeclarator
185     :   ^(VAR_DECLARATOR variableDeclaratorId variableInitializer?)
186     ;
187     
188 variableDeclaratorId
189     :   ^(IDENT arrayDeclaratorList?)
190     ;
191
192 variableInitializer
193     :   arrayInitializer
194     |   expression
195     ;
196
197 arrayDeclaratorList
198     :   ^(ARRAY_DECLARATOR_LIST ARRAY_DECLARATOR*)  
199     ;
200     
201 arrayInitializer
202     :   ^(ARRAY_INITIALIZER variableInitializer*)
203     ;
204
205 genericTypeParameterList
206     :   ^(GENERIC_TYPE_PARAM_LIST genericTypeParameter+)
207     ;
208
209 genericTypeParameter
210     :   ^(IDENT bound?)
211     ;
212         
213 bound
214     :   ^(EXTENDS_BOUND_LIST type+)
215     ;
216
217 modifierList
218     :   ^(MODIFIER_LIST modifier+)
219     ;
220
221 modifier
222     :   'public'
223     |   'protected'
224     |   'private'
225     |   'entry'
226     |   'abstract'
227     |   'native'
228     |   localModifier
229     ;
230
231 localModifierList
232     :   ^(LOCAL_MODIFIER_LIST localModifier+)
233     ;
234
235 localModifier
236     :   'final'
237     |   'static'
238     |   'volatile'
239     ;
240
241 type
242     :   simpleType
243     |   objectType 
244     ;
245
246 simpleType
247     :   ^(TYPE primitiveType arrayDeclaratorList?)
248     ;
249     
250 objectType
251     :   ^(TYPE qualifiedTypeIdent arrayDeclaratorList?)
252     ;
253
254 qualifiedTypeIdent
255     :   ^(QUALIFIED_TYPE_IDENT typeIdent+) 
256     ;
257
258 typeIdent
259     :   ^(IDENT genericTypeArgumentList?)
260     ;
261
262 primitiveType
263     :   'boolean'     { $start.symbol = new Symbol(symtab, "bool_primitive", symtab.resolveBuiltinType("bool")); }
264     |   'char'        { $start.symbol = new Symbol(symtab, "char_primitive", symtab.resolveBuiltinType("char")); }
265     |   'byte'        { $start.symbol = new Symbol(symtab, "byte_primitive", symtab.resolveBuiltinType("char")); }
266     |   'short'       { $start.symbol = new Symbol(symtab, "short_primitive", symtab.resolveBuiltinType("short")); }
267     |   'int'         { $start.symbol = new Symbol(symtab, "int_primitive", symtab.resolveBuiltinType("int")); }
268     |   'long'        { $start.symbol = new Symbol(symtab, "long_primitive", symtab.resolveBuiltinType("long")); }
269     |   'float'       { $start.symbol = new Symbol(symtab, "float_primitive", symtab.resolveBuiltinType("float")); }
270     |   'double'      { $start.symbol = new Symbol(symtab, "double_primitive", symtab.resolveBuiltinType("double")); }
271     ;
272
273 genericTypeArgumentList
274     :   ^(GENERIC_TYPE_ARG_LIST genericTypeArgument+)
275     ;
276     
277 genericTypeArgument
278     :   type
279     |   '?'
280     ;
281
282 formalParameterList
283     :   ^(FORMAL_PARAM_LIST formalParameterStandardDecl* formalParameterVarargDecl?) 
284     ;
285     
286 formalParameterStandardDecl
287     :   ^(FORMAL_PARAM_STD_DECL localModifierList? type variableDeclaratorId)
288     ;
289     
290 formalParameterVarargDecl
291     :   ^(FORMAL_PARAM_VARARG_DECL localModifierList? type variableDeclaratorId)
292     ;
293     
294 // FIXME: is this rule right? Verify that this is ok, I expected something like:
295 // IDENT (^('.' qualifiedIdentifier IDENT))*
296 qualifiedIdentifier
297     :   IDENT
298     |   ^('.' qualifiedIdentifier IDENT)
299     ;
300     
301 block
302     :   ^(BLOCK (blockStatement)*)
303     ;
304     
305 blockStatement
306     :   localVariableDeclaration
307     |   statement
308     ;
309     
310 localVariableDeclaration
311     :   ^(PRIMITIVE_VAR_DECLARATION localModifierList? simpleType variableDeclaratorList)
312     |   ^(OBJECT_VAR_DECLARATION localModifierList? objectType variableDeclaratorList)
313     ;
314
315 statement
316     :   block
317     |   ^('assert' expression expression?)
318     |   ^('if' parenthesizedExpression statement statement?)
319     |   ^('for' forInit? FOR_EXPR expression? FOR_UPDATE expression* statement)
320     |   ^(FOR_EACH localModifierList? type IDENT expression statement) 
321     |   ^('while' parenthesizedExpression statement)
322     |   ^('do' statement parenthesizedExpression)
323     |   ^('switch' parenthesizedExpression switchCaseLabel*)
324     |   ^('return' expression?)
325     |   ^('throw' expression)
326     |   ^('break' IDENT?) {
327             if ($IDENT != null) {
328                 translator.error(this, "Labeled break not supported yet, ignoring.", $IDENT);
329             }
330         }
331     |   ^('continue' IDENT?) {
332             if ($IDENT != null) {
333                 translator.error(this, "Labeled continue not supported yet, ignoring.", $IDENT);
334             }
335         }
336     |   ^(LABELED_STATEMENT IDENT statement)
337     |   expression
338     |   ^('embed' STRING_LITERAL EMBED_BLOCK)
339     |   ';' // Empty statement.
340     ;
341         
342 switchCaseLabel
343     :   ^('case' expression blockStatement*)
344     |   ^('default' blockStatement*)
345     ;
346     
347 forInit
348     :   localVariableDeclaration 
349     |   expression+
350     ;
351     
352 // EXPRESSIONS
353
354 parenthesizedExpression
355     :   ^(PAREN_EXPR expression)
356     ;
357     
358 expression
359     :   ^(EXPR expr)
360     ;
361
362 expr
363     :   ^('=' expr expr)
364     |   ^('+=' expr expr)
365     |   ^('-=' expr expr)
366     |   ^('*=' expr expr)
367     |   ^('/=' expr expr)
368     |   ^('&=' expr expr)
369     |   ^('|=' expr expr)
370     |   ^('^=' expr expr)
371     |   ^('%=' expr expr)
372     |   ^('>>>=' expr expr)
373     |   ^('>>=' expr expr)
374     |   ^('<<=' expr expr)
375     |   ^('?' expr expr expr)
376     |   ^('||' expr expr)
377     |   ^('&&' expr expr)
378     |   ^('|' expr expr)
379     |   ^('^' expr expr)
380     |   ^('&' expr expr)
381     |   ^('==' expr expr)
382     |   ^('!=' expr expr)
383     |   ^('instanceof' expr type)
384     |   ^('<=' expr expr)
385     |   ^('>=' expr expr)
386     |   ^('>>>' expr expr)
387     |   ^('>>' expr expr)
388     |   ^('>' expr expr)
389     |   ^('<<' expr expr)
390     |   ^('<' expr expr)
391     |   ^('+' expr expr)
392     |   ^('-' expr expr)
393     |   ^('*' expr expr)
394     |   ^('/' expr expr)
395     |   ^('%' expr expr)
396     |   ^(UNARY_PLUS expr)
397     |   ^(UNARY_MINUS expr)
398     |   ^(PRE_INC expr)
399     |   ^(PRE_DEC expr)
400     |   ^(POST_INC expr)
401     |   ^(POST_DEC expr)
402     |   ^('~' expr)
403     |   ^('!' expr)
404     |   ^(CAST_EXPR type expr)
405     |   primaryExpression
406     ;
407     
408 primaryExpression
409     :   ^(  '.' primaryExpression
410                 (   IDENT
411                 |   'this'
412                 |   'super'
413                 )
414         )
415     |   parenthesizedExpression
416     |   IDENT
417     |   ^(METHOD_CALL primaryExpression genericTypeArgumentList? arguments)
418     |   explicitConstructorCall
419     |   ^(ARRAY_ELEMENT_ACCESS primaryExpression expression)
420     |   literal
421     |   newExpression
422     |   'this'
423     |   arrayTypeDeclarator
424     |   'super'
425     ;
426     
427 explicitConstructorCall
428     :   ^(THIS_CONSTRUCTOR_CALL genericTypeArgumentList? arguments)
429     |   ^(SUPER_CONSTRUCTOR_CALL primaryExpression? genericTypeArgumentList? arguments)
430     ;
431
432 arrayTypeDeclarator
433     :   ^(ARRAY_DECLARATOR (arrayTypeDeclarator | qualifiedIdentifier | primitiveType))
434     ;
435
436 newExpression
437     :   ^(  STATIC_ARRAY_CREATOR
438             (   primitiveType newArrayConstruction
439             |   genericTypeArgumentList? qualifiedTypeIdent newArrayConstruction
440             )
441         )
442     ;
443
444 newArrayConstruction
445     :   arrayDeclaratorList arrayInitializer
446     |   expression+ arrayDeclaratorList?
447     ;
448
449 arguments
450     :   ^(ARGUMENT_LIST expression*)
451     ;
452
453 literal 
454     :   HEX_LITERAL
455     |   OCTAL_LITERAL
456     |   DECIMAL_LITERAL
457     |   FLOATING_POINT_LITERAL
458     |   CHARACTER_LITERAL
459     |   STRING_LITERAL          
460     |   'true'
461     |   'false'
462     |   'null'
463     ;
464