Charj: fix namespace handling to use symbol table correctly
[charm.git] / src / langs / charj / src / charj / translator / CharjSemantics.g
1 /**
2  * The semantic phase walks the tree and builds the symbol table, handles
3  * all the imports, and does the semantic checks. The resulting tree and
4  * symbol table are used by the emitter to generate the output. 
5  */
6
7 tree grammar CharjSemantics;
8
9 options {
10     backtrack = true; 
11     memoize = true;
12     tokenVocab = Charj;
13     ASTLabelType = CharjAST;
14 }
15
16 scope ScopeStack {
17     Scope current;
18 }
19
20 @header {
21 package charj.translator;
22 }
23
24 @members {
25     SymbolTable symtab = null;
26     PackageScope currentPackage = null;
27     ClassSymbol currentClass = null;
28     MethodSymbol currentMethod = null;
29     LocalScope currentLocalScope = null;
30     Translator translator;
31
32     /**
33      *  Test a list of CharjAST nodes to see if any of them has the given token
34      *  type.
35      */
36     public boolean listContainsToken(List<CharjAST> list, int tokenType) {
37         if (list == null) return false;
38         for (CharjAST node : list) {
39             if (node.token.getType() == tokenType) {
40                 return true;
41             }
42         }
43         return false;
44     }
45
46     public void importPackages(ClassSymbol cs, List<CharjAST> imports) {
47         if (imports == null) {
48             return;
49         }
50
51         for (CharjAST pkg : imports) {
52             String pkgName = input.getTokenStream().toString(
53                     pkg.getTokenStartIndex(),
54                     pkg.getTokenStopIndex());
55             // find imported class and add to cs.imports
56             PackageScope p = cs.importPackage(pkgName);
57             if (p == null) {
58                 translator.error(
59                     this, 
60                     "package " + pkgName + " not found.",
61                     pkg);
62             }
63         }
64     }
65 }
66
67
68 // Replace default ANTLR generated catch clauses with this action, allowing early failure.
69 @rulecatch {
70     catch (RecognitionException re) {
71         reportError(re);
72         throw re;
73     }
74 }
75
76
77 // Starting point for parsing a Charj file.
78 charjSource[SymbolTable _symtab] returns [ClassSymbol cs]
79 scope ScopeStack; // default scope
80 @init {
81     symtab = _symtab;
82     $ScopeStack::current = symtab.getDefaultPkg();
83 }
84     // TODO: go back to allowing multiple type definitions per file, check that
85     // there is exactly one public type and return that one.
86     :   ^(CHARJ_SOURCE 
87         (packageDeclaration)? 
88         (importDeclarations) 
89         (typeDeclaration[$importDeclarations.packageNames]))
90         { $cs = $typeDeclaration.sym; }
91     ;
92
93 // note: no new scope here--this replaces the default scope
94 packageDeclaration
95 @init { 
96     List<String> names = null; 
97 }
98     :   ^('package' qualifiedIdentifier)  {
99             String packageName = $qualifiedIdentifier.text;
100             PackageScope ps = symtab.resolvePackage(packageName);
101             if (ps == null) {
102                 ps = symtab.definePackage(packageName);
103                 symtab.addScope(ps);
104             }
105             currentPackage = ps;
106             $ScopeStack::current = ps;
107             $qualifiedIdentifier.start.symbol = ps;
108         }
109     ;
110     
111 importDeclarations returns [List<CharjAST> packageNames]
112 @init {
113         packageNames = new ArrayList<CharjAST>();
114 }
115     :   (^('import' qualifiedIdentifier './*'?)
116                 { packageNames.add($qualifiedIdentifier.start); })*
117     ;
118
119
120 typeDeclaration[List<CharjAST> imports] returns [ClassSymbol sym]
121 scope ScopeStack; // top-level type scope
122     :   ^((('class')|(chareType)|('chare_array' ARRAY_DIMENSION)) IDENT
123             (^('extends' parent=type))? (^('implements' type+))? classScopeDeclaration*)
124         {
125             Scope outerScope = $ScopeStack[-1]::current;
126             $sym = new ClassSymbol(symtab, $IDENT.text, outerScope.resolveType($parent.text), outerScope);
127             outerScope.define($sym.name, $sym);
128             currentClass = $sym;
129             $sym.definition = $typeDeclaration.start;
130             $sym.definitionTokenStream = input.getTokenStream();
131             $IDENT.symbol = $sym;
132             $ScopeStack::current = $sym;
133             importPackages($sym, $imports);
134         }
135     |   ^('interface' IDENT (^('extends' type+))?  interfaceScopeDeclaration*)
136     |   ^('enum' IDENT (^('implements' type+))? enumConstant+ classScopeDeclaration*)
137     ;
138
139 chareType
140     :   'chare'
141     |   'group'
142     |   'nodegroup'
143     ;
144
145 enumConstant
146     :   ^(IDENT arguments?)
147     ;
148     
149 classScopeDeclaration
150     :   ^(FUNCTION_METHOD_DECL m=modifierList? g=genericTypeParameterList? 
151             ty=type IDENT f=formalParameterList a=arrayDeclaratorList? 
152             b=block?)
153     |   ^(VOID_METHOD_DECL m=modifierList? g=genericTypeParameterList? IDENT 
154             f=formalParameterList b=block?)
155     |   ^(PRIMITIVE_VAR_DECLARATION modifierList? simpleType variableDeclaratorList)
156     |   ^(OBJECT_VAR_DECLARATION modifierList? objectType variableDeclaratorList)
157     |   ^(CONSTRUCTOR_DECL m=modifierList? g=genericTypeParameterList? IDENT f=formalParameterList 
158             b=block)
159     ;
160     
161 interfaceScopeDeclaration
162     :   ^(FUNCTION_METHOD_DECL modifierList? genericTypeParameterList? 
163             type IDENT formalParameterList arrayDeclaratorList?)
164     |   ^(VOID_METHOD_DECL modifierList? genericTypeParameterList? IDENT formalParameterList)
165         // Interface constant declarations have been switched to variable
166         // declarations by Charj.g; the parser has already checked that
167         // there's an obligatory initializer.
168     |   ^(PRIMITIVE_VAR_DECLARATION modifierList? simpleType variableDeclaratorList)
169     |   ^(OBJECT_VAR_DECLARATION modifierList? objectType variableDeclaratorList)
170     ;
171
172 variableDeclaratorList
173     :   ^(VAR_DECLARATOR_LIST variableDeclarator+)
174     ;
175
176 variableDeclarator
177     :   ^(VAR_DECLARATOR variableDeclaratorId variableInitializer?)
178     ;
179     
180 variableDeclaratorId
181     :   ^(IDENT arrayDeclaratorList?)
182     ;
183
184 variableInitializer
185     :   arrayInitializer
186     |   expression
187     ;
188
189 arrayDeclaratorList
190     :   ^(ARRAY_DECLARATOR_LIST ARRAY_DECLARATOR*)  
191     ;
192     
193 arrayInitializer
194     :   ^(ARRAY_INITIALIZER variableInitializer*)
195     ;
196
197 genericTypeParameterList
198     :   ^(GENERIC_TYPE_PARAM_LIST genericTypeParameter+)
199     ;
200
201 genericTypeParameter
202     :   ^(IDENT bound?)
203     ;
204         
205 bound
206     :   ^(EXTENDS_BOUND_LIST type+)
207     ;
208
209 modifierList
210     :   ^(MODIFIER_LIST modifier+)
211     ;
212
213 modifier
214     :   'public'
215     |   'protected'
216     |   'private'
217     |   'entry'
218     |   'abstract'
219     |   'native'
220     |   localModifier
221     ;
222
223 localModifierList
224     :   ^(LOCAL_MODIFIER_LIST localModifier+)
225     ;
226
227 localModifier
228     :   'final'
229     |   'static'
230     |   'volatile'
231     ;
232
233 type
234     :   simpleType
235     |   objectType 
236     ;
237
238 simpleType
239     :   ^(TYPE primitiveType arrayDeclaratorList?)
240     ;
241     
242 objectType
243     :   ^(TYPE qualifiedTypeIdent arrayDeclaratorList?)
244     ;
245
246 qualifiedTypeIdent
247     :   ^(QUALIFIED_TYPE_IDENT typeIdent+) 
248     ;
249
250 typeIdent
251     :   ^(IDENT genericTypeArgumentList?)
252     ;
253
254 primitiveType
255     :   'boolean'     { $start.symbol = new Symbol(symtab, "bool_primitive", symtab.resolveBuiltinType("bool")); }
256     |   'char'        { $start.symbol = new Symbol(symtab, "char_primitive", symtab.resolveBuiltinType("char")); }
257     |   'byte'        { $start.symbol = new Symbol(symtab, "byte_primitive", symtab.resolveBuiltinType("char")); }
258     |   'short'       { $start.symbol = new Symbol(symtab, "short_primitive", symtab.resolveBuiltinType("short")); }
259     |   'int'         { $start.symbol = new Symbol(symtab, "int_primitive", symtab.resolveBuiltinType("int")); }
260     |   'long'        { $start.symbol = new Symbol(symtab, "long_primitive", symtab.resolveBuiltinType("long")); }
261     |   'float'       { $start.symbol = new Symbol(symtab, "float_primitive", symtab.resolveBuiltinType("float")); }
262     |   'double'      { $start.symbol = new Symbol(symtab, "double_primitive", symtab.resolveBuiltinType("double")); }
263     ;
264
265 genericTypeArgumentList
266     :   ^(GENERIC_TYPE_ARG_LIST genericTypeArgument+)
267     ;
268     
269 genericTypeArgument
270     :   type
271     |   '?'
272     ;
273
274 formalParameterList
275     :   ^(FORMAL_PARAM_LIST formalParameterStandardDecl* formalParameterVarargDecl?) 
276     ;
277     
278 formalParameterStandardDecl
279     :   ^(FORMAL_PARAM_STD_DECL localModifierList? type variableDeclaratorId)
280     ;
281     
282 formalParameterVarargDecl
283     :   ^(FORMAL_PARAM_VARARG_DECL localModifierList? type variableDeclaratorId)
284     ;
285     
286 // FIXME: is this rule right? Verify that this is ok, I expected something like:
287 // IDENT (^('.' qualifiedIdentifier IDENT))*
288 qualifiedIdentifier
289     :   IDENT
290     |   ^('.' qualifiedIdentifier IDENT)
291     ;
292     
293 block
294     :   ^(BLOCK (blockStatement)*)
295     ;
296     
297 blockStatement
298     :   localVariableDeclaration
299     |   statement
300     ;
301     
302 localVariableDeclaration
303     :   ^(PRIMITIVE_VAR_DECLARATION localModifierList? simpleType variableDeclaratorList)
304     |   ^(OBJECT_VAR_DECLARATION localModifierList? objectType variableDeclaratorList)
305     ;
306
307 statement
308     :   block
309     |   ^('assert' expression expression?)
310     |   ^('if' parenthesizedExpression statement statement?)
311     |   ^('for' forInit? FOR_EXPR expression? FOR_UPDATE expression* statement)
312     |   ^(FOR_EACH localModifierList? type IDENT expression statement) 
313     |   ^('while' parenthesizedExpression statement)
314     |   ^('do' statement parenthesizedExpression)
315     |   ^('switch' parenthesizedExpression switchCaseLabel*)
316     |   ^('return' expression?)
317     |   ^('throw' expression)
318     |   ^('break' IDENT?) {
319             if ($IDENT != null) {
320                 translator.error(this, "Labeled break not supported yet, ignoring.", $IDENT);
321             }
322         }
323     |   ^('continue' IDENT?) {
324             if ($IDENT != null) {
325                 translator.error(this, "Labeled continue not supported yet, ignoring.", $IDENT);
326             }
327         }
328     |   ^(LABELED_STATEMENT IDENT statement)
329     |   expression
330     |   ^('embed' STRING_LITERAL EMBED_BLOCK)
331     |   ';' // Empty statement.
332     ;
333         
334 switchCaseLabel
335     :   ^('case' expression blockStatement*)
336     |   ^('default' blockStatement*)
337     ;
338     
339 forInit
340     :   localVariableDeclaration 
341     |   expression+
342     ;
343     
344 // EXPRESSIONS
345
346 parenthesizedExpression
347     :   ^(PAREN_EXPR expression)
348     ;
349     
350 expression
351     :   ^(EXPR expr)
352     ;
353
354 expr
355     :   ^('=' expr expr)
356     |   ^('+=' expr expr)
357     |   ^('-=' expr expr)
358     |   ^('*=' expr expr)
359     |   ^('/=' expr expr)
360     |   ^('&=' expr expr)
361     |   ^('|=' expr expr)
362     |   ^('^=' expr expr)
363     |   ^('%=' expr expr)
364     |   ^('>>>=' expr expr)
365     |   ^('>>=' expr expr)
366     |   ^('<<=' expr expr)
367     |   ^('?' expr expr expr)
368     |   ^('||' expr expr)
369     |   ^('&&' expr expr)
370     |   ^('|' expr expr)
371     |   ^('^' expr expr)
372     |   ^('&' expr expr)
373     |   ^('==' expr expr)
374     |   ^('!=' expr expr)
375     |   ^('instanceof' expr type)
376     |   ^('<=' expr expr)
377     |   ^('>=' expr expr)
378     |   ^('>>>' expr expr)
379     |   ^('>>' expr expr)
380     |   ^('>' expr expr)
381     |   ^('<<' expr expr)
382     |   ^('<' expr expr)
383     |   ^('+' expr expr)
384     |   ^('-' expr expr)
385     |   ^('*' expr expr)
386     |   ^('/' expr expr)
387     |   ^('%' expr expr)
388     |   ^(UNARY_PLUS expr)
389     |   ^(UNARY_MINUS expr)
390     |   ^(PRE_INC expr)
391     |   ^(PRE_DEC expr)
392     |   ^(POST_INC expr)
393     |   ^(POST_DEC expr)
394     |   ^('~' expr)
395     |   ^('!' expr)
396     |   ^(CAST_EXPR type expr)
397     |   primaryExpression
398     ;
399     
400 primaryExpression
401     :   ^(  '.' primaryExpression
402                 (   IDENT
403                 |   'this'
404                 |   'super'
405                 )
406         )
407     |   parenthesizedExpression
408     |   IDENT
409     |   ^(METHOD_CALL primaryExpression genericTypeArgumentList? arguments)
410     |   explicitConstructorCall
411     |   ^(ARRAY_ELEMENT_ACCESS primaryExpression expression)
412     |   literal
413     |   newExpression
414     |   'this'
415     |   arrayTypeDeclarator
416     |   'super'
417     ;
418     
419 explicitConstructorCall
420     :   ^(THIS_CONSTRUCTOR_CALL genericTypeArgumentList? arguments)
421     |   ^(SUPER_CONSTRUCTOR_CALL primaryExpression? genericTypeArgumentList? arguments)
422     ;
423
424 arrayTypeDeclarator
425     :   ^(ARRAY_DECLARATOR (arrayTypeDeclarator | qualifiedIdentifier | primitiveType))
426     ;
427
428 newExpression
429     :   ^(  STATIC_ARRAY_CREATOR
430             (   primitiveType newArrayConstruction
431             |   genericTypeArgumentList? qualifiedTypeIdent newArrayConstruction
432             )
433         )
434     ;
435
436 newArrayConstruction
437     :   arrayDeclaratorList arrayInitializer
438     |   expression+ arrayDeclaratorList?
439     ;
440
441 arguments
442     :   ^(ARGUMENT_LIST expression*)
443     ;
444
445 literal 
446     :   HEX_LITERAL
447     |   OCTAL_LITERAL
448     |   DECIMAL_LITERAL
449     |   FLOATING_POINT_LITERAL
450     |   CHARACTER_LITERAL
451     |   STRING_LITERAL          
452     |   'true'
453     |   'false'
454     |   'null'
455     ;
456