improved handling of declaration modifiers
[charm.git] / src / langs / charj / src / charj / translator / CharjSemantics.g
1 /**
2  * The semantic phase walks the tree and builds the symbol table, handles
3  * all the imports, and does the semantic checks. The resulting tree and
4  * symbol table are used by the emitter to generate the output. 
5  */
6
7 tree grammar CharjSemantics;
8
9 options {
10     backtrack = true; 
11     memoize = true;
12     tokenVocab = Charj;
13     ASTLabelType = CharjAST;
14 }
15
16 scope ScopeStack {
17     Scope current;
18 }
19
20 @header {
21 package charj.translator;
22 }
23
24 @members {
25     SymbolTable symtab = null;
26     PackageScope currentPackage = null;
27     ClassSymbol currentClass = null;
28     MethodSymbol currentMethod = null;
29     LocalScope currentLocalScope = null;
30     Translator translator;
31
32     /**
33      *  Test a list of CharjAST nodes to see if any of them has the given token
34      *  type.
35      */
36     public boolean listContainsToken(List<CharjAST> list, int tokenType) {
37         if (list == null) return false;
38         for (CharjAST node : list) {
39             if (node.token.getType() == tokenType) {
40                 return true;
41             }
42         }
43         return false;
44     }
45
46     public void importPackages(ClassSymbol cs, List<CharjAST> imports) {
47         if (imports == null) {
48             return;
49         }
50
51         for (CharjAST pkg : imports) {
52             String pkgName = input.getTokenStream().toString(
53                     pkg.getTokenStartIndex(),
54                     pkg.getTokenStopIndex());
55             // find imported class and add to cs.imports
56             PackageScope p = cs.importPackage(pkgName);
57             if (p == null) {
58                 translator.error(
59                     this, 
60                     "package " + pkgName + " not found.",
61                     pkg);
62             }
63         }
64     }
65 }
66
67
68 // Replace default ANTLR generated catch clauses with this action, allowing early failure.
69 @rulecatch {
70     catch (RecognitionException re) {
71         reportError(re);
72         throw re;
73     }
74 }
75
76
77 // Starting point for parsing a Charj file.
78 charjSource[SymbolTable _symtab] returns [ClassSymbol cs]
79 scope ScopeStack; // default scope
80 @init {
81     symtab = _symtab;
82     $ScopeStack::current = symtab.getDefaultPkg();
83 }
84     // TODO: go back to allowing multiple type definitions per file, check that
85     // there is exactly one public type and return that one.
86     :   ^(CHARJ_SOURCE 
87         (packageDeclaration)? 
88         (importDeclarations) 
89         (typeDeclaration[$importDeclarations.packageNames]))
90         { $cs = $typeDeclaration.sym; }
91     ;
92
93 // note: no new scope here--this replaces the default scope
94 packageDeclaration
95 @init { 
96     List<String> names = null; 
97 }
98     :   ^('package' qualifiedIdentifier)  {
99             String packageName = $qualifiedIdentifier.text;
100             PackageScope ps = symtab.resolvePackage(packageName);
101             if (ps == null) {
102                 ps = symtab.definePackage(packageName);
103                 symtab.addScope(ps);
104             }
105             currentPackage = ps;
106             $ScopeStack::current = ps;
107             $qualifiedIdentifier.start.symbol = ps;
108         }
109     ;
110     
111 importDeclarations returns [List<CharjAST> packageNames]
112 @init {
113         packageNames = new ArrayList<CharjAST>();
114 }
115     :   (^('import' qualifiedIdentifier './*'?)
116                 { packageNames.add($qualifiedIdentifier.start); })*
117     ;
118
119
120 typeDeclaration[List<CharjAST> imports] returns [ClassSymbol sym]
121 scope ScopeStack; // top-level type scope
122     :   ^('class' IDENT (^('extends' type))? (^('implements' type+))? classScopeDeclaration*)
123         {
124             Scope outerScope = $ScopeStack[-1]::current;
125             $sym = new ClassSymbol(symtab, $IDENT.text, null, outerScope);
126             outerScope.define($sym.name, $sym);
127             currentClass = $sym;
128             $sym.definition = $typeDeclaration.start;
129             $sym.definitionTokenStream = input.getTokenStream();
130             $IDENT.symbol = $sym;
131             $ScopeStack::current = $sym;
132             importPackages($sym, $imports);
133         }
134     |   ^('interface' IDENT (^('extends' type+))?  interfaceScopeDeclaration*)
135     |   ^('enum' IDENT (^('implements' type+))? enumConstant+ classScopeDeclaration*)
136     ;
137
138 enumConstant
139     :   ^(IDENT arguments?)
140     ;
141     
142 classScopeDeclaration
143     :   ^(FUNCTION_METHOD_DECL m=modifierList? g=genericTypeParameterList? 
144             ty=type IDENT f=formalParameterList a=arrayDeclaratorList? 
145             b=block?)
146     |   ^(VOID_METHOD_DECL m=modifierList? g=genericTypeParameterList? IDENT 
147             f=formalParameterList b=block?)
148     |   ^(PRIMITIVE_VAR_DECLARATION modifierList? simpleType variableDeclaratorList)
149     |   ^(OBJECT_VAR_DECLARATION modifierList? objectType variableDeclaratorList)
150     |   ^(CONSTRUCTOR_DECL m=modifierList? g=genericTypeParameterList? IDENT f=formalParameterList 
151             b=block)
152     ;
153     
154 interfaceScopeDeclaration
155     :   ^(FUNCTION_METHOD_DECL modifierList? genericTypeParameterList? 
156             type IDENT formalParameterList arrayDeclaratorList?)
157     |   ^(VOID_METHOD_DECL modifierList? genericTypeParameterList? IDENT formalParameterList)
158         // Interface constant declarations have been switched to variable
159         // declarations by Charj.g; the parser has already checked that
160         // there's an obligatory initializer.
161     |   ^(PRIMITIVE_VAR_DECLARATION modifierList? simpleType variableDeclaratorList)
162     |   ^(OBJECT_VAR_DECLARATION modifierList? objectType variableDeclaratorList)
163     ;
164
165 variableDeclaratorList
166     :   ^(VAR_DECLARATOR_LIST variableDeclarator+)
167     ;
168
169 variableDeclarator
170     :   ^(VAR_DECLARATOR variableDeclaratorId variableInitializer?)
171     ;
172     
173 variableDeclaratorId
174     :   ^(IDENT arrayDeclaratorList?)
175     ;
176
177 variableInitializer
178     :   arrayInitializer
179     |   expression
180     ;
181
182 arrayDeclaratorList
183     :   ^(ARRAY_DECLARATOR_LIST ARRAY_DECLARATOR*)  
184     ;
185     
186 arrayInitializer
187     :   ^(ARRAY_INITIALIZER variableInitializer*)
188     ;
189
190 genericTypeParameterList
191     :   ^(GENERIC_TYPE_PARAM_LIST genericTypeParameter+)
192     ;
193
194 genericTypeParameter
195     :   ^(IDENT bound?)
196     ;
197         
198 bound
199     :   ^(EXTENDS_BOUND_LIST type+)
200     ;
201
202 modifierList
203     :   ^(MODIFIER_LIST modifier+)
204     ;
205
206 modifier
207     :   'public'
208     |   'protected'
209     |   'private'
210     |   'entry'
211     |   'abstract'
212     |   'native'
213     |   localModifier
214     ;
215
216 localModifierList
217     :   ^(LOCAL_MODIFIER_LIST localModifier+)
218     ;
219
220 localModifier
221     :   'final'
222     |   'static'
223     |   'volatile'
224     ;
225
226 type
227     :   simpleType
228     |   objectType 
229     ;
230
231 simpleType
232     :   ^(TYPE primitiveType arrayDeclaratorList?)
233     ;
234     
235 objectType
236     :   ^(TYPE qualifiedTypeIdent arrayDeclaratorList?)
237     ;
238
239 qualifiedTypeIdent
240     :   ^(QUALIFIED_TYPE_IDENT typeIdent+) 
241     ;
242
243 typeIdent
244     :   ^(IDENT genericTypeArgumentList?)
245     ;
246
247 primitiveType
248     :   'boolean'     { $start.symbol = new Symbol(symtab, "bool_primitive", symtab.resolveBuiltinType("bool")); }
249     |   'char'        { $start.symbol = new Symbol(symtab, "char_primitive", symtab.resolveBuiltinType("char")); }
250     |   'byte'        { $start.symbol = new Symbol(symtab, "byte_primitive", symtab.resolveBuiltinType("char")); }
251     |   'short'       { $start.symbol = new Symbol(symtab, "short_primitive", symtab.resolveBuiltinType("short")); }
252     |   'int'         { $start.symbol = new Symbol(symtab, "int_primitive", symtab.resolveBuiltinType("int")); }
253     |   'long'        { $start.symbol = new Symbol(symtab, "long_primitive", symtab.resolveBuiltinType("long")); }
254     |   'float'       { $start.symbol = new Symbol(symtab, "float_primitive", symtab.resolveBuiltinType("float")); }
255     |   'double'      { $start.symbol = new Symbol(symtab, "double_primitive", symtab.resolveBuiltinType("double")); }
256     ;
257
258 genericTypeArgumentList
259     :   ^(GENERIC_TYPE_ARG_LIST genericTypeArgument+)
260     ;
261     
262 genericTypeArgument
263     :   type
264     |   '?'
265     ;
266
267 formalParameterList
268     :   ^(FORMAL_PARAM_LIST formalParameterStandardDecl* formalParameterVarargDecl?) 
269     ;
270     
271 formalParameterStandardDecl
272     :   ^(FORMAL_PARAM_STD_DECL localModifierList? type variableDeclaratorId)
273     ;
274     
275 formalParameterVarargDecl
276     :   ^(FORMAL_PARAM_VARARG_DECL localModifierList? type variableDeclaratorId)
277     ;
278     
279 // FIXME: is this rule right? Verify that this is ok, I expected something like:
280 // IDENT (^('.' qualifiedIdentifier IDENT))*
281 qualifiedIdentifier
282     :   IDENT
283     |   ^('.' qualifiedIdentifier IDENT)
284     ;
285     
286 block
287     :   ^(BLOCK (blockStatement)*)
288     ;
289     
290 blockStatement
291     :   localVariableDeclaration
292     |   statement
293     ;
294     
295 localVariableDeclaration
296     :   ^(PRIMITIVE_VAR_DECLARATION localModifierList? simpleType variableDeclaratorList)
297     |   ^(OBJECT_VAR_DECLARATION localModifierList? objectType variableDeclaratorList)
298     ;
299
300 statement
301     :   block
302     |   ^('assert' expression expression?)
303     |   ^('if' parenthesizedExpression statement statement?)
304     |   ^('for' forInit expression? expression* statement)
305     |   ^(FOR_EACH localModifierList? type IDENT expression statement) 
306     |   ^('while' parenthesizedExpression statement)
307     |   ^('do' statement parenthesizedExpression)
308     |   ^('switch' parenthesizedExpression switchCaseLabel*)
309     |   ^('return' expression?)
310     |   ^('throw' expression)
311     |   ^('break' IDENT?) {
312             if ($IDENT != null) {
313                 translator.error(this, "Labeled break not supported yet, ignoring.", $IDENT);
314             }
315         }
316     |   ^('continue' IDENT?) {
317             if ($IDENT != null) {
318                 translator.error(this, "Labeled continue not supported yet, ignoring.", $IDENT);
319             }
320         }
321     |   ^(LABELED_STATEMENT IDENT statement)
322     |   expression
323     |   ^('embed' STRING_LITERAL EMBED_BLOCK)
324     |   ';' // Empty statement.
325     ;
326         
327 switchCaseLabel
328     :   ^('case' expression blockStatement*)
329     |   ^('default' blockStatement*)
330     ;
331     
332 forInit
333     :   localVariableDeclaration 
334     |   expression+
335     ;
336     
337 // EXPRESSIONS
338
339 parenthesizedExpression
340     :   ^(PAREN_EXPR expression)
341     ;
342     
343 expression
344     :   ^(EXPR expr)
345     ;
346
347 expr
348     :   ^('=' expr expr)
349     |   ^('+=' expr expr)
350     |   ^('-=' expr expr)
351     |   ^('*=' expr expr)
352     |   ^('/=' expr expr)
353     |   ^('&=' expr expr)
354     |   ^('|=' expr expr)
355     |   ^('^=' expr expr)
356     |   ^('%=' expr expr)
357     |   ^('>>>=' expr expr)
358     |   ^('>>=' expr expr)
359     |   ^('<<=' expr expr)
360     |   ^('?' expr expr expr)
361     |   ^('||' expr expr)
362     |   ^('&&' expr expr)
363     |   ^('|' expr expr)
364     |   ^('^' expr expr)
365     |   ^('&' expr expr)
366     |   ^('==' expr expr)
367     |   ^('!=' expr expr)
368     |   ^('instanceof' expr type)
369     |   ^('<=' expr expr)
370     |   ^('>=' expr expr)
371     |   ^('>>>' expr expr)
372     |   ^('>>' expr expr)
373     |   ^('>' expr expr)
374     |   ^('<<' expr expr)
375     |   ^('<' expr expr)
376     |   ^('+' expr expr)
377     |   ^('-' expr expr)
378     |   ^('*' expr expr)
379     |   ^('/' expr expr)
380     |   ^('%' expr expr)
381     |   ^(UNARY_PLUS expr)
382     |   ^(UNARY_MINUS expr)
383     |   ^(PRE_INC expr)
384     |   ^(PRE_DEC expr)
385     |   ^(POST_INC expr)
386     |   ^(POST_DEC expr)
387     |   ^('~' expr)
388     |   ^('!' expr)
389     |   ^(CAST_EXPR type expr)
390     |   primaryExpression
391     ;
392     
393 primaryExpression
394     :   ^(  '.' primaryExpression
395                 (   IDENT
396                 |   'this'
397                 |   'super'
398                 |   'class'
399                 )
400         )
401     |   parenthesizedExpression
402     |   IDENT
403     |   ^(METHOD_CALL primaryExpression genericTypeArgumentList? arguments)
404     |   explicitConstructorCall
405     |   ^(ARRAY_ELEMENT_ACCESS primaryExpression expression)
406     |   literal
407     |   newExpression
408     |   'this'
409     |   arrayTypeDeclarator
410     |   'super'
411     ;
412     
413 explicitConstructorCall
414     :   ^(THIS_CONSTRUCTOR_CALL genericTypeArgumentList? arguments)
415     |   ^(SUPER_CONSTRUCTOR_CALL primaryExpression? genericTypeArgumentList? arguments)
416     ;
417
418 arrayTypeDeclarator
419     :   ^(ARRAY_DECLARATOR (arrayTypeDeclarator | qualifiedIdentifier | primitiveType))
420     ;
421
422 newExpression
423     :   ^(  STATIC_ARRAY_CREATOR
424             (   primitiveType newArrayConstruction
425             |   genericTypeArgumentList? qualifiedTypeIdent newArrayConstruction
426             )
427         )
428     ;
429
430 newArrayConstruction
431     :   arrayDeclaratorList arrayInitializer
432     |   expression+ arrayDeclaratorList?
433     ;
434
435 arguments
436     :   ^(ARGUMENT_LIST expression*)
437     ;
438
439 literal 
440     :   HEX_LITERAL
441     |   OCTAL_LITERAL
442     |   DECIMAL_LITERAL
443     |   FLOATING_POINT_LITERAL
444     |   CHARACTER_LITERAL
445     |   STRING_LITERAL          
446     |   'true'
447     |   'false'
448     |   'null'
449     ;
450