Charj: fix missing modifier and consolidate entry method output rules
[charm.git] / src / langs / charj / src / charj / translator / CharjEmitter.g
1 /**
2  * ANTLR (v3) Tree Parser for the Charj Language
3  */
4
5 tree grammar CharjEmitter;
6
7 options {
8     backtrack = true; 
9     memoize = true;
10     tokenVocab = Charj;
11     ASTLabelType = CharjAST;
12     output = template;
13 }
14
15
16 @header {
17 package charj.translator;
18 }
19
20
21 @members {
22     SymbolTable symtab = null;
23
24     PackageScope currentPackage = null;
25     ClassSymbol currentClass = null;
26     MethodSymbol currentMethod = null;
27     LocalScope currentLocalScope = null;
28
29     Translator translator_;
30     OutputMode mode_;
31
32     private boolean emitCC() { return mode_ == OutputMode.cc; }
33     private boolean emitCI() { return mode_ == OutputMode.ci; }
34     private boolean emitH() { return mode_ == OutputMode.h; }
35     private boolean debug() { return translator_.debug(); }
36     private String basename() { return translator_.basename(); }
37
38     /**
39      *  Override ANTLR's token mismatch behavior so we throw exceptions early.
40      */
41     protected void mismatch(IntStream input, int ttype, BitSet follow)
42         throws RecognitionException {
43         throw new MismatchedTokenException(ttype, input);
44     }
45
46     /**
47      *  Override ANTLR's set mismatch behavior so we throw exceptions early.
48      */
49     public Object recoverFromMismatchedSet(IntStream input, RecognitionException e, BitSet follow)
50         throws RecognitionException {
51         throw e;
52     }
53
54     /**
55      *  Test a list of CharjAST nodes to see if any of them has the given token
56      *  type.
57      */
58     public boolean listContainsToken(List<CharjAST> list, int tokenType) {
59         if (list == null) return false;
60         for (CharjAST node : list) {
61             if (node.token.getType() == tokenType) {
62                 return true;
63             }
64         }
65         return false;
66     }
67 }
68
69
70 // Replace default ANTLR generated catch clauses with this action, allowing early failure.
71 @rulecatch {
72     catch (RecognitionException re) {
73         reportError(re);
74         throw re;
75     }
76 }
77
78
79 // Starting point for parsing a Charj file.
80 charjSource[SymbolTable symtab, OutputMode m]
81 @init {
82     this.symtab = symtab;
83     this.translator_ = symtab.translator;
84     this.mode_ = m;
85 }
86     :   ^(CHARJ_SOURCE (p=packageDeclaration)? 
87         (i+=importDeclaration)*
88         (r+=readonlyDeclaration)*
89         (t+=typeDeclaration)*)
90         -> {emitCC()}? charjSource_cc(basename={basename()}, pd={$p.names}, imports={$i}, types={$t}, ros={$r}, debug={debug()})
91         -> {emitCI()}? charjSource_ci(basename={basename()}, pd={$p.names}, imports={$i}, types={$t}, ros={$r}, debug={debug()})
92         -> {emitH()}? charjSource_h(basename={basename()}, pd={$p.names}, imports={$i}, types={$t}, ros={$r}, debug={debug()})
93         ->
94     ;
95
96 topLevelDeclaration
97     :   importDeclaration -> {$importDeclaration.st;}
98     |   typeDeclaration -> {$typeDeclaration.st;}
99     ;
100
101 packageDeclaration returns [List names]
102     :   ^('package' (ids+=IDENT)+)
103         {
104             $names = $ids;
105         }
106         ->
107     ;
108
109 readonlyDeclaration
110     :   ^(READONLY lvd=localVariableDeclaration)
111         -> {emitCI()}? template(bn={basename()}, v={$lvd.st}) "readonly <v>"
112         -> {emitH()}? template(v={$lvd.st}) "extern <v>"
113         -> {emitCC()}? {$lvd.st;}
114         ->
115     ;
116     
117 importDeclaration
118 @init {
119     String importID = null;
120 }
121     :   ^('import' qualifiedIdentifier ds='.*'?)
122         {
123             importID = $qualifiedIdentifier.text;
124             if ($ds != null) {
125             }
126         }
127         {$ds == null}? // TODO: add support for importing x.*
128         -> {(emitCC() || emitH())}? importDeclaration_cc_h(
129             inc_id={importID.replace(".","/")},
130             use_id={importID.replace(".","::")})
131         ->
132     ;
133     
134 typeDeclaration
135 @init {
136     boolean needsMigration = false;
137     List<String> inits = new ArrayList<String>();
138     List<String> pupInits = new ArrayList<String>();
139 }
140     :   ^(TYPE CLASS IDENT (^('extends' su=type))? (^('implements' type+))?
141         {
142             currentClass = (ClassSymbol)$IDENT.def;
143
144             inits = currentClass.generateInits(currentClass.initializers);
145         }
146         (csds+=classScopeDeclaration)*)
147         -> {emitCC()}? classDeclaration_cc(
148                 sym={currentClass},
149                 ident={$IDENT.text}, 
150                 ext={$su.st}, 
151                 csds={$csds},
152                 inits={inits})
153         -> {emitH()}?  classDeclaration_h(
154                 sym={currentClass},
155                 ident={$IDENT.text}, 
156                 ext={$su.st}, 
157                 csds={$csds})
158         ->
159     |   ^('template' (i0+=IDENT*) ^('class' i1=IDENT (^('extends' su=type))? (^('implements' type+))? (csds+=classScopeDeclaration)*))
160         -> {emitH()}? templateDeclaration_h(
161             tident={$i0},
162             ident={$i1.text},
163             ext={$su.st},
164             csds={$csds})
165         -> 
166     |   ^(INTERFACE IDENT (^('extends' type+))? interfaceScopeDeclaration*)
167         -> template(t={$text}) "/*INTERFACE-not implemented*/ <t>"
168     |   ^(ENUM IDENT (^('implements' type+))? classScopeDeclaration*)
169         -> template(t={$text}) "/*ENUM-not implemented*/ <t>"
170     |   ^(TYPE chareType IDENT (^('extends' type))? (^('implements' type+))?
171         {
172             currentClass = (ClassSymbol)$IDENT.def;
173             needsMigration = currentClass.isChareArray && !currentClass.hasMigrationCtor;
174
175             inits = currentClass.generateInits(currentClass.initializers);
176             pupInits = currentClass.generateInits(currentClass.pupInitializers);
177         }
178         (csds+=classScopeDeclaration)*)
179         -> {emitCC()}? chareDeclaration_cc(
180                 sym={currentClass},
181                 ident={$IDENT.text}, 
182                 ext={$su.st}, 
183                 csds={$csds},
184                 pupInits={pupInits},
185                 pupers={currentClass.generatePUPers()},
186                 needsMigration={needsMigration},
187                 inits={inits})
188         -> {emitCI()}? chareDeclaration_ci(
189                 basename={basename()},
190                 sym={currentClass},
191                 chareType={$chareType.st},
192                 arrayDim={null},
193                 ident={$IDENT.text}, 
194                 ext={$su.st}, 
195                 csds={$csds})
196         -> {emitH()}? chareDeclaration_h(
197                 sym={currentClass},
198                 ident={$IDENT.text}, 
199                 ext={$su.st}, 
200                 csds={$csds},
201                 needsPupInit={pupInits.size() > 0},
202                 needsMigration={needsMigration})
203         ->
204     ;
205
206 chareType
207 @init {
208 $st = %{$start.getText()};
209 }
210     :   CHARE
211     |   GROUP
212     |   NODEGROUP
213     |   MAINCHARE
214     |   ^(CHARE_ARRAY ARRAY_DIMENSION)
215         -> template(t={$ARRAY_DIMENSION.text}) "array [<t>]"
216     ;
217
218 enumConstant
219     :   ^(IDENT arguments?)
220         -> template(t={$text}) "/*enumConstant-not implemented*/ <t>"
221     ;
222
223 classScopeDeclaration
224 @init
225 {
226     boolean entry = false;
227     boolean migrationCtor = false;
228     boolean sdagMethod = false;
229 }
230     :   ^(FUNCTION_METHOD_DECL m=modifierList? g=genericTypeParameterList? 
231             ty=type IDENT f=formalParameterList
232             { currentMethod = (MethodSymbol)$IDENT.def; }
233             b=block?)
234         -> {emitCC()}? funcMethodDecl_cc(
235                 classSym={currentClass},
236                 methodSym={currentMethod},
237                 modl={$m.st}, 
238                 gtpl={$g.st}, 
239                 ty={$ty.st},
240                 id={$IDENT.text}, 
241                 fpl={$f.st}, 
242                 block={$b.st})
243         -> {emitH()}? funcMethodDecl_h(
244                 modl={$m.st}, 
245                 gtpl={$g.st}, 
246                 ty={$ty.st},
247                 id={$IDENT.text}, 
248                 fpl={$f.st}, 
249                 block={$b.st})
250         -> {emitCI()}? // do nothing, since it's not an entry method
251         ->
252     |   ^(ENTRY_FUNCTION_DECL m=modifierList? g=genericTypeParameterList? 
253             ty=type IDENT f=formalParameterList a=domainExpression[null]? 
254             {
255                 currentMethod = (MethodSymbol)$IDENT.def;
256                 sdagMethod = currentMethod.hasSDAG;
257             }
258             b=block?) 
259         -> {emitCC()}? funcMethodDecl_cc(
260                 classSym={currentClass},
261                 methodSym={currentMethod},
262                 modl={$m.st}, 
263                 gtpl={$g.st}, 
264                 ty={$ty.st},
265                 id={$IDENT.text}, 
266                 fpl={$f.st}, 
267                 adl={$a.st},
268                 block={$b.st})
269         -> {emitH()}? funcMethodDecl_h(
270                 modl={$m.st}, 
271                 gtpl={$g.st}, 
272                 ty={$ty.st},
273                 id={$IDENT.text}, 
274                 fpl={$f.st}, 
275                 adl={$a.st},
276                 block={$b.st})
277         -> {emitCI()}? funcMethodDecl_ci(
278                 modl={$m.st}, 
279                 gtpl={$g.st}, 
280                 ty={$ty.st},
281                 id={$IDENT.text}, 
282                 fpl={$f.st}, 
283                 block={$b.st})
284         ->
285     |   ^(SDAG_FUNCTION_DECL m=modifierList? g=genericTypeParameterList? 
286             ty=type IDENT f=formalParameterList a=domainExpression[null]? 
287             {
288             currentMethod = (MethodSymbol)$IDENT.def;
289             sdagMethod = currentMethod.hasSDAG;
290             }
291             ^(BLOCK (sdg+=sdagBasicBlock)*))
292             //sdgb=nakedSdagBlock?) 
293         -> {emitCI()}? funcMethodDecl_sdag_ci(
294                 classSym={currentClass},
295                 methodSym={currentMethod},
296                 modl={$m.st}, 
297                 gtpl={$g.st}, 
298                 ty={$ty.st},
299                 id={$IDENT.text}, 
300                 fpl={$f.st}, 
301                 adl={$a.st},
302                 block={$sdg})
303         ->
304     |   ^(DIVCON_METHOD_DECL modifierList? type IDENT formalParameterList divconBlock)
305     |   ^(PRIMITIVE_VAR_DECLARATION modifierList? simpleType variableDeclaratorList[null])
306         -> {emitH()}? class_var_decl(
307             modl={$modifierList.st},
308             type={$simpleType.st},
309             declList={$variableDeclaratorList.st})
310         ->
311     |   ^(OBJECT_VAR_DECLARATION modifierList? objectType variableDeclaratorList[$objectType.st])
312         -> {emitH()}? class_var_decl(
313             modl={$modifierList.st},
314             type={$objectType.st},
315             declList={$variableDeclaratorList.st})
316         ->
317     |   ^(CONSTRUCTOR_DECL m=modifierList? g=genericTypeParameterList? IDENT f=formalParameterList
318             {
319                 currentMethod = (MethodSymbol)$IDENT.def;
320             }
321             b=block)
322         -> {emitCC()}? ctorDecl_cc(
323                 modl={$m.st},
324                 gtpl={$g.st}, 
325                 id={$IDENT.text}, 
326                 fpl={$f.st}, 
327                 block={$b.st})
328         -> {emitCI()}? // do nothing, it's not an entry constructor
329         -> {emitH()}? ctorDecl_h(
330                 modl={$m.st},
331                 gtpl={$g.st}, 
332                 id={$IDENT.text}, 
333                 fpl={$f.st}, 
334                 block={$b.st})
335         ->
336     |   ^(ENTRY_CONSTRUCTOR_DECL m=modifierList? g=genericTypeParameterList? IDENT f=formalParameterList
337             {
338                 currentMethod = (MethodSymbol)$IDENT.def;
339                 migrationCtor = currentClass.migrationCtor == $ENTRY_CONSTRUCTOR_DECL;
340             }
341             b=block)
342         -> {emitCC()}? ctorDecl_cc(
343                 modl={$m.st},
344                 gtpl={$g.st}, 
345                 id={$IDENT.text}, 
346                 fpl={$f.st}, 
347                 block={$b.st})
348         -> {emitCI() && !migrationCtor}? ctorDecl_ci(
349                 modl={$m.st},
350                 gtpl={$g.st}, 
351                 id={$IDENT.text}, 
352                 fpl={$f.st}, 
353                 block={$b.st})
354         -> {emitH()}? ctorDecl_h(
355                 modl={$m.st},
356                 gtpl={$g.st}, 
357                 id={$IDENT.text}, 
358                 fpl={$f.st}, 
359                 block={$b.st})
360         ->
361     ;
362     
363 interfaceScopeDeclaration
364     :   ^(FUNCTION_METHOD_DECL modifierList? genericTypeParameterList? type IDENT formalParameterList)
365         -> template(t={$text}) "/*interfaceScopeDeclarations-not implemented */ <t>"
366     |   ^(PRIMITIVE_VAR_DECLARATION modifierList? simpleType variableDeclaratorList[$simpleType.st])
367         -> template(t={$text}) "/*interfaceScopeDeclarations-not implemented */ <t>"
368     |   ^(OBJECT_VAR_DECLARATION modifierList? objectType variableDeclaratorList[$objectType.st])
369         -> template(t={$text}) "/*interfaceScopeDeclarations-not implemented */ <t>"
370     ;
371
372 variableDeclaratorList[StringTemplate obtype]
373     :   ^(VAR_DECLARATOR_LIST (var_decls+=variableDeclarator[obtype])+ )
374         -> var_decl_list(var_decls={$var_decls})
375     ;
376
377 variableDeclarator[StringTemplate obtype]
378     :   ^(VAR_DECLARATOR id=variableDeclaratorId initializer=variableInitializer[obtype]?)
379         -> {emitCC()}? var_decl_cc(id={$id.st}, initializer={$initializer.st})
380         -> {emitH()}?  var_decl_h(id={$id.st}, initializer={$initializer.st})
381         -> {emitCI()}? var_decl_ci(id={$id.st}, initializer={$initializer.st})
382         ->
383     ; 
384     
385 variableDeclaratorId
386     :   ^(IDENT de=domainExpression[null]?)
387         -> var_decl_id(id={$IDENT.text}, domainExp={$de.st})
388     ;
389
390 variableInitializer[StringTemplate obtype]
391     :   arrayInitializer
392         -> {$arrayInitializer.st}
393     |   newExpression[obtype]
394         -> {$newExpression.st}
395     |   expression
396         -> {$expression.st}
397     ;
398
399 rangeItem
400     :   dl=DECIMAL_LITERAL
401         -> template(t={$dl.text}) "<t>"
402     |   IDENT
403         -> template(t={$IDENT.text}) "<t>"
404     ;
405
406 rangeExpression
407     :   ^(RANGE_EXPRESSION (ri+=rangeItem)*)
408         -> template(t={$ri}) "Range(<t; separator=\",\">)"
409     ;
410
411 rangeList returns [int len]
412     :   (r+=rangeExpression)*
413         { $len = $r.size(); }
414         -> template(t={$r}) "<t; separator=\", \">"
415     ;
416
417 domainExpression[List<StringTemplate> otherParams]
418     :   ^(DOMAIN_EXPRESSION rl=rangeList)
419         -> range_constructor(range={$rl.st}, others={$otherParams}, len={$rl.len})
420     ;
421
422 domainExpressionAccess
423     :   ^(DOMAIN_EXPRESSION rl=rangeListAccess)
424         -> template(t={$rangeListAccess.st}) "<t>"
425     ;
426
427 rangeListAccess
428     :   (r+=rangeExpressionAccess)*
429         -> template(t={$r}) "<t; separator=\", \">"
430     ;
431
432 rangeExpressionAccess
433     :   ^(RANGE_EXPRESSION (ri+=rangeItem)*)
434         -> template(t={$ri}) "<t; separator=\",\">"
435     ;
436
437 arrayInitializer
438     :   ^(ARRAY_INITIALIZER variableInitializer[null]*)
439         -> template(t={$text}) "/* arrayInitializer-not implemented */ <t>"
440     ;
441
442 genericTypeParameterList
443     :   ^(GENERIC_TYPE_PARAM_LIST genericTypeParameter+)
444         -> template(t={$text}) "/*GENERIC_TYPE_PARAM_LIST-not implemented*/ <t>"
445     ;
446
447 genericTypeParameter
448     :   ^(IDENT bound?)
449         -> template(t={$text}) "/*genericTypeParameter-not implemented*/ <t>"
450     ;
451         
452 bound
453     :   ^(EXTENDS_BOUND_LIST type+)
454         -> template(t={$text}) "/*EXTENDS_BOUND_LIST-not implemented*/ <t>"
455     ;
456
457 throwsClause
458     :   ^(THROWS_CLAUSE qualifiedIdentifier+)
459         -> template(t={$text}) "/* throwsClause-not implemented */ <t>"
460     ;
461
462 modifierList
463     :   ^(MODIFIER_LIST accessModifierList localModifierList charjModifierList otherModifierList)
464         ->  {emitCC()}? mod_list_cc(accmods = {$accessModifierList.names}, localmods = {$localModifierList.names}, charjmods = {$charjModifierList.names}, othermods = {$otherModifierList.names})
465         ->  {emitH()}? mod_list_h(accmods = {$accessModifierList.names}, localmods = {$localModifierList.names}, charjmods = {$charjModifierList.names}, othermods = {$otherModifierList.names})
466         ->  {emitCI()}? mod_list_ci(accmods = {$accessModifierList.names}, localmods = {$localModifierList.names}, charjmods = {$charjModifierList.names}, othermods = {$otherModifierList.names})
467         ->
468     ;
469
470 modifier
471     :   accessModifier
472     |   localModifier
473     |   charjModifier
474     |   otherModifier
475     ;
476
477 accessModifierList
478 returns [List names]
479     :   ^(ACCESS_MODIFIER_LIST (m+=accessModifier)*)
480         {
481             $names = $m;
482         }
483     ;
484 localModifierList
485 returns [List names]
486     :   ^(LOCAL_MODIFIER_LIST (m+=localModifier)*)
487         {
488             $names = $m;
489         }
490         ->  local_mod_list(mods = {$names})
491     ;
492
493 charjModifierList
494 returns [List names]
495     :   ^(CHARJ_MODIFIER_LIST (m+=charjModifier)*)
496         {
497             $names = $m;
498         }
499     ;
500
501 otherModifierList
502 returns [List names]
503     :   ^(OTHER_MODIFIER_LIST (m+=otherModifier)*)
504         {
505             $names = $m;
506         }
507     ;
508     
509 localModifier
510 @init
511 {
512     $st = %{$start.getText()};
513 }
514     :   FINAL
515     |   STATIC
516     |   VOLATILE
517     ;
518
519 accessModifier
520 @init
521 {
522     $st = %{$start.getText()};
523 }
524     :   PUBLIC
525     |   PROTECTED
526     |   PRIVATE
527         {
528             $st = %{"private"};
529         }
530     ;
531
532 charjModifier
533     :   ENTRY -> {%{$ENTRY.text}}
534     |   SDAGENTRY -> template() "entry"
535     |   TRACED
536     ;
537
538 otherModifier
539 @init
540 {
541     $st = %{$start.getText()};
542 }
543     :   ABSTRACT
544     |   NATIVE
545     ;
546     
547 type
548     :   simpleType
549         -> {$simpleType.st}
550     |   objectType 
551         -> {$objectType.st}
552     |   VOID
553         {
554             $st = %{"void"};
555         }
556     ;
557
558 simpleType
559     :   ^(SIMPLE_TYPE primitiveType domainExpression[null]?)
560         -> simple_type(typeID={$primitiveType.st}, arrDeclList={$domainExpression.st})
561     ;
562
563 objectType //[boolean forNewExpression]
564     : proxyType -> {$proxyType.st;}
565     | nonProxyType -> {$nonProxyType.st}
566     ;
567
568 nonProxyType
569     :   ^(OBJECT_TYPE qualifiedTypeIdent domainExpression[null]?)
570         -> obj_type(typeID={$qualifiedTypeIdent.st}, arrDeclList={$domainExpression.st})
571     |   ^(POINTER_TYPE qualifiedTypeIdent domainExpression[null]?)
572         -> pointer_type(typeID={$qualifiedTypeIdent.st}, arrDeclList={$domainExpression.st})
573     |   ^(REFERENCE_TYPE qualifiedTypeIdent domainExpression[null]?)
574         -> reference_type(typeID={$qualifiedTypeIdent.st}, arrDeclList={$domainExpression.st})
575     ;
576
577 proxyType
578     :   ^(PROXY_TYPE qualifiedTypeIdent domainExpression[null]?)
579         -> proxy_type(typeID={$qualifiedTypeIdent.st}, arrDeclList={$domainExpression.st})
580         |       ^(ARRAY_SECTION_TYPE qualifiedTypeIdent domainExpression[null]?) // TODO array sections
581                 -> template() "not implemented yet"
582     ;
583
584 qualifiedTypeIdent returns [ClassSymbol type]
585     :   ^(QUALIFIED_TYPE_IDENT (t+=typeIdent)+)
586         {$type = (ClassSymbol)$QUALIFIED_TYPE_IDENT.def;}
587         -> template(types={$t}) "<types; separator=\"::\">"
588     ;
589
590 typeIdent
591     :   ^(IDENT templateInstantiation?)
592         -> typeIdent(typeID={$IDENT.text}, generics={$templateInstantiation.st})
593     ;
594
595 primitiveType
596 @init {
597 $st = %{$start.getText()};
598 }
599     :   BOOLEAN
600         -> template() "bool"
601     |   CHAR
602     |   BYTE
603         -> template() "char"
604     |   SHORT
605     |   INT
606     |   LONG
607     |   FLOAT
608     |   DOUBLE
609     ;
610
611 templateArg
612     :   genericTypeArgument
613         -> {$genericTypeArgument.st}
614     |   literal
615         -> {$literal.st}
616     ;
617
618 templateArgList
619     :   params+=templateArg+
620         -> template(params={$params}) "<params; separator=\", \">"
621     ;
622
623 templateInstantiation
624     :   ^(TEMPLATE_INST templateArgList)
625         -> template(args={$templateArgList.st}) "\<<args>\>"
626     |   ^(TEMPLATE_INST ts=templateInstantiation)
627         -> template(inst={$ts.st}) "\<<inst>\>"
628     ;
629
630 genericTypeArgumentList
631     :   ^(GENERIC_TYPE_ARG_LIST (gta+=genericTypeArgument)+)
632         -> template(gtal={$gta}) "\<<gtal; separator=\", \">\>"
633     ;
634
635 genericTypeArgument
636     :   type
637         -> {$type.st}
638     |   '?'
639         -> template(t={$text}) "/* genericTypeArgument: wildcard bound types not implemented */ <t>"
640     ;
641
642 formalParameterList
643     :   ^(FORMAL_PARAM_LIST (fpsd+=formalParameterStandardDecl)* fpvd=formalParameterVarargDecl?)
644         -> formal_param_list(sdecl={$fpsd}, vdecl={$fpvd.st})
645     ;
646     
647 formalParameterStandardDecl
648     :   ^(FORMAL_PARAM_STD_DECL lms=localModifierList? t=type vdid=variableDeclaratorId)
649         -> formal_param_decl(modList={$lms.st}, type={$t.st}, declID={$vdid.st})
650     ;
651     
652 formalParameterVarargDecl
653     :   ^(FORMAL_PARAM_VARARG_DECL localModifierList? type variableDeclaratorId)
654         -> template(t={$text}) "/*formal parameter varargs not implemented*/ <t>"
655     ;
656     
657 qualifiedIdentifier
658     :   IDENT
659         -> template(t={$text}) "<t>"
660     |   ^(DOT qualifiedIdentifier IDENT)
661         -> template(t={$text}) "<t>"
662     ;
663     
664 block
665 @init { boolean emptyBlock = true; }
666     :   ^(BLOCK (b+=blockStatement)*)
667         { emptyBlock = ($b == null || $b.size() == 0); }
668         -> {((emitCC() && (currentMethod == null || !currentMethod.hasSDAG)) ||
669             (emitCI() && (currentMethod != null && currentMethod.hasSDAG))) && emptyBlock}? template(bsl={$b}) "{ }"
670         -> {emitCC() && (currentMethod == null || !currentMethod.hasSDAG)}? block_cc(bsl={$b})
671         -> {emitCI() && (currentMethod != null && currentMethod.hasSDAG)}? block_cc(bsl={$b})
672         ->
673     ;
674
675
676 nakedSdagBlock
677     :   ^(BLOCK (sdg+=sdagBasicBlock)*)
678         -> template(sdg={$sdg}) "<sdg>"
679     ;
680
681
682 sdagBlock
683     :   ^(BLOCK (sdg+=sdagBasicBlock)*)
684         -> block_cc(bsl={$sdg})
685     ;
686
687 sdagBasicBlock
688     :   sdagStatement
689         -> {$sdagStatement.st}
690     |   (s+=statement)+
691         -> block_atomic(s={$s})
692     ;
693     
694 blockStatement
695     :   localVariableDeclaration
696         -> {$localVariableDeclaration.st}
697     |   statement
698         -> {$statement.st}
699     ;
700
701
702 localVariableDeclaration
703     :   ^(PRIMITIVE_VAR_DECLARATION localModifierList? simpleType vdl=variableDeclaratorList[null])
704         -> local_var_decl(
705             modList={$localModifierList.st},
706             type={$simpleType.st},
707             declList={$vdl.st})
708     |   ^(OBJECT_VAR_DECLARATION localModifierList? objectType vdl=variableDeclaratorList[$objectType.st])
709         -> local_var_decl(
710             modList={$localModifierList.st},
711             type={$objectType.st},
712             declList={$vdl.st})
713     ;
714
715
716 statement
717     :   nonBlockStatement
718         -> {$nonBlockStatement.st}
719     |   block
720         -> {$block.st}
721     ;
722
723 divconBlock
724     :   ^(DIVCON_BLOCK divconExpr)
725     ;
726
727 divconAssignment
728     :   ^(LET_ASSIGNMENT IDENT expression)
729     ;
730
731 divconAssignmentList
732     :   divconAssignment+
733     ;
734
735 divconExpr
736     :   ^(IF parenthesizedExpression divconExpr divconExpr?)
737     |   ^(LET divconAssignmentList IN divconExpr)
738     |   expression
739     ;
740
741 sdagStatement
742     :   ^(OVERLAP sdagBlock)
743         -> template(b={$sdagBlock.st}) "overlap <b>"
744     |   ^(WHEN (wa+=whenArgument)* nakedSdagBlock)
745         -> template(w={wa}, b={$nakedSdagBlock.st}) "when <w> <b>"
746     |   ^(SDAG_IF pe=parenthesizedExpression
747             ifblock=sdagBlock elseblock=sdagBlock?)
748         -> if(cond={$pe.st}, then={$ifblock.st}, else_={$elseblock.st})
749     |   ^(SDAG_FOR forInit? FOR_EXPR cond=expression?
750             FOR_UPDATE (update+=expression)* b=sdagBlock)
751         -> for(initializer={$forInit.st}, cond={$cond.st},
752                 update={$update}, body={$b.st})
753     |   ^(SDAG_WHILE pe=parenthesizedExpression b=sdagBlock)
754         -> while(cond={$pe.st}, body={$b.st})
755     |   ^(SDAG_DO b=sdagBlock pe=parenthesizedExpression)
756         -> dowhile(cond={$pe.st}, block={$b.st})
757     ;
758
759 whenArgument
760     :   IDENT expression? formalParameterList
761         -> template(i={$IDENT}, e={$expression.st}, f={$formalParameterList.st}) "<i> <if(e)>[<e>] <endif><f>"
762     ;
763
764 nonBlockStatement
765     :   ^(ASSERT cond=expression msg=expression?)
766         -> assert(cond={$cond.st}, msg={$msg.st})
767     |   ^(IF parenthesizedExpression then=block else_=block?)
768         -> if(cond={$parenthesizedExpression.st}, then={$then.st}, else_={$else_.st})
769     |   ^(FOR forInit? FOR_EXPR cond=expression? FOR_UPDATE (update+=expression)* b=block)
770         -> for(initializer={$forInit.st}, cond={$cond.st}, update={$update}, body={$block.st})
771     |   ^(FOR_EACH localModifierList? type IDENT expression block) 
772         -> template(t={$text}) "/* foreach not implemented */ <t>"
773     |   ^(WHILE pe=parenthesizedExpression b=block)
774         -> while(cond={$pe.st}, body={$b.st})
775     |   ^(DO b=block pe=parenthesizedExpression)
776         -> dowhile(cond={$pe.st}, block={$b.st})
777     |   ^(SWITCH pe=parenthesizedExpression (scls+=switchCaseLabel)*)
778         -> switch(expr={$pe.st}, labels={$scls})
779     |   ^(RETURN e=expression?)
780         -> return(val={$e.st})
781     |   ^(THROW expression)
782         -> template(t={$text}) "/* throw not implemented */ <t>"
783     |   ^(BREAK IDENT?)
784         -> template() "break;" // TODO: support labeling
785     |   ^(CONTINUE IDENT?)
786         -> template() "continue;" // TODO: support labeling
787     |   ^(LABELED_STATEMENT i=IDENT s=statement)
788         -> label(text={$i.text}, stmt={$s.st})
789     |   expression
790         -> template(expr={$expression.st}) "<expr>;"
791     |   ^('delete' expression)
792         -> template(t={$expression.st}) "delete <t>;"
793     |   ^('embed' STRING_LITERAL EMBED_BLOCK)
794         ->  embed_cc(str={$STRING_LITERAL.text}, blk={$EMBED_BLOCK.text})
795     |   ';' // Empty statement.
796         -> {%{$start.getText()}}
797     |   ^(PRINT (exprs += expression)*)
798         ->  print(exprs = {$exprs})
799     |   ^(PRINTLN (exprs += expression)*)
800         ->  println(exprs = {$exprs})
801     |   ^(EXIT expression?)
802         ->  exit(expr = {$expression.st})
803     |   EXITALL
804         ->  exitall()
805     ;
806         
807 switchCaseLabel
808     :   ^(CASE expression (b+=blockStatement)*)
809         -> case(expr={$expression.st}, block={$b})
810     |   ^(DEFAULT (b+=blockStatement)*)
811         -> template(block={$b}) "default: <block>"
812     ;
813     
814 forInit
815     :   localVariableDeclaration
816         -> template(lvd={$localVariableDeclaration.st}) "<lvd>"
817     |   (ex+=expression)+
818         -> template(ex={$ex}) "<ex; separator=\", \">"
819     ;
820
821 // EXPRESSIONS
822
823 parenthesizedExpression
824     :   ^(PAREN_EXPR exp=expression)
825         -> template(expr={$exp.st}) "(<expr>)"
826     ;
827
828 expressionArrayAccess
829     :   ^(EXPR expr)
830         -> {$expr.st}
831     |    domainExpressionAccess
832         -> {$domainExpressionAccess.st}
833     ;
834     
835 expression
836     :   ^(EXPR expr)
837         -> {$expr.st}
838     |   domainExpression[null]
839         -> {$domainExpression.st}
840     ;
841
842 expr
843     :   ^(ASSIGNMENT e1=expr e2=expr)
844         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> = <e2>"
845     |   ^('+=' e1=expr e2=expr)
846         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> += <e2>"
847     |   ^('-=' e1=expr e2=expr)
848         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> -= <e2>"
849     |   ^('*=' e1=expr e2=expr)
850         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> *= <e2>"
851     |   ^('/=' e1=expr e2=expr)
852         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> /= <e2>"
853     |   ^('&=' e1=expr e2=expr)
854         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> &= <e2>"
855     |   ^('|=' e1=expr e2=expr)
856         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> |= <e2>"
857     |   ^('^=' e1=expr e2=expr)
858         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> ^= <e2>"
859     |   ^('%=' e1=expr e2=expr)
860         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> %= <e2>"
861     |   ^('>>>=' e1=expr e2=expr)
862         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \>\>\>= <e2>"
863     |   ^('>>=' e1=expr e2=expr)
864         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \>\>= <e2>"
865     |   ^('<<=' e1=expr e2=expr)
866         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \<\<= <e2>"
867     |   ^('?' e1=expr e2=expr e3=expr)
868         -> template(e1={$e1.st}, e2={$e2.st}, e3={$e3.st}) "<e1> ? <e2> : <e3>"
869     |   ^('||' e1=expr e2=expr)
870         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> || <e2>"
871     |   ^('&&' e1=expr e2=expr)
872         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> && <e2>"
873     |   ^(BITWISE_OR e1=expr e2=expr)
874         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> | <e2>"
875     |   ^('^' e1=expr e2=expr)
876         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> ^ <e2>"
877     |   ^('&' e1=expr e2=expr)
878         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> & <e2>"
879     |   ^(EQUALS e1=expr e2=expr)
880         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> == <e2>"
881     |   ^('!=' e1=expr e2=expr)
882         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> != <e2>"
883     |   ^('instanceof' expr type)
884         -> template(t={$text}) "/* instanceof not implemented */ <t>"
885     |   ^('<=' e1=expr e2=expr)
886         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \<= <e2>"
887     |   ^('>=' e1=expr e2=expr)
888         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \>= <e2>"
889     |   ^('>>>' e1=expr e2=expr)
890         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \>\>\> <e2>"
891     |   ^('>>' e1=expr e2=expr)
892         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \>\> <e2>"
893     |   ^('>' e1=expr e2=expr)
894         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \> <e2>"
895     |   ^('<<' e1=expr e2=expr)
896         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \<\< <e2>"
897     |   ^('<' e1=expr e2=expr)
898         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \< <e2>"
899     |   ^('+' e1=expr e2=expr)
900         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> + <e2>"
901     |   ^('-' e1=expr e2=expr)
902         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> - <e2>"
903     |   ^('*' e1=expr e2=expr)
904         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> * <e2>"
905     |   ^('/' e1=expr e2=expr)
906         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> / <e2>"
907     |   ^('%' e1=expr e2=expr)
908         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> % <e2>"
909     |   ^(UNARY_PLUS e1=expr)
910         -> template(e1={$e1.st}) "+<e1>"
911     |   ^(UNARY_MINUS e1=expr)
912         -> template(e1={$e1.st}) "-<e1>"
913     |   ^(PRE_INC e1=expr)
914         -> template(e1={$e1.st}) "++<e1>"
915     |   ^(PRE_DEC e1=expr)
916         -> template(e1={$e1.st}) "--<e1>"
917     |   ^(POST_INC e1=expr)
918         -> template(e1={$e1.st}) "<e1>++"
919     |   ^(POST_DEC e1=expr)
920         -> template(e1={$e1.st}) "<e1>--"
921     |   ^(TILDE e1=expr)
922         -> template(e1={$e1.st}) "~<e1>"
923     |   ^(NOT e1=expr)
924         -> template(e1={$e1.st}) "!<e1>"
925     |   ^(CAST_EXPR ty=type e1=expr)
926         -> template(ty={$ty.st}, e1={$e1.st}) "(<ty>)<e1>"
927     |   primaryExpression
928         -> {$primaryExpression.st}
929     |   ^(POINTER_DEREFERENCE e1 = expr)
930         ->  template(e = {$e1.st}) "*(<e>)"
931     ;
932
933 primaryExpression
934 @init { int dims = 1; }
935     :   ^(DOT prim=primaryExpression
936             ( IDENT   -> template(id={$IDENT.text}, prim={$prim.st}) "<prim>.<id>"
937             | THIS    -> template(prim={$prim.st}) "<prim>.this"
938             | SUPER   -> template(prim={$prim.st}) "<prim>.super"
939             )
940         )
941     |   ^(ARROW prim=primaryExpression
942             ( IDENT   -> template(id={$IDENT.text}, prim={$prim.st}) "<prim>-><id>"
943             | THIS    -> template(prim={$prim.st}) "<prim>->this"
944             | SUPER   -> template(prim={$prim.st}) "<prim>->super"
945             )
946         )
947     |   parenthesizedExpression
948         -> {$parenthesizedExpression.st}
949     |   IDENT
950         -> {%{$IDENT.text}}
951     |   CHELPER
952         -> {%{"constructorHelper"}}
953     |   ^(METHOD_CALL pe=primaryExpression gtal=genericTypeArgumentList? args=arguments)
954         -> method_call(primary={$pe.st}, generic_types={$gtal.st}, args={$args.st})
955     |   ^(ENTRY_METHOD_CALL pe=primaryExpression gtal=genericTypeArgumentList? args=arguments)
956         -> method_call(primary={$pe.st}, generic_types={$gtal.st}, args={$args.st})
957     |   explicitConstructorCall
958         -> {$explicitConstructorCall.st}
959     |   ^(ARRAY_ELEMENT_ACCESS pe=primaryExpression ex=expressionArrayAccess) {
960             if ($pe.start.symbolType != null && $pe.start.symbolType instanceof PointerType) {
961                 PointerType p = (PointerType)($pe.start.symbolType);
962                 if (p.baseType instanceof ClassSymbol) {
963                     ClassSymbol cs = (ClassSymbol)(p.baseType);
964                     if (cs.templateArgs != null && cs.templateArgs.size() > 1 &&
965                         cs.templateArgs.get(1) instanceof LiteralType) {
966                         LiteralType l = (LiteralType)(cs.templateArgs.get(1));
967                         dims = Integer.valueOf(l.literal);
968                     }
969                 }
970             }
971         }
972         -> {$pe.start.symbolType != null && $pe.start.symbolType instanceof PointerType && dims == 1}?
973                template(pe={$pe.st}, ex={$ex.st}) "(*(<pe>))[<ex>]"
974         -> {$pe.start.symbolType != null && $pe.start.symbolType instanceof PointerType && dims == 2}?
975                template(pe={$pe.st}, ex={$ex.st}) "(*(<pe>)).access(<ex>)"
976         -> template(pe={$pe.st}, ex={$ex.st}) "(<pe>)[<ex>]"
977     |   literal
978         -> {$literal.st}
979     |   newExpression[null]
980         -> {$newExpression.st}
981     |   THIS
982         -> {%{$start.getText()}}
983     |   arrayTypeDeclarator
984         -> {$arrayTypeDeclarator.st}
985     |   SUPER
986         -> {%{$start.getText()}}
987     |   GETNUMPES
988         ->  template() "CkNumPes()"
989     |   GETNUMNODES
990         ->  template() "CkNumNodes()"
991     |   GETMYPE
992         ->  template() "CkMyPe()"
993     |   GETMYNODE
994         ->  template() "CkMyNode()"
995     |   GETMYRANK
996         ->  template() "CkMyRank()"
997         |       THISINDEX
998                 ->      template() "thisIndex"
999         |       THISPROXY
1000                 ->      template() "thisProxy"
1001     |   domainExpression[null]
1002         ->  {$domainExpression.st}
1003     ;
1004     
1005 explicitConstructorCall
1006     :   ^(THIS_CONSTRUCTOR_CALL genericTypeArgumentList? arguments)
1007         -> template(t={$text}) "<t>"
1008     |   ^(SUPER_CONSTRUCTOR_CALL primaryExpression? genericTypeArgumentList? arguments)
1009         -> template(t={$text}) "<t>"
1010     ;
1011
1012 arrayTypeDeclarator
1013     :   ^(ARRAY_DECLARATOR (arrayTypeDeclarator | qualifiedIdentifier | primitiveType))
1014         -> template(t={$text}) "<t>"
1015     ;
1016
1017 newExpression[StringTemplate obtype]
1018     :   ^(NEW_EXPRESSION arguments? domainExpression[$arguments.args])
1019         -> template(domain={$domainExpression.st},type={$obtype}) "new <type>(<domain>)"
1020     |   ^(NEW proxyType arguments)
1021         -> template(t={$proxyType.st}, a={$arguments.st}) "<t>::ckNew(<a>)"
1022     |   ^(NEW nonProxyType arguments)
1023         -> template(q={$nonProxyType.st}, a={$arguments.st}) "new <q>(<a>)"
1024     ;
1025
1026 arguments returns [List<StringTemplate> args]
1027 @init {
1028     $args = new ArrayList<StringTemplate>();
1029 }
1030     :   ^(ARGUMENT_LIST (e=expression { $args.add($e.st); } )*)        
1031         ->  arguments(exprs={$args})
1032     ;
1033
1034 literal
1035 @init {
1036 $st = %{$start.getText()};
1037 }
1038     :   HEX_LITERAL
1039     |   OCTAL_LITERAL
1040     |   DECIMAL_LITERAL
1041     |   FLOATING_POINT_LITERAL
1042     |   CHARACTER_LITERAL
1043     |   STRING_LITERAL
1044     |   TRUE
1045     |   FALSE
1046     |   NULL
1047     ;
1048