Charj: Simplified method handling, methods now registered with parents
[charm.git] / src / langs / charj / src / charj / translator / CharjEmitter.g
1 /**
2  * ANTLR (v3) Tree Parser for the Charj Language
3  */
4
5 tree grammar CharjEmitter;
6
7 options {
8     backtrack = true; 
9     memoize = true;
10     tokenVocab = Charj;
11     ASTLabelType = CharjAST;
12     output = template;
13 }
14
15
16 @header {
17 package charj.translator;
18 }
19
20
21 @members {
22     SymbolTable symtab = null;
23
24     PackageScope currentPackage = null;
25     ClassSymbol currentClass = null;
26     MethodSymbol currentMethod = null;
27     LocalScope currentLocalScope = null;
28
29     Translator translator_;
30     OutputMode mode_;
31
32     private boolean emitCC() { return mode_ == OutputMode.cc; }
33     private boolean emitCI() { return mode_ == OutputMode.ci; }
34     private boolean emitH() { return mode_ == OutputMode.h; }
35     private boolean debug() { return translator_.debug(); }
36
37     /**
38      *  Override ANTLR's token mismatch behavior so we throw exceptions early.
39      */
40     protected void mismatch(IntStream input, int ttype, BitSet follow)
41         throws RecognitionException {
42         throw new MismatchedTokenException(ttype, input);
43     }
44
45     /**
46      *  Override ANTLR's set mismatch behavior so we throw exceptions early.
47      */
48     public Object recoverFromMismatchedSet(IntStream input, RecognitionException e, BitSet follow)
49         throws RecognitionException {
50         throw e;
51     }
52
53     /**
54      *  Test a list of CharjAST nodes to see if any of them has the given token
55      *  type.
56      */
57     public boolean listContainsToken(List<CharjAST> list, int tokenType) {
58         if (list == null) return false;
59         for (CharjAST node : list) {
60             if (node.token.getType() == tokenType) {
61                 return true;
62             }
63         }
64         return false;
65     }
66 }
67
68
69 // Replace default ANTLR generated catch clauses with this action, allowing early failure.
70 @rulecatch {
71     catch (RecognitionException re) {
72         reportError(re);
73         throw re;
74     }
75 }
76
77
78 // Starting point for parsing a Charj file.
79 charjSource[SymbolTable symtab, OutputMode m]
80 @init {
81     this.symtab = symtab;
82     this.translator_ = symtab.translator;
83     this.mode_ = m;
84 }
85     :   ^(CHARJ_SOURCE (p=packageDeclaration)? 
86         (i+=importDeclaration)* 
87         (t=typeDeclaration))
88         -> {emitCC()}? charjSource_cc(
89             pd={$p.st}, ids={$i}, tds={$t.st}, debug={debug()})
90         -> {emitCI()}? charjSource_ci(pd={$p.st}, ids={$i}, tds={$t.st}, debug={debug()})
91         -> {emitH()}? charjSource_h(
92             pd={$p.st}, ids={$i}, tds={$t.st}, debug={debug()})
93         ->
94     ;
95
96 packageDeclaration
97 @init { 
98     List<String> names = null; 
99 }
100     :   ^('package' qualifiedIdentifier)
101         ->
102     ;
103     
104 importDeclaration
105 @init {
106     String importID = null;
107 }
108     :   ^('import' qualifiedIdentifier ds='.*'?)
109         {
110             importID = $qualifiedIdentifier.text;
111             if ($ds != null) {
112             }
113         }
114         {$ds == null}? // TODO: add support for importing x.*
115         -> {(emitCC() || emitH())}? importDeclaration_cc_h(
116             inc_id={importID.replace(".","/")},
117             use_id={importID.replace(".","::")})
118         ->
119     ;
120     
121 typeDeclaration
122     :   ^(TYPE 'class' IDENT (^('extends' su=type))? (^('implements' type+))? (csds+=classScopeDeclaration)*)
123         {
124             currentClass = (ClassSymbol)$IDENT.symbol;
125         }
126         -> {emitCC()}? classDeclaration_cc(
127                 sym={currentClass},
128                 ident={$IDENT.text}, 
129                 ext={$su.st}, 
130                 csds={$csds})
131         -> {emitH()}?  classDeclaration_h(
132                 sym={currentClass},
133                 ident={$IDENT.text}, 
134                 ext={$su.st}, 
135                 csds={$csds})
136         ->
137     |   ^('interface' IDENT (^('extends' type+))? interfaceScopeDeclaration*)
138         -> template(t={$text}) "/*INTERFACE-not implemented*/ <t>"
139     |   ^('enum' IDENT (^('implements' type+))? classScopeDeclaration*)
140         -> template(t={$text}) "/*ENUM-not implemented*/ <t>"
141     |   ^(TYPE chareType IDENT (^('extends' type))? (^('implements' type+))? classScopeDeclaration*)
142         {
143             currentClass = (ClassSymbol)$IDENT.symbol;
144         }
145         -> {emitCC()}? chareDeclaration_cc(
146                 sym={currentClass},
147                 ident={$IDENT.text}, 
148                 ext={$su.st}, 
149                 csds={$csds})
150         -> {emitCI()}? chareDeclaration_ci(
151                 sym={currentClass},
152                 chareType={$chareType.st},
153                 arrayDim={null},
154                 ident={$IDENT.text}, 
155                 ext={$su.st}, 
156                 csds={$csds})
157         -> {emitH()}? chareDeclaration_h(
158                 sym={currentClass},
159                 ident={$IDENT.text}, 
160                 ext={$su.st}, 
161                 csds={$csds})
162         ->
163     ;
164
165 chareType
166 @init {
167 $st = %{$start.getText()};
168 }
169     :   'chare'
170     |   'group'
171     |   'nodegroup'
172     |   ^('chare_array' ARRAY_DIMENSION)
173         -> template(t={$ARRAY_DIMENSION.text}) "array [<t>]"
174     ;
175
176 enumConstant
177     :   ^(IDENT arguments?)
178         -> template(t={$text}) "/*enumConstant-not implemented*/ <t>"
179     ;
180
181 classScopeDeclaration
182 @init { boolean entry = false; }
183     :   ^(FUNCTION_METHOD_DECL m=modifierList? g=genericTypeParameterList? 
184             ty=type IDENT f=formalParameterList a=arrayDeclaratorList? 
185             b=block?)
186         { 
187             if ($m.st != null) {
188                 // determine whether this is an entry method
189                 entry = listContainsToken($m.start.getChildren(), ENTRY);
190             }
191         }
192         -> {emitCC()}? funcMethodDecl_cc(
193                 modl={$m.st}, 
194                 gtpl={$g.st}, 
195                 ty={$ty.text},
196                 id={$IDENT.text}, 
197                 fpl={$f.st}, 
198                 adl={$a.st},
199                 block={$b.st})
200         -> {emitH()}? funcMethodDecl_h(
201                 modl={$m.st}, 
202                 gtpl={$g.st}, 
203                 ty={$ty.text},
204                 id={$IDENT.text}, 
205                 fpl={$f.st}, 
206                 adl={$a.st},
207                 block={$b.st})
208         -> {(emitCI() && entry)}? funcMethodDecl_ci(
209                 modl={$m.st}, 
210                 gtpl={$g.st}, 
211                 ty={$ty.text},
212                 id={$IDENT.text}, 
213                 fpl={$f.st}, 
214                 adl={$a.st},
215                 block={$b.st})
216         ->
217     |   ^(PRIMITIVE_VAR_DECLARATION modifierList? simpleType variableDeclaratorList)
218         -> {emitCC() || emitH()}? class_var_decl(
219             modl={$modifierList.st},
220             type={$simpleType.st},
221             declList={$variableDeclaratorList.st})
222         ->
223     |   ^(OBJECT_VAR_DECLARATION modifierList? objectType variableDeclaratorList)
224         -> {emitCC() || emitH()}? class_var_decl(
225             modl={$modifierList.st},
226             type={$objectType.st},
227             declList={$variableDeclaratorList.st})
228         ->
229     |   ^(CONSTRUCTOR_DECL m=modifierList? g=genericTypeParameterList? IDENT f=formalParameterList b=block)
230         { 
231             // determine whether this is an entry method
232             if ($m.st != null) {
233                 entry = listContainsToken($m.start.getChildren(), ENTRY);
234             }
235         }
236         -> {emitCC()}? ctorDecl_cc(
237                 modl={$m.st}, 
238                 gtpl={$g.st}, 
239                 id={$IDENT.text}, 
240                 fpl={$f.st}, 
241                 block={$b.st})
242         -> {emitCI() && entry}? ctorDecl_ci(
243                 modl={$m.st}, 
244                 gtpl={$g.st}, 
245                 id={$IDENT.text}, 
246                 fpl={$f.st}, 
247                 block={$b.st})
248         -> {emitH()}? ctorDecl_h(
249                 modl={$m.st}, 
250                 gtpl={$g.st}, 
251                 id={$IDENT.text}, 
252                 fpl={$f.st}, 
253                 block={$b.st})
254         ->
255     ;
256     
257 interfaceScopeDeclaration
258     :   ^(FUNCTION_METHOD_DECL modifierList? genericTypeParameterList? type IDENT formalParameterList arrayDeclaratorList?)
259         -> template(t={$text}) "/*interfaceScopeDeclarations-not implemented */ <t>"
260     |   ^(PRIMITIVE_VAR_DECLARATION modifierList? simpleType variableDeclaratorList)
261         -> template(t={$text}) "/*interfaceScopeDeclarations-not implemented */ <t>"
262     |   ^(OBJECT_VAR_DECLARATION modifierList? objectType variableDeclaratorList)
263         -> template(t={$text}) "/*interfaceScopeDeclarations-not implemented */ <t>"
264     ;
265
266 variableDeclaratorList
267     :   ^(VAR_DECLARATOR_LIST (var_decls+=variableDeclarator)+)
268         -> var_decl_list(var_decls={$var_decls})
269     ;
270
271 variableDeclarator
272     :   ^(VAR_DECLARATOR id=variableDeclaratorId initializer=variableInitializer?)
273         -> var_decl(id={$id.st}, initializer={$initializer.st})
274     ;
275     
276 variableDeclaratorId
277     :   ^(IDENT adl=arrayDeclaratorList?)
278         -> var_decl_id(id={$IDENT.text}, arrayDeclList={$adl.st})
279     ;
280
281 variableInitializer
282     :   arrayInitializer
283         -> {$arrayInitializer.st}
284     |   expression
285         -> {$expression.st}
286     ;
287
288 arrayDeclaratorList
289     :   ^(ARRAY_DECLARATOR_LIST ARRAY_DECLARATOR*)  
290         -> template(t={$text}) "<t>"
291     ;
292     
293 arrayInitializer
294     :   ^(ARRAY_INITIALIZER variableInitializer*)
295         -> template(t={$text}) "/* arrayInitializer-not implemented */ <t>"
296     ;
297
298 genericTypeParameterList
299     :   ^(GENERIC_TYPE_PARAM_LIST genericTypeParameter+)
300         -> template(t={$text}) "/*GENERIC_TYPE_PARAM_LIST-not implemented*/ <t>"
301     ;
302
303 genericTypeParameter
304     :   ^(IDENT bound?)
305         -> template(t={$text}) "/*genericTypeParameter-not implemented*/ <t>"
306     ;
307         
308 bound
309     :   ^(EXTENDS_BOUND_LIST type+)
310         -> template(t={$text}) "/*EXTENDS_BOUND_LIST-not implemented*/ <t>"
311     ;
312
313 throwsClause
314     :   ^(THROWS_CLAUSE qualifiedIdentifier+)
315         -> template(t={$text}) "/* throwsClause-not implemented */ <t>"
316     ;
317
318 modifierList
319     :   ^(MODIFIER_LIST (m+=modifier)+)
320         -> mod_list(mods={$m})
321     ;
322
323 modifier
324 @init {
325 $st = %{$start.getText()};
326 }
327     :   'public'
328     |   'protected'
329     |   'private'
330     |   'entry'
331     |   'abstract'
332     |   'native'
333     |   localModifier
334         -> {$localModifier.st}
335     ;
336
337 localModifierList
338     :   ^(LOCAL_MODIFIER_LIST (m+=localModifier)+)
339         -> local_mod_list(mods={$m})
340     ;
341
342 localModifier
343 @init {
344 $st = %{$start.getText()};
345 }
346     :   'final'
347     |   'static'
348     |   'volatile'
349     ;
350
351     
352 type
353     :   simpleType
354         -> {$simpleType.st}
355     |   objectType 
356         -> {$objectType.st}
357     ;
358
359 simpleType
360     :   ^(TYPE primitiveType arrayDeclaratorList?)
361         -> type(typeID={$primitiveType.st}, arrDeclList={$arrayDeclaratorList.st})
362     ;
363
364 objectType
365     :   ^(TYPE qualifiedTypeIdent arrayDeclaratorList?)
366         -> type(typeID={$qualifiedTypeIdent.st}, arrDeclList={$arrayDeclaratorList.st})
367     ;
368
369 qualifiedTypeIdent
370     :   ^(QUALIFIED_TYPE_IDENT (t+=typeIdent)+) 
371         -> template(types={$t}) "<types; separator=\".\">"
372     ;
373
374 typeIdent
375     :   ^(IDENT genericTypeArgumentList?)
376         -> typeIdent(typeID={$IDENT.text}, generics={$genericTypeArgumentList.st})
377     ;
378
379 primitiveType
380 @init {
381 $st = %{$start.getText()};
382 }
383     :   'boolean'
384         -> template() "bool"
385     |   'char'
386     |   'byte'
387         -> template() "char"
388     |   'short'
389     |   'int'
390     |   'long'
391     |   'float'
392     |   'double'
393     ;
394
395 genericTypeArgumentList
396     :   ^(GENERIC_TYPE_ARG_LIST (gta+=genericTypeArgument)+)
397         -> template(gtal={$gta}) "\<<gtal; separator=\", \">\>"
398     ;
399     
400 genericTypeArgument
401     :   type
402         -> {$type.st}
403     |   '?'
404         -> template(t={$text}) "/* genericTypeArgument: wildcard bound types not implemented */ <t>"
405     ;
406
407 formalParameterList
408     :   ^(FORMAL_PARAM_LIST (fpsd+=formalParameterStandardDecl)* fpvd=formalParameterVarargDecl?)
409         -> formal_param_list(sdecl={$fpsd}, vdecl={$fpvd.st})
410     ;
411     
412 formalParameterStandardDecl
413     :   ^(FORMAL_PARAM_STD_DECL lms=localModifierList? t=type vdid=variableDeclaratorId)
414         -> formal_param_decl(modList={$lms.st}, type={$t.st}, declID={$vdid.st})
415     ;
416     
417 formalParameterVarargDecl
418     :   ^(FORMAL_PARAM_VARARG_DECL localModifierList? type variableDeclaratorId)
419         -> template(t={$text}) "/*formal parameter varargs not implemented*/ <t>"
420     ;
421     
422 qualifiedIdentifier
423     :   IDENT
424         -> template(t={$text}) "<t>"
425     |   ^('.' qualifiedIdentifier IDENT)
426         -> template(t={$text}) "<t>"
427     ;
428     
429 block
430 @init { boolean emptyBlock = true; }
431     :   ^(BLOCK (b+=blockStatement)*)
432         { emptyBlock = ($b == null || $b.size() == 0); }
433         -> {emitCC() && emptyBlock}? template(bsl={$b}) "{ }"
434         -> {emitCC()}? block_cc(bsl={$b})
435         ->
436     ;
437     
438 blockStatement
439     :   localVariableDeclaration
440         -> {$localVariableDeclaration.st}
441     |   statement
442         -> {$statement.st}
443     ;
444
445
446 localVariableDeclaration
447     :   ^(PRIMITIVE_VAR_DECLARATION localModifierList? simpleType variableDeclaratorList)
448         -> local_var_decl(
449             modList={null},
450             type={$simpleType.st},
451             declList={$variableDeclaratorList.st})
452     |   ^(OBJECT_VAR_DECLARATION localModifierList? objectType variableDeclaratorList)
453         -> local_var_decl(
454             modList={null},
455             type={$objectType.st},
456             declList={$variableDeclaratorList.st})
457     ;
458
459
460 statement
461     :   block
462         -> {$block.st}
463     |   ^('assert' cond=expression msg=expression?)
464         -> assert(cond={$cond.st}, msg={$msg.st})
465     |   ^('if' parenthesizedExpression then=statement else_=statement?)
466         -> if(cond={$parenthesizedExpression.st}, then={$then.st}, else_={$else_.st})
467     |   ^('for' forInit? FOR_EXPR cond=expression? FOR_UPDATE (update+=expression)* s=statement)
468         -> for(initializer={$forInit.st}, cond={$cond.st}, update={$update}, body={$s.st})
469     |   ^(FOR_EACH localModifierList? type IDENT expression statement) 
470         -> template(t={$text}) "/* foreach not implemented */ <t>"
471     |   ^('while' pe=parenthesizedExpression s=statement)
472         -> while(cond={$pe.st}, body={$s.st})
473     |   ^('do' s=statement pe=parenthesizedExpression)
474         -> dowhile(cond={$pe.st}, block={$s.st})
475     |   ^('switch' pe=parenthesizedExpression (scls+=switchCaseLabel)*)
476         -> switch(expr={$pe.st}, labels={$scls})
477     |   ^('return' e=expression?)
478         -> return(val={$e.st})
479     |   ^('throw' expression)
480         -> template(t={$text}) "/* throw not implemented */ <t>"
481     |   ^('break' IDENT?)
482         -> template() "break;" // TODO: support labeling
483     |   ^('continue' IDENT?)
484         -> template() "continue;" // TODO: support labeling
485     |   ^(LABELED_STATEMENT i=IDENT s=statement)
486         -> label(text={$i.text}, stmt={$s.st})
487     |   expression
488         -> template(expr={$expression.st}) "<expr>;"
489     |   ^('embed' STRING_LITERAL EMBED_BLOCK)
490         ->  embed_cc(str={$STRING_LITERAL.text}, blk={$EMBED_BLOCK.text})
491     |   ';' // Empty statement.
492         -> {%{$start.getText()}}
493     ;
494         
495 switchCaseLabel
496     :   ^('case' expression (b+=blockStatement)*)
497         -> case(expr={$expression.st}, block={$b})
498     |   ^('default' (b+=blockStatement)*)
499         -> template(block={$b}) "default: <block>"
500     ;
501     
502 forInit
503     :   localVariableDeclaration
504         -> template(lvd={$localVariableDeclaration.st}) "<lvd>"
505     |   (ex+=expression)+
506         -> template(ex={$ex}) "<ex; separator=\", \">"
507     ;
508
509 // EXPRESSIONS
510
511 parenthesizedExpression
512     :   ^(PAREN_EXPR exp=expression)
513         -> template(expr={$exp.st}) "(<expr>)"
514     ;
515     
516 expression
517     :   ^(EXPR expr)
518         -> {$expr.st}
519     ;
520
521 expr
522     :   ^('=' e1=expr e2=expr)
523         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> = <e2>"
524     |   ^('+=' e1=expr e2=expr)
525         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> += <e2>"
526     |   ^('-=' e1=expr e2=expr)
527         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> -= <e2>"
528     |   ^('*=' e1=expr e2=expr)
529         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> *= <e2>"
530     |   ^('/=' e1=expr e2=expr)
531         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> /= <e2>"
532     |   ^('&=' e1=expr e2=expr)
533         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> &= <e2>"
534     |   ^('|=' e1=expr e2=expr)
535         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> |= <e2>"
536     |   ^('^=' e1=expr e2=expr)
537         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> ^= <e2>"
538     |   ^('%=' e1=expr e2=expr)
539         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> %= <e2>"
540     |   ^('>>>=' e1=expr e2=expr)
541         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \>\>\>= <e2>"
542     |   ^('>>=' e1=expr e2=expr)
543         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \>\>= <e2>"
544     |   ^('<<=' e1=expr e2=expr)
545         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \<\<= <e2>"
546     |   ^('?' e1=expr e2=expr e3=expr)
547         -> template(e1={$e1.st}, e2={$e2.st}, e3={$e3.st}) "<e1> ? <e2> : <e3>"
548     |   ^('||' e1=expr e2=expr)
549         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> || <e2>"
550     |   ^('&&' e1=expr e2=expr)
551         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> && <e2>"
552     |   ^('|' e1=expr e2=expr)
553         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> | <e2>"
554     |   ^('^' e1=expr e2=expr)
555         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> ^ <e2>"
556     |   ^('&' e1=expr e2=expr)
557         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> & <e2>"
558     |   ^('==' e1=expr e2=expr)
559         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> == <e2>"
560     |   ^('!=' e1=expr e2=expr)
561         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> != <e2>"
562     |   ^('instanceof' expr type)
563         -> template(t={$text}) "/* instanceof not implemented */ <t>"
564     |   ^('<=' e1=expr e2=expr)
565         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \<= <e2>"
566     |   ^('>=' e1=expr e2=expr)
567         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \>= <e2>"
568     |   ^('>>>' e1=expr e2=expr)
569         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \>\>\> <e2>"
570     |   ^('>>' e1=expr e2=expr)
571         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \>\> <e2>"
572     |   ^('>' e1=expr e2=expr)
573         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \> <e2>"
574     |   ^('<<' e1=expr e2=expr)
575         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \<\< <e2>"
576     |   ^('<' e1=expr e2=expr)
577         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \< <e2>"
578     |   ^('+' e1=expr e2=expr)
579         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> + <e2>"
580     |   ^('-' e1=expr e2=expr)
581         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> - <e2>"
582     |   ^('*' e1=expr e2=expr)
583         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> * <e2>"
584     |   ^('/' e1=expr e2=expr)
585         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> / <e2>"
586     |   ^('%' e1=expr e2=expr)
587         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> % <e2>"
588     |   ^(UNARY_PLUS e1=expr)
589         -> template(e1={$e1.st}) "+<e1>"
590     |   ^(UNARY_MINUS e1=expr)
591         -> template(e1={$e1.st}) "-<e1>"
592     |   ^(PRE_INC e1=expr)
593         -> template(e1={$e1.st}) "++<e1>"
594     |   ^(PRE_DEC e1=expr)
595         -> template(e1={$e1.st}) "--<e1>"
596     |   ^(POST_INC e1=expr)
597         -> template(e1={$e1.st}) "<e1>++"
598     |   ^(POST_DEC e1=expr)
599         -> template(e1={$e1.st}) "<e1>--"
600     |   ^('~' e1=expr)
601         -> template(e1={$e1.st}) "~<e1>"
602     |   ^('!' e1=expr)
603         -> template(e1={$e1.st}) "!<e1>"
604     |   ^(CAST_EXPR ty=type e1=expr)
605         -> template(ty={$ty.st}, e1={$e1.st}) "(<ty>)<e1>"
606     |   primaryExpression
607         -> {$primaryExpression.st}
608     ;
609     
610 primaryExpression
611     :   ^('.' prim=primaryExpression IDENT)
612         -> template(id={$IDENT}, prim={$prim.st}) "<prim>.<id>"
613     |   ^('.' prim=primaryExpression 'this')
614         -> template(prim={$prim.st}) "<prim>.this"
615     |   ^('.' prim=primaryExpression 'super')
616         -> template(prim={$prim.st}) "<prim>.super"
617     |   parenthesizedExpression
618         -> {$parenthesizedExpression.st}
619     |   IDENT
620         -> {%{$start.getText()}}
621     |   ^(METHOD_CALL pe=primaryExpression gtal=genericTypeArgumentList? args=arguments)
622         -> method_call(primary={$pe.st}, generic_types={$gtal.st}, args={$args.st})
623     |   explicitConstructorCall
624         -> {$explicitConstructorCall.st}
625     |   ^(ARRAY_ELEMENT_ACCESS pe=primaryExpression ex=expression)
626         -> template(pe={$pe.st}, ex={$ex.st}) "<pe>[<ex>]"
627     |   literal
628         -> {$literal.st}
629     |   newExpression
630         -> {$newExpression.st}
631     |   'this'
632         -> {%{$start.getText()}}
633     |   arrayTypeDeclarator
634         -> {$arrayTypeDeclarator.st}
635     |   'super'
636         -> {%{$start.getText()}}
637     ;
638     
639 explicitConstructorCall
640     :   ^(THIS_CONSTRUCTOR_CALL genericTypeArgumentList? arguments)
641         -> template(t={$text}) "<t>"
642     |   ^(SUPER_CONSTRUCTOR_CALL primaryExpression? genericTypeArgumentList? arguments)
643         -> template(t={$text}) "<t>"
644     ;
645
646 arrayTypeDeclarator
647     :   ^(ARRAY_DECLARATOR (arrayTypeDeclarator | qualifiedIdentifier | primitiveType))
648         -> template(t={$text}) "<t>"
649     ;
650
651 newExpression
652     :   ^(  STATIC_ARRAY_CREATOR
653             (   primitiveType newArrayConstruction
654             |   genericTypeArgumentList? qualifiedTypeIdent newArrayConstruction
655             )
656         )
657         -> template(t={$text}) "<t>"
658     ;
659
660 newArrayConstruction
661     :   arrayDeclaratorList arrayInitializer
662         -> array_construction_with_init(
663                 array_decls={$arrayDeclaratorList.st},
664                 initializer={$arrayInitializer.st})
665     |   (ex+=expression)+ adl=arrayDeclaratorList?
666         -> array_construction(exprs={$ex}, array_decls={$adl.st})
667     ;
668
669 arguments
670     :   ^(ARGUMENT_LIST (ex+=expression)*)
671         -> arguments(exprs={$ex})
672     ;
673
674 literal
675 @init {
676 $st = %{$start.getText()};
677 }
678     :   HEX_LITERAL
679     |   OCTAL_LITERAL
680     |   DECIMAL_LITERAL
681     |   FLOATING_POINT_LITERAL
682     |   CHARACTER_LITERAL
683     |   STRING_LITERAL
684     |   'true'
685     |   'false'
686     |   'null'
687     ;
688