e680c7d00a36ae5c2f8cd93e2393e64c128344d4
[charm.git] / src / langs / charj / src / charj / translator / CharjEmitter.g
1 /**
2  * ANTLR (v3) Tree Parser for the Charj Language
3  */
4
5 tree grammar CharjEmitter;
6
7 options {
8     backtrack = true; 
9     memoize = true;
10     tokenVocab = Charj;
11     ASTLabelType = CharjAST;
12     output = template;
13 }
14
15
16 @header {
17 package charj.translator;
18 }
19
20
21 @members {
22     SymbolTable symtab = null;
23
24     PackageScope currentPackage = null;
25     ClassSymbol currentClass = null;
26     MethodSymbol currentMethod = null;
27     LocalScope currentLocalScope = null;
28
29     Translator translator_;
30     OutputMode mode_;
31
32     private boolean emitCC() { return mode_ == OutputMode.cc; }
33     private boolean emitCI() { return mode_ == OutputMode.ci; }
34     private boolean emitH() { return mode_ == OutputMode.h; }
35     private boolean debug() { return translator_.debug(); }
36     private String basename() { return translator_.basename(); }
37
38     /**
39      *  Override ANTLR's token mismatch behavior so we throw exceptions early.
40      */
41     protected void mismatch(IntStream input, int ttype, BitSet follow)
42         throws RecognitionException {
43         throw new MismatchedTokenException(ttype, input);
44     }
45
46     /**
47      *  Override ANTLR's set mismatch behavior so we throw exceptions early.
48      */
49     public Object recoverFromMismatchedSet(IntStream input, RecognitionException e, BitSet follow)
50         throws RecognitionException {
51         throw e;
52     }
53
54     /**
55      *  Test a list of CharjAST nodes to see if any of them has the given token
56      *  type.
57      */
58     public boolean listContainsToken(List<CharjAST> list, int tokenType) {
59         if (list == null) return false;
60         for (CharjAST node : list) {
61             if (node.token.getType() == tokenType) {
62                 return true;
63             }
64         }
65         return false;
66     }
67 }
68
69
70 // Replace default ANTLR generated catch clauses with this action, allowing early failure.
71 @rulecatch {
72     catch (RecognitionException re) {
73         reportError(re);
74         throw re;
75     }
76 }
77
78
79 // Starting point for parsing a Charj file.
80 charjSource[SymbolTable symtab, OutputMode m]
81 @init {
82     this.symtab = symtab;
83     this.translator_ = symtab.translator;
84     this.mode_ = m;
85 }
86     :   ^(CHARJ_SOURCE (p=packageDeclaration)? 
87         (i+=importDeclaration)*
88         (r+=readonlyDeclaration)*
89         (t+=typeDeclaration)*)
90         -> {emitCC()}? charjSource_cc(basename={basename()}, pd={$p.names}, imports={$i}, types={$t}, ros={$r}, debug={debug()})
91         -> {emitCI()}? charjSource_ci(basename={basename()}, pd={$p.names}, imports={$i}, types={$t}, ros={$r}, debug={debug()})
92         -> {emitH()}? charjSource_h(basename={basename()}, pd={$p.names}, imports={$i}, types={$t}, ros={$r}, debug={debug()})
93         ->
94     ;
95
96 topLevelDeclaration
97     :   importDeclaration -> {$importDeclaration.st;}
98     |   typeDeclaration -> {$typeDeclaration.st;}
99     ;
100
101 packageDeclaration returns [List names]
102     :   ^('package' (ids+=IDENT)+)
103         {
104             $names = $ids;
105         }
106         ->
107     ;
108
109 readonlyDeclaration
110     :   ^(READONLY lvd=localVariableDeclaration)
111         -> {emitCI()}? template(bn={basename()}, v={$lvd.st}) "readonly <v>"
112         -> {emitH()}? template(v={$lvd.st}) "extern <v>"
113         -> {emitCC()}? {$lvd.st;}
114         ->
115     ;
116     
117 importDeclaration
118 @init {
119     String importID = null;
120 }
121     :   ^('import' qualifiedIdentifier ds='.*'?)
122         {
123             importID = $qualifiedIdentifier.text;
124             if ($ds != null) {
125             }
126         }
127         {$ds == null}? // TODO: add support for importing x.*
128         -> {(emitCC() || emitH())}? importDeclaration_cc_h(
129             inc_id={importID.replace(".","/")},
130             use_id={importID.replace(".","::")})
131         ->
132     ;
133     
134 typeDeclaration
135     :   ^(TYPE CLASS IDENT (^('extends' su=type))? (^('implements' type+))?
136         {
137             currentClass = (ClassSymbol)$IDENT.symbol;
138         }
139         (csds+=classScopeDeclaration)*)
140         -> {emitCC()}? classDeclaration_cc(
141                 sym={currentClass},
142                 ident={$IDENT.text}, 
143                 ext={$su.st}, 
144                 csds={$csds})
145         -> {emitH()}?  classDeclaration_h(
146                 sym={currentClass},
147                 ident={$IDENT.text}, 
148                 ext={$su.st}, 
149                 csds={$csds})
150         ->
151     |   ^('template' (i0+=IDENT*) ^('class' i1=IDENT (^('extends' su=type))? (^('implements' type+))? (csds+=classScopeDeclaration)*))
152         -> {emitH()}? templateDeclaration_h(
153             tident={$i0},
154             ident={$i1.text},
155             ext={$su.st},
156             csds={$csds})
157         -> 
158     |   ^(INTERFACE IDENT (^('extends' type+))? interfaceScopeDeclaration*)
159         -> template(t={$text}) "/*INTERFACE-not implemented*/ <t>"
160     |   ^(ENUM IDENT (^('implements' type+))? classScopeDeclaration*)
161         -> template(t={$text}) "/*ENUM-not implemented*/ <t>"
162     |   ^(TYPE chareType IDENT (^('extends' type))? (^('implements' type+))?
163         {
164             currentClass = (ClassSymbol)$IDENT.symbol;
165         }
166         (csds+=classScopeDeclaration)*)
167         -> {emitCC()}? chareDeclaration_cc(
168                 sym={currentClass},
169                 ident={$IDENT.text}, 
170                 ext={$su.st}, 
171                 csds={$csds})
172         -> {emitCI()}? chareDeclaration_ci(
173                 sym={currentClass},
174                 chareType={$chareType.st},
175                 arrayDim={null},
176                 ident={$IDENT.text}, 
177                 ext={$su.st}, 
178                 csds={$csds})
179         -> {emitH()}? chareDeclaration_h(
180                 sym={currentClass},
181                 ident={$IDENT.text}, 
182                 ext={$su.st}, 
183                 csds={$csds})
184         ->
185     ;
186
187 chareType
188 @init {
189 $st = %{$start.getText()};
190 }
191     :   CHARE
192     |   GROUP
193     |   NODEGROUP
194     |   MAINCHARE
195     |   ^(CHARE_ARRAY ARRAY_DIMENSION)
196         -> template(t={$ARRAY_DIMENSION.text}) "array [<t>]"
197     ;
198
199 enumConstant
200     :   ^(IDENT arguments?)
201         -> template(t={$text}) "/*enumConstant-not implemented*/ <t>"
202     ;
203
204 classScopeDeclaration
205 @init
206 {
207     boolean entry = false;
208     boolean migrationCtor = false;
209 }
210     :   ^(FUNCTION_METHOD_DECL m=modifierList? g=genericTypeParameterList? 
211             ty=type IDENT f=formalParameterList
212             b=block?)
213         {
214             // determine whether it's an entry method
215             if($m.start != null)
216                 entry = listContainsToken($m.start.getChildren(), CHARJ_MODIFIER_LIST);
217         }
218         -> {emitCC()}? funcMethodDecl_cc(
219                 sym={currentClass},
220                 modl={$m.st}, 
221                 gtpl={$g.st}, 
222                 ty={$ty.st},
223                 id={$IDENT.text}, 
224                 fpl={$f.st}, 
225                 block={$b.st})
226         -> {emitH()}? funcMethodDecl_h(
227                 modl={$m.st}, 
228                 gtpl={$g.st}, 
229                 ty={$ty.st},
230                 id={$IDENT.text}, 
231                 fpl={$f.st}, 
232                 block={$b.st})
233         -> {(emitCI() && entry)}? funcMethodDecl_ci(
234                 modl={$m.st}, 
235                 gtpl={$g.st}, 
236                 ty={$ty.st},
237                 id={$IDENT.text}, 
238                 fpl={$f.st}, 
239                 block={$b.st})
240         ->
241     |   ^(PRIMITIVE_VAR_DECLARATION modifierList? simpleType variableDeclaratorList[null, false])
242         -> {emitCC() || emitH()}? class_var_decl(
243             modl={$modifierList.st},
244             type={$simpleType.st},
245             declList={$variableDeclaratorList.st})
246         ->
247     |   ^(OBJECT_VAR_DECLARATION modifierList? objectType variableDeclaratorList[$objectType.st, false])
248         -> {emitCC() || emitH()}? class_var_decl(
249             modl={$modifierList.st},
250             type={$objectType.st},
251             declList={$variableDeclaratorList.st})
252         ->
253     |   ^(CONSTRUCTOR_DECL m=modifierList? g=genericTypeParameterList? IDENT f=formalParameterList b=block)
254         {
255             // determine whether it's an entry method
256             if ($m.start != null) {
257                 entry = listContainsToken($m.start.getChildren(), CHARJ_MODIFIER_LIST);
258             }
259             migrationCtor = currentClass.migrationCtor == $CONSTRUCTOR_DECL;
260         }
261         -> {emitCC()}? ctorDecl_cc(
262                 modl={$m.st},
263                 gtpl={$g.st}, 
264                 id={$IDENT.text}, 
265                 fpl={$f.st}, 
266                 block={$b.st})
267         -> {emitCI() && entry && !migrationCtor}? ctorDecl_ci(
268                 modl={$m.st},
269                 gtpl={$g.st}, 
270                 id={$IDENT.text}, 
271                 fpl={$f.st}, 
272                 block={$b.st})
273         -> {emitH()}? ctorDecl_h(
274                 modl={$m.st},
275                 gtpl={$g.st}, 
276                 id={$IDENT.text}, 
277                 fpl={$f.st}, 
278                 block={$b.st})
279         ->
280     ;
281     
282 interfaceScopeDeclaration
283     :   ^(FUNCTION_METHOD_DECL modifierList? genericTypeParameterList? type IDENT formalParameterList)
284         -> template(t={$text}) "/*interfaceScopeDeclarations-not implemented */ <t>"
285     |   ^(PRIMITIVE_VAR_DECLARATION modifierList? simpleType variableDeclaratorList[$simpleType.st, false])
286         -> template(t={$text}) "/*interfaceScopeDeclarations-not implemented */ <t>"
287     |   ^(OBJECT_VAR_DECLARATION modifierList? objectType variableDeclaratorList[$objectType.st, false])
288         -> template(t={$text}) "/*interfaceScopeDeclarations-not implemented */ <t>"
289     ;
290
291 variableDeclaratorList[StringTemplate obtype, boolean output]
292     :   ^(VAR_DECLARATOR_LIST (var_decls+=variableDeclarator[obtype, output])+ )
293         -> var_decl_list(var_decls={$var_decls})
294     ;
295
296 variableDeclarator[StringTemplate obtype, boolean output]
297     :   ^(VAR_DECLARATOR id=variableDeclaratorId[output] initializer=variableInitializer[obtype, output]?)
298         -> {$output && emitCC()}? var_decl_cc(id={$id.st}, initializer={$initializer.st})
299         -> {$output && emitH()}?  var_decl_h(id={$id.st}, initializer={$initializer.st})
300         -> {$output && emitCI()}? var_decl_ci(id={$id.st}, initializer={$initializer.st})
301         -> {!$output && emitCC()}? var_decl_cc(id={$id.st})
302         -> {!$output && emitH()}?  var_decl_h(id={$id.st})
303         -> {!$output && emitCI()}? var_decl_ci(id={$id.st})
304         ->
305     ; 
306     
307 variableDeclaratorId[boolean output]
308     :   ^(IDENT de=domainExpression[null]?)
309         -> {$output}? var_decl_id(id={$IDENT.text}, domainExp={$de.st})
310         -> {!$output}? var_decl_id(id={$IDENT.text})
311         ->
312     ;
313
314 variableInitializer[StringTemplate obtype, boolean output]
315     :   arrayInitializer
316         -> {$arrayInitializer.st}
317     |   newExpression[obtype, output]
318         -> {$newExpression.st}
319     |   expression
320         -> {$expression.st}
321     ;
322
323 rangeItem
324     :   dl=DECIMAL_LITERAL
325         -> template(t={$dl.text}) "<t>"
326     |   IDENT
327         -> template(t={$IDENT.text}) "<t>"
328     ;
329
330 rangeExpression
331     :   ^(RANGE_EXPRESSION (ri+=rangeItem)*)
332         -> template(t={$ri}) "Range(<t; separator=\",\">)"
333     ;
334
335 rangeList returns [int len]
336     :   (r+=rangeExpression)*
337         { $len = $r.size(); }
338         -> template(t={$r}) "<t; separator=\", \">"
339         
340     ;
341
342 domainExpression[List<StringTemplate> otherParams]
343     :   ^(DOMAIN_EXPRESSION rl=rangeList)
344         -> range_constructor(range={$rl.st}, others={$otherParams}, len={$rl.len})
345
346     ;
347
348 /*arrayDeclaratorList
349     :   ^(ARRAY_DECLARATOR_LIST ARRAY_DECLARATOR*)  
350         -> template(t={$text}) "<t>"
351     ;*/
352     
353 arrayInitializer
354     :   ^(ARRAY_INITIALIZER variableInitializer[null, false]*)
355         -> template(t={$text}) "/* arrayInitializer-not implemented */ <t>"
356     ;
357
358 genericTypeParameterList
359     :   ^(GENERIC_TYPE_PARAM_LIST genericTypeParameter+)
360         -> template(t={$text}) "/*GENERIC_TYPE_PARAM_LIST-not implemented*/ <t>"
361     ;
362
363 genericTypeParameter
364     :   ^(IDENT bound?)
365         -> template(t={$text}) "/*genericTypeParameter-not implemented*/ <t>"
366     ;
367         
368 bound
369     :   ^(EXTENDS_BOUND_LIST type+)
370         -> template(t={$text}) "/*EXTENDS_BOUND_LIST-not implemented*/ <t>"
371     ;
372
373 throwsClause
374     :   ^(THROWS_CLAUSE qualifiedIdentifier+)
375         -> template(t={$text}) "/* throwsClause-not implemented */ <t>"
376     ;
377
378 modifierList
379     :   ^(MODIFIER_LIST accessModifierList? localModifierList? charjModifierList? otherModifierList?)
380         ->  {emitCC()}? mod_list_cc(accmods = {$accessModifierList.names}, localmods = {$localModifierList.names}, charjmods = {$charjModifierList.names}, othermods = {$otherModifierList.names})
381         ->  {emitH()}? mod_list_h(accmods = {$accessModifierList.names}, localmods = {$localModifierList.names}, charjmods = {$charjModifierList.names}, othermods = {$otherModifierList.names})
382         ->  {emitCI()}? mod_list_ci(accmods = {$accessModifierList.names}, localmods = {$localModifierList.names}, charjmods = {$charjModifierList.names}, othermods = {$otherModifierList.names})
383         ->
384     ;
385
386 modifier
387     :   accessModifier
388     |   localModifier
389     |   charjModifier
390     |   otherModifier
391     ;
392
393 accessModifierList
394 returns [List names]
395     :   ^(ACCESS_MODIFIER_LIST (m+=accessModifier)+)
396         {
397             $names = $m;
398         }
399     ;
400 localModifierList
401 returns [List names]
402     :   ^(LOCAL_MODIFIER_LIST (m+=localModifier)+)
403         {
404             $names = $m;
405         }
406         ->  local_mod_list(mods = {$names})
407     ;
408
409 charjModifierList
410 returns [List names]
411     :   ^(CHARJ_MODIFIER_LIST (m+=charjModifier)+)
412         {
413             $names = $m;
414         }
415     ;
416
417 otherModifierList
418 returns [List names]
419     :   ^(OTHER_MODIFIER_LIST (m+=otherModifier)+)
420         {
421             $names = $m;
422         }
423     ;
424     
425 localModifier
426 @init
427 {
428     $st = %{$start.getText()};
429 }
430     :   FINAL
431     |   STATIC
432     |   VOLATILE
433     ;
434
435 accessModifier
436 @init
437 {
438     $st = %{$start.getText()};
439 }
440     :   PUBLIC
441     |   PROTECTED
442     |   PRIVATE
443     ;
444
445 charjModifier
446 @init
447 {
448     $st = %{$start.getText()};
449 }
450     :   ENTRY
451     ;
452
453 otherModifier
454 @init
455 {
456     $st = %{$start.getText()};
457 }
458     :   ABSTRACT
459     |   NATIVE
460     ;
461     
462 type
463     :   simpleType
464         -> {$simpleType.st}
465     |   objectType 
466         -> {$objectType.st}
467     |   VOID
468         {
469             $st = %{$start.getText()};
470         }
471     ;
472
473 simpleType
474     :   ^(SIMPLE_TYPE primitiveType domainExpression[null]?)
475         -> simple_type(typeID={$primitiveType.st}, arrDeclList={$domainExpression.st})
476     ;
477
478 objectType
479     : proxyType -> {$proxyType.st;}
480     | nonProxyType -> {$nonProxyType.st}
481     ;
482
483 nonProxyType
484     :   ^(OBJECT_TYPE qualifiedTypeIdent domainExpression[null]?)
485         -> obj_type(typeID={$qualifiedTypeIdent.st}, arrDeclList={$domainExpression.st})
486     |   ^(POINTER_TYPE qualifiedTypeIdent domainExpression[null]?)
487         -> pointer_type(typeID={$qualifiedTypeIdent.st}, arrDeclList={$domainExpression.st})
488     |   ^(REFERENCE_TYPE qualifiedTypeIdent domainExpression[null]?)
489         -> reference_type(typeID={$qualifiedTypeIdent.st}, arrDeclList={$domainExpression.st})
490     ;
491
492 proxyType
493     :   ^(PROXY_TYPE qualifiedTypeIdent domainExpression[null]?)
494         -> proxy_type(typeID={$qualifiedTypeIdent.st}, arrDeclList={$domainExpression.st})
495     ;
496
497 qualifiedTypeIdent returns [ClassSymbol type]
498     :   ^(QUALIFIED_TYPE_IDENT (t+=typeIdent)+)
499         {$type = (ClassSymbol)$QUALIFIED_TYPE_IDENT.symbol;}
500         -> template(types={$t}) "<types; separator=\"::\">"
501     ;
502
503 typeIdent
504     :   ^(IDENT templateInstantiation?)
505         -> typeIdent(typeID={$IDENT.text}, generics={$templateInstantiation.st})
506     ;
507
508 primitiveType
509 @init {
510 $st = %{$start.getText()};
511 }
512     :   BOOLEAN
513         -> template() "bool"
514     |   CHAR
515     |   BYTE
516         -> template() "char"
517     |   SHORT
518     |   INT
519     |   LONG
520     |   FLOAT
521     |   DOUBLE
522     ;
523
524 templateArg
525     :   genericTypeArgument
526         -> {$genericTypeArgument.st}
527     |   literal
528         -> {$literal.st}
529     ;
530
531 templateArgList
532     :   params+=templateArg+
533         -> template(params={$params}) "<params; separator=\", \">"
534     ;
535
536 templateInstantiation
537     :   ^(TEMPLATE_INST templateArgList)
538         -> template(args={$templateArgList.st}) "\<<args>\>"
539     |   ^(TEMPLATE_INST ts=templateInstantiation)
540         -> template(inst={$ts.st}) "\<<inst>\>"
541     ;
542
543 genericTypeArgumentList
544     :   ^(GENERIC_TYPE_ARG_LIST (gta+=genericTypeArgument)+)
545         -> template(gtal={$gta}) "\<<gtal; separator=\", \">\>"
546     ;
547
548 genericTypeArgument
549     :   type
550         -> {$type.st}
551     |   '?'
552         -> template(t={$text}) "/* genericTypeArgument: wildcard bound types not implemented */ <t>"
553     ;
554
555 formalParameterList
556     :   ^(FORMAL_PARAM_LIST (fpsd+=formalParameterStandardDecl)* fpvd=formalParameterVarargDecl?)
557         -> formal_param_list(sdecl={$fpsd}, vdecl={$fpvd.st})
558     ;
559     
560 formalParameterStandardDecl
561     :   ^(FORMAL_PARAM_STD_DECL lms=localModifierList? t=type vdid=variableDeclaratorId[true])
562         -> formal_param_decl(modList={$lms.st}, type={$t.st}, declID={$vdid.st})
563     ;
564     
565 formalParameterVarargDecl
566     :   ^(FORMAL_PARAM_VARARG_DECL localModifierList? type variableDeclaratorId[true])
567         -> template(t={$text}) "/*formal parameter varargs not implemented*/ <t>"
568     ;
569     
570 qualifiedIdentifier
571     :   IDENT
572         -> template(t={$text}) "<t>"
573     |   ^(DOT qualifiedIdentifier IDENT)
574         -> template(t={$text}) "<t>"
575     ;
576     
577 block
578 @init { boolean emptyBlock = true; }
579     :   ^(BLOCK (b+=blockStatement)*)
580         { emptyBlock = ($b == null || $b.size() == 0); }
581         -> {emitCC() && emptyBlock}? template(bsl={$b}) "{ }"
582         -> {emitCC()}? block_cc(bsl={$b})
583         ->
584     ;
585     
586 blockStatement
587     :   localVariableDeclaration
588         -> {$localVariableDeclaration.st}
589     |   statement
590         -> {$statement.st}
591     ;
592
593
594 localVariableDeclaration
595     :   ^(PRIMITIVE_VAR_DECLARATION localModifierList? simpleType vdl=variableDeclaratorList[null, true])
596         -> local_var_decl(
597             modList={$localModifierList.st},
598             type={$simpleType.st},
599             declList={$vdl.st})
600     |   ^(OBJECT_VAR_DECLARATION localModifierList? objectType vdl=variableDeclaratorList[$objectType.st, true])
601         -> local_var_decl(
602             modList={$localModifierList.st},
603             type={$objectType.st},
604             declList={$vdl.st})
605     ;
606
607
608 statement
609     :   nonBlockStatement
610         -> {$nonBlockStatement.st}
611     |   block
612         -> {$block.st}
613     ;
614
615 nonBlockStatement
616     :   ^(ASSERT cond=expression msg=expression?)
617         -> assert(cond={$cond.st}, msg={$msg.st})
618     |   ^(IF parenthesizedExpression then=block else_=block?)
619         -> if(cond={$parenthesizedExpression.st}, then={$then.st}, else_={$else_.st})
620     |   ^(FOR forInit? FOR_EXPR cond=expression? FOR_UPDATE (update+=expression)* b=block)
621         -> for(initializer={$forInit.st}, cond={$cond.st}, update={$update}, body={$block.st})
622     |   ^(FOR_EACH localModifierList? type IDENT expression block) 
623         -> template(t={$text}) "/* foreach not implemented */ <t>"
624     |   ^(WHILE pe=parenthesizedExpression b=block)
625         -> while(cond={$pe.st}, body={$b.st})
626     |   ^(DO b=block pe=parenthesizedExpression)
627         -> dowhile(cond={$pe.st}, block={$b.st})
628     |   ^(SWITCH pe=parenthesizedExpression (scls+=switchCaseLabel)*)
629         -> switch(expr={$pe.st}, labels={$scls})
630     |   ^(RETURN e=expression?)
631         -> return(val={$e.st})
632     |   ^(THROW expression)
633         -> template(t={$text}) "/* throw not implemented */ <t>"
634     |   ^(BREAK IDENT?)
635         -> template() "break;" // TODO: support labeling
636     |   ^(CONTINUE IDENT?)
637         -> template() "continue;" // TODO: support labeling
638     |   ^(LABELED_STATEMENT i=IDENT s=statement)
639         -> label(text={$i.text}, stmt={$s.st})
640     |   expression
641         -> template(expr={$expression.st}) "<expr>;"
642     |   ^('delete' qualifiedIdentifier)
643         -> template(t={$qualifiedIdentifier.st}) "delete <t>;"
644     |   ^('embed' STRING_LITERAL EMBED_BLOCK)
645         ->  embed_cc(str={$STRING_LITERAL.text}, blk={$EMBED_BLOCK.text})
646     |   ';' // Empty statement.
647         -> {%{$start.getText()}}
648     |   ^(PRINT (exprs += expression)*)
649         ->  print(exprs = {$exprs})
650     |   ^(PRINTLN (exprs += expression)*)
651         ->  println(exprs = {$exprs})
652     |   ^(EXIT expression?)
653         ->  exit(expr = {$expression.st})
654     |   EXITALL
655         ->  exitall()
656     ;
657         
658 switchCaseLabel
659     :   ^(CASE expression (b+=blockStatement)*)
660         -> case(expr={$expression.st}, block={$b})
661     |   ^(DEFAULT (b+=blockStatement)*)
662         -> template(block={$b}) "default: <block>"
663     ;
664     
665 forInit
666     :   localVariableDeclaration
667         -> template(lvd={$localVariableDeclaration.st}) "<lvd>"
668     |   (ex+=expression)+
669         -> template(ex={$ex}) "<ex; separator=\", \">"
670     ;
671
672 // EXPRESSIONS
673
674 parenthesizedExpression
675     :   ^(PAREN_EXPR exp=expression)
676         -> template(expr={$exp.st}) "(<expr>)"
677     ;
678     
679 expression
680     :   ^(EXPR expr)
681         -> {$expr.st}
682     |   domainExpression[null]
683         -> {$domainExpression.st}
684     ;
685
686 expr
687     :   ^(ASSIGNMENT e1=expr e2=expr)
688         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> = <e2>"
689     |   ^('+=' e1=expr e2=expr)
690         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> += <e2>"
691     |   ^('-=' e1=expr e2=expr)
692         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> -= <e2>"
693     |   ^('*=' e1=expr e2=expr)
694         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> *= <e2>"
695     |   ^('/=' e1=expr e2=expr)
696         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> /= <e2>"
697     |   ^('&=' e1=expr e2=expr)
698         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> &= <e2>"
699     |   ^('|=' e1=expr e2=expr)
700         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> |= <e2>"
701     |   ^('^=' e1=expr e2=expr)
702         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> ^= <e2>"
703     |   ^('%=' e1=expr e2=expr)
704         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> %= <e2>"
705     |   ^('>>>=' e1=expr e2=expr)
706         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \>\>\>= <e2>"
707     |   ^('>>=' e1=expr e2=expr)
708         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \>\>= <e2>"
709     |   ^('<<=' e1=expr e2=expr)
710         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \<\<= <e2>"
711     |   ^('?' e1=expr e2=expr e3=expr)
712         -> template(e1={$e1.st}, e2={$e2.st}, e3={$e3.st}) "<e1> ? <e2> : <e3>"
713     |   ^('||' e1=expr e2=expr)
714         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> || <e2>"
715     |   ^('&&' e1=expr e2=expr)
716         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> && <e2>"
717     |   ^(BITWISE_OR e1=expr e2=expr)
718         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> | <e2>"
719     |   ^('^' e1=expr e2=expr)
720         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> ^ <e2>"
721     |   ^('&' e1=expr e2=expr)
722         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> & <e2>"
723     |   ^(EQUALS e1=expr e2=expr)
724         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> == <e2>"
725     |   ^('!=' e1=expr e2=expr)
726         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> != <e2>"
727     |   ^('instanceof' expr type)
728         -> template(t={$text}) "/* instanceof not implemented */ <t>"
729     |   ^('<=' e1=expr e2=expr)
730         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \<= <e2>"
731     |   ^('>=' e1=expr e2=expr)
732         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \>= <e2>"
733     |   ^('>>>' e1=expr e2=expr)
734         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \>\>\> <e2>"
735     |   ^('>>' e1=expr e2=expr)
736         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \>\> <e2>"
737     |   ^('>' e1=expr e2=expr)
738         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \> <e2>"
739     |   ^('<<' e1=expr e2=expr)
740         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \<\< <e2>"
741     |   ^('<' e1=expr e2=expr)
742         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \< <e2>"
743     |   ^('+' e1=expr e2=expr)
744         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> + <e2>"
745     |   ^('-' e1=expr e2=expr)
746         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> - <e2>"
747     |   ^('*' e1=expr e2=expr)
748         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> * <e2>"
749     |   ^('/' e1=expr e2=expr)
750         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> / <e2>"
751     |   ^('%' e1=expr e2=expr)
752         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> % <e2>"
753     |   ^(UNARY_PLUS e1=expr)
754         -> template(e1={$e1.st}) "+<e1>"
755     |   ^(UNARY_MINUS e1=expr)
756         -> template(e1={$e1.st}) "-<e1>"
757     |   ^(PRE_INC e1=expr)
758         -> template(e1={$e1.st}) "++<e1>"
759     |   ^(PRE_DEC e1=expr)
760         -> template(e1={$e1.st}) "--<e1>"
761     |   ^(POST_INC e1=expr)
762         -> template(e1={$e1.st}) "<e1>++"
763     |   ^(POST_DEC e1=expr)
764         -> template(e1={$e1.st}) "<e1>--"
765     |   ^(TILDE e1=expr)
766         -> template(e1={$e1.st}) "~<e1>"
767     |   ^(NOT e1=expr)
768         -> template(e1={$e1.st}) "!<e1>"
769     |   ^(CAST_EXPR ty=type e1=expr)
770         -> template(ty={$ty.st}, e1={$e1.st}) "(<ty>)<e1>"
771     |   primaryExpression
772         -> {$primaryExpression.st}
773     ;
774
775 primaryExpression
776     :   ^(DOT prim=primaryExpression
777             ( IDENT   -> template(id={$IDENT}, prim={$prim.st}) "<prim>.<id>"
778             | THIS    -> template(prim={$prim.st}) "<prim>.this"
779             | SUPER   -> template(prim={$prim.st}) "<prim>.super"
780             )
781         )
782     |   ^(ARROW prim=primaryExpression
783             ( IDENT   -> template(id={$IDENT}, prim={$prim.st}) "<prim>-><id>"
784             | THIS    -> template(prim={$prim.st}) "<prim>->this"
785             | SUPER   -> template(prim={$prim.st}) "<prim>->super"
786             )
787         )
788     |   parenthesizedExpression
789         -> {$parenthesizedExpression.st}
790     |   IDENT
791         -> {%{$start.getText()}}
792     |   ^(METHOD_CALL pe=primaryExpression gtal=genericTypeArgumentList? args=arguments)
793         -> method_call(primary={$pe.st}, generic_types={$gtal.st}, args={$args.st})
794     |   ^(ENTRY_METHOD_CALL pe=primaryExpression gtal=genericTypeArgumentList? args=arguments)
795         -> method_call(primary={$pe.st}, generic_types={$gtal.st}, args={$args.st})
796     |   explicitConstructorCall
797         -> {$explicitConstructorCall.st}
798     |   ^(ARRAY_ELEMENT_ACCESS pe=primaryExpression ex=expression)
799         -> template(pe={$pe.st}, ex={$ex.st}) "<pe>[<ex>]"
800     |   literal
801         -> {$literal.st}
802     |   newExpression[null, false]
803         -> {$newExpression.st}
804     |   THIS
805         -> {%{$start.getText()}}
806     |   arrayTypeDeclarator
807         -> {$arrayTypeDeclarator.st}
808     |   SUPER
809         -> {%{$start.getText()}}
810     |   GETNUMPES
811         ->  template() "CkNumPes()"
812     |   GETNUMNODES
813         ->  template() "CkNumNodes()"
814     |   GETMYPE
815         ->  template() "CkMyPe()"
816     |   GETMYNODE
817         ->  template() "CkMyNode()"
818     |   GETMYRANK
819         ->  template() "CkMyRank()"
820
821     ;
822     
823 explicitConstructorCall
824     :   ^(THIS_CONSTRUCTOR_CALL genericTypeArgumentList? arguments)
825         -> template(t={$text}) "<t>"
826     |   ^(SUPER_CONSTRUCTOR_CALL primaryExpression? genericTypeArgumentList? arguments)
827         -> template(t={$text}) "<t>"
828     ;
829
830 arrayTypeDeclarator
831     :   ^(ARRAY_DECLARATOR (arrayTypeDeclarator | qualifiedIdentifier | primitiveType))
832         -> template(t={$text}) "<t>"
833     ;
834
835 newExpression[StringTemplate obtype, boolean output] returns [StringTemplate initArray]
836     :   ^(NEW_EXPRESSION arguments? domainExpression[$arguments.args])
837         -> {$output}? template(domain={$domainExpression.st},type={$obtype}) "new <type>(<domain>)"
838         -> {!$output}? template() ""
839         ->
840     |   ^(NEW proxyType arguments)
841         -> template(t={$proxyType.st}, a={$arguments.st}) "<t>::ckNew(<a>)"
842     |   ^(NEW nonProxyType arguments)
843         -> template(q={$nonProxyType.st}, a={$arguments.st}) "new <q>(<a>)"
844     ;
845
846 /*newExpression
847     :   ^(  STATIC_ARRAY_CREATOR
848             (   primitiveType newArrayConstruction
849             |   genericTypeArgumentList? qualifiedTypeIdent newArrayConstruction
850             )
851         )
852         -> template(t={$text}) "<t>"
853     |   ^(NEW proxyType arguments)
854         -> template(t={$proxyType.st}, a={$arguments.st}) "<t>::ckNew(<a>)"
855     |   ^(NEW nonProxyType arguments)
856         -> template(q={$nonProxyType.st}, a={$arguments.st}) "new <q>(<a>)"
857     ;
858 */
859 /*newArrayConstruction
860     :   arrayDeclaratorList arrayInitializer
861         -> array_construction_with_init(
862                 array_decls={$arrayDeclaratorList.st},
863                 initializer={$arrayInitializer.st})
864     |   (ex+=expression)+ adl=arrayDeclaratorList?
865         -> array_construction(exprs={$ex}, array_decls={$adl.st})
866     ;
867 */
868 arguments returns [List<StringTemplate> args]
869 @init {
870     $args = new ArrayList<StringTemplate>();
871 }
872     :   ^(ARGUMENT_LIST (e=expression { $args.add($e.st); } )*)        
873         ->  arguments(exprs={$args})
874     ;
875
876 literal
877 @init {
878 $st = %{$start.getText()};
879 }
880     :   HEX_LITERAL
881     |   OCTAL_LITERAL
882     |   DECIMAL_LITERAL
883     |   FLOATING_POINT_LITERAL
884     |   CHARACTER_LITERAL
885     |   STRING_LITERAL
886     |   TRUE
887     |   FALSE
888     |   NULL
889     ;
890