892499d578ab6ad4e0e6f5735b8eb3742671e2f2
[charm.git] / src / langs / charj / src / charj / translator / CharjEmitter.g
1 /**
2  * ANTLR (v3) Tree Parser for the Charj Language
3  */
4
5 tree grammar CharjEmitter;
6
7 options {
8     backtrack = true; 
9     memoize = true;
10     tokenVocab = Charj;
11     ASTLabelType = CharjAST;
12     output = template;
13 }
14
15
16 @header {
17 package charj.translator;
18 }
19
20
21 @members {
22     SymbolTable symtab = null;
23
24     PackageScope currentPackage = null;
25     ClassSymbol currentClass = null;
26     MethodSymbol currentMethod = null;
27     LocalScope currentLocalScope = null;
28
29     Translator translator_;
30     OutputMode mode_;
31
32     private boolean emitCC() { return mode_ == OutputMode.cc; }
33     private boolean emitCI() { return mode_ == OutputMode.ci; }
34     private boolean emitH() { return mode_ == OutputMode.h; }
35     private boolean debug() { return translator_.debug(); }
36     private String basename() { return translator_.basename(); }
37
38     /**
39      *  Override ANTLR's token mismatch behavior so we throw exceptions early.
40      */
41     protected void mismatch(IntStream input, int ttype, BitSet follow)
42         throws RecognitionException {
43         throw new MismatchedTokenException(ttype, input);
44     }
45
46     /**
47      *  Override ANTLR's set mismatch behavior so we throw exceptions early.
48      */
49     public Object recoverFromMismatchedSet(IntStream input, RecognitionException e, BitSet follow)
50         throws RecognitionException {
51         throw e;
52     }
53
54     /**
55      *  Test a list of CharjAST nodes to see if any of them has the given token
56      *  type.
57      */
58     public boolean listContainsToken(List<CharjAST> list, int tokenType) {
59         if (list == null) return false;
60         for (CharjAST node : list) {
61             if (node.token.getType() == tokenType) {
62                 return true;
63             }
64         }
65         return false;
66     }
67 }
68
69
70 // Replace default ANTLR generated catch clauses with this action, allowing early failure.
71 @rulecatch {
72     catch (RecognitionException re) {
73         reportError(re);
74         throw re;
75     }
76 }
77
78
79 // Starting point for parsing a Charj file.
80 charjSource[SymbolTable symtab, OutputMode m]
81 @init {
82     this.symtab = symtab;
83     this.translator_ = symtab.translator;
84     this.mode_ = m;
85 }
86     :   ^(CHARJ_SOURCE (p=packageDeclaration)? 
87         (i+=importDeclaration)* 
88         (t=typeDeclaration))
89         -> {emitCC()}? charjSource_cc(basename={basename()}, pd={$p.names}, ids={$i}, tds={$t.st}, debug={debug()})
90         -> {emitCI()}? charjSource_ci(basename={basename()}, pd={$p.names}, ids={$i}, tds={$t.st}, debug={debug()})
91         -> {emitH()}? charjSource_h(basename={basename()}, pd={$p.names}, ids={$i}, tds={$t.st}, debug={debug()})
92         ->
93     ;
94
95 packageDeclaration
96 returns [List names]
97     :   ^('package' (ids+=IDENT)+)
98         {
99             $names = $ids;
100         }
101         ->
102     ;
103     
104 importDeclaration
105 @init {
106     String importID = null;
107 }
108     :   ^('import' qualifiedIdentifier ds='.*'?)
109         {
110             importID = $qualifiedIdentifier.text;
111             if ($ds != null) {
112             }
113         }
114         {$ds == null}? // TODO: add support for importing x.*
115         -> {(emitCC() || emitH())}? importDeclaration_cc_h(
116             inc_id={importID.replace(".","/")},
117             use_id={importID.replace(".","::")})
118         ->
119     ;
120     
121 typeDeclaration
122     :   ^(TYPE CLASS IDENT (^('extends' su=type))? (^('implements' type+))?
123         {
124             currentClass = (ClassSymbol)$IDENT.symbol;
125         }
126         (csds+=classScopeDeclaration)*)
127         -> {emitCC()}? classDeclaration_cc(
128                 sym={currentClass},
129                 ident={$IDENT.text}, 
130                 ext={$su.st}, 
131                 csds={$csds})
132         -> {emitH()}?  classDeclaration_h(
133                 sym={currentClass},
134                 ident={$IDENT.text}, 
135                 ext={$su.st}, 
136                 csds={$csds})
137         ->
138     |   ^(INTERFACE IDENT (^('extends' type+))? interfaceScopeDeclaration*)
139         -> template(t={$text}) "/*INTERFACE-not implemented*/ <t>"
140     |   ^(ENUM IDENT (^('implements' type+))? classScopeDeclaration*)
141         -> template(t={$text}) "/*ENUM-not implemented*/ <t>"
142     |   ^(TYPE chareType IDENT (^('extends' type))? (^('implements' type+))?
143         {
144             currentClass = (ClassSymbol)$IDENT.symbol;
145         }
146         (csds+=classScopeDeclaration)*)
147         -> {emitCC()}? chareDeclaration_cc(
148                 sym={currentClass},
149                 ident={$IDENT.text}, 
150                 ext={$su.st}, 
151                 csds={$csds})
152         -> {emitCI()}? chareDeclaration_ci(
153                 sym={currentClass},
154                 chareType={$chareType.st},
155                 arrayDim={null},
156                 ident={$IDENT.text}, 
157                 ext={$su.st}, 
158                 csds={$csds})
159         -> {emitH()}? chareDeclaration_h(
160                 sym={currentClass},
161                 ident={$IDENT.text}, 
162                 ext={$su.st}, 
163                 csds={$csds})
164         ->
165     ;
166
167 chareType
168 @init {
169 $st = %{$start.getText()};
170 }
171     :   CHARE
172     |   GROUP
173     |   NODEGROUP
174     |   MAINCHARE
175     |   ^(CHARE_ARRAY ARRAY_DIMENSION)
176         -> template(t={$ARRAY_DIMENSION.text}) "array [<t>]"
177     ;
178
179 enumConstant
180     :   ^(IDENT arguments?)
181         -> template(t={$text}) "/*enumConstant-not implemented*/ <t>"
182     ;
183
184 classScopeDeclaration
185 @init {
186   boolean entry = false;
187   List<String> modList = new ArrayList<String>();
188
189 }
190     :   ^(FUNCTION_METHOD_DECL m=modifierList? g=genericTypeParameterList? 
191             ty=type IDENT f=formalParameterList a=arrayDeclaratorList? 
192             b=block?)
193         { 
194             if ($m.st != null) {
195                 // determine whether this is an entry method
196                 entry = listContainsToken($m.start.getChildren(), ENTRY);
197                 for(Object o : $m.names)
198                   if(o.equals("entry")) continue;
199                   else modList.add(o.toString());
200             }
201         }
202         -> {emitCC()}? funcMethodDecl_cc(
203                 sym={currentClass},
204                 modl={modList}, 
205                 gtpl={$g.st}, 
206                 ty={$ty.st},
207                 id={$IDENT.text}, 
208                 fpl={$f.st}, 
209                 adl={$a.st},
210                 block={$b.st})
211         -> {emitH()}? funcMethodDecl_h(
212                 modl={modList}, 
213                 gtpl={$g.st}, 
214                 ty={$ty.st},
215                 id={$IDENT.text}, 
216                 fpl={$f.st}, 
217                 adl={$a.st},
218                 block={$b.st})
219         -> {(emitCI() && entry)}? funcMethodDecl_ci(
220                 modl={$m.st}, 
221                 gtpl={$g.st}, 
222                 ty={$ty.st},
223                 id={$IDENT.text}, 
224                 fpl={$f.st}, 
225                 adl={$a.st},
226                 block={$b.st})
227         ->
228     |   ^(PRIMITIVE_VAR_DECLARATION modifierList? simpleType variableDeclaratorList)
229         -> {emitH()}? class_var_decl(
230             modl={$modifierList.st},
231             type={$simpleType.st},
232             declList={$variableDeclaratorList.st})
233         ->
234     |   ^(OBJECT_VAR_DECLARATION modifierList? objectType variableDeclaratorList)
235         -> {emitH()}? class_var_decl(
236             modl={$modifierList.st},
237             type={$objectType.st},
238             declList={$variableDeclaratorList.st})
239         ->
240     |   ^(CONSTRUCTOR_DECL m=modifierList? g=genericTypeParameterList? IDENT f=formalParameterList b=block)
241         { 
242             // determine whether this is an entry method
243             if ($m.st != null) {
244                 entry = listContainsToken($m.start.getChildren(), ENTRY);
245             }
246         }
247         -> {emitCC()}? ctorDecl_cc(
248                 modl={$m.st}, 
249                 gtpl={$g.st}, 
250                 id={$IDENT.text}, 
251                 fpl={$f.st}, 
252                 block={$b.st})
253         -> {emitCI() && entry}? ctorDecl_ci(
254                 modl={$m.st}, 
255                 gtpl={$g.st}, 
256                 id={$IDENT.text}, 
257                 fpl={$f.st}, 
258                 block={$b.st})
259         -> {emitH()}? ctorDecl_h(
260                 modl={$m.st}, 
261                 gtpl={$g.st}, 
262                 id={$IDENT.text}, 
263                 fpl={$f.st}, 
264                 block={$b.st})
265         ->
266     ;
267     
268 interfaceScopeDeclaration
269     :   ^(FUNCTION_METHOD_DECL modifierList? genericTypeParameterList? type IDENT formalParameterList arrayDeclaratorList?)
270         -> template(t={$text}) "/*interfaceScopeDeclarations-not implemented */ <t>"
271     |   ^(PRIMITIVE_VAR_DECLARATION modifierList? simpleType variableDeclaratorList)
272         -> template(t={$text}) "/*interfaceScopeDeclarations-not implemented */ <t>"
273     |   ^(OBJECT_VAR_DECLARATION modifierList? objectType variableDeclaratorList)
274         -> template(t={$text}) "/*interfaceScopeDeclarations-not implemented */ <t>"
275     ;
276
277 variableDeclaratorList
278     :   ^(VAR_DECLARATOR_LIST (var_decls+=variableDeclarator)+)
279         -> var_decl_list(var_decls={$var_decls})
280     ;
281
282 variableDeclarator
283     :   ^(VAR_DECLARATOR id=variableDeclaratorId initializer=variableInitializer?)
284         -> var_decl(id={$id.st}, initializer={$initializer.st})
285     ;
286     
287 variableDeclaratorId
288     :   ^(IDENT adl=arrayDeclaratorList?)
289         -> var_decl_id(id={$IDENT.text}, arrayDeclList={$adl.st})
290     ;
291
292 variableInitializer
293     :   arrayInitializer
294         -> {$arrayInitializer.st}
295     |   expression
296         -> {$expression.st}
297     ;
298
299 arrayDeclaratorList
300     :   ^(ARRAY_DECLARATOR_LIST ARRAY_DECLARATOR*)  
301         -> template(t={$text}) "<t>"
302     ;
303     
304 arrayInitializer
305     :   ^(ARRAY_INITIALIZER variableInitializer*)
306         -> template(t={$text}) "/* arrayInitializer-not implemented */ <t>"
307     ;
308
309 genericTypeParameterList
310     :   ^(GENERIC_TYPE_PARAM_LIST genericTypeParameter+)
311         -> template(t={$text}) "/*GENERIC_TYPE_PARAM_LIST-not implemented*/ <t>"
312     ;
313
314 genericTypeParameter
315     :   ^(IDENT bound?)
316         -> template(t={$text}) "/*genericTypeParameter-not implemented*/ <t>"
317     ;
318         
319 bound
320     :   ^(EXTENDS_BOUND_LIST type+)
321         -> template(t={$text}) "/*EXTENDS_BOUND_LIST-not implemented*/ <t>"
322     ;
323
324 throwsClause
325     :   ^(THROWS_CLAUSE qualifiedIdentifier+)
326         -> template(t={$text}) "/* throwsClause-not implemented */ <t>"
327     ;
328
329 modifierList
330 returns [List<String> names]
331     :   ^(MODIFIER_LIST (m+=modifier)+)
332         {
333           $names = new ArrayList<String>();
334           for(Object o : $m) $names.add(o.toString());
335         }
336         -> mod_list(mods={$m})
337     ;
338
339 modifier
340 @init {
341 $st = %{$start.getText()};
342 }
343     :   PUBLIC
344     |   PROTECTED
345     |   PRIVATE
346     |   ENTRY
347     |   ABSTRACT
348     |   NATIVE
349     |   localModifier
350         -> {$localModifier.st}
351     ;
352
353 localModifierList
354     :   ^(LOCAL_MODIFIER_LIST (m+=localModifier)+)
355         -> local_mod_list(mods={$m})
356     ;
357
358 localModifier
359 @init {
360 $st = %{$start.getText()};
361 }
362     :   FINAL
363     |   STATIC
364     |   VOLATILE
365     ;
366
367     
368 type
369     :   simpleType
370         -> {$simpleType.st}
371     |   objectType 
372         -> {$objectType.st}
373     |   VOID
374         {
375             $st = %{$start.getText()};
376         }
377     ;
378
379 simpleType
380     :   ^(TYPE primitiveType arrayDeclaratorList?)
381         -> type(typeID={$primitiveType.st}, arrDeclList={$arrayDeclaratorList.st})
382     ;
383
384 objectType
385     :   ^(TYPE qualifiedTypeIdent arrayDeclaratorList?)
386         -> obj_type(typeID={$qualifiedTypeIdent.st}, arrDeclList={$arrayDeclaratorList.st})
387     ;
388
389 qualifiedTypeIdent
390     :   ^(QUALIFIED_TYPE_IDENT (t+=typeIdent)+) 
391         -> template(types={$t}) "<types; separator=\"::\">"
392     ;
393
394 typeIdent
395     :   ^(IDENT genericTypeArgumentList?)
396         -> typeIdent(typeID={$IDENT.text}, generics={$genericTypeArgumentList.st})
397     ;
398
399 primitiveType
400 @init {
401 $st = %{$start.getText()};
402 }
403     :   BOOLEAN
404         -> template() "bool"
405     |   CHAR
406     |   BYTE
407         -> template() "char"
408     |   SHORT
409     |   INT
410     |   LONG
411     |   FLOAT
412     |   DOUBLE
413     ;
414
415 genericTypeArgumentList
416     :   ^(GENERIC_TYPE_ARG_LIST (gta+=genericTypeArgument)+)
417         -> template(gtal={$gta}) "\<<gtal; separator=\", \">\>"
418     ;
419     
420 genericTypeArgument
421     :   type
422         -> {$type.st}
423     |   '?'
424         -> template(t={$text}) "/* genericTypeArgument: wildcard bound types not implemented */ <t>"
425     ;
426
427 formalParameterList
428     :   ^(FORMAL_PARAM_LIST (fpsd+=formalParameterStandardDecl)* fpvd=formalParameterVarargDecl?)
429         -> formal_param_list(sdecl={$fpsd}, vdecl={$fpvd.st})
430     ;
431     
432 formalParameterStandardDecl
433     :   ^(FORMAL_PARAM_STD_DECL lms=localModifierList? t=type vdid=variableDeclaratorId)
434         -> formal_param_decl(modList={$lms.st}, type={$t.st}, declID={$vdid.st})
435     ;
436     
437 formalParameterVarargDecl
438     :   ^(FORMAL_PARAM_VARARG_DECL localModifierList? type variableDeclaratorId)
439         -> template(t={$text}) "/*formal parameter varargs not implemented*/ <t>"
440     ;
441     
442 qualifiedIdentifier
443     :   IDENT
444         -> template(t={$text}) "<t>"
445     |   ^('.' qualifiedIdentifier IDENT)
446         -> template(t={$text}) "<t>"
447     ;
448     
449 block
450 @init { boolean emptyBlock = true; }
451     :   ^(BLOCK (b+=blockStatement)*)
452         { emptyBlock = ($b == null || $b.size() == 0); }
453         -> {emitCC() && emptyBlock}? template(bsl={$b}) "{ }"
454         -> {emitCC()}? block_cc(bsl={$b})
455         ->
456     ;
457     
458 blockStatement
459     :   localVariableDeclaration
460         -> {$localVariableDeclaration.st}
461     |   statement
462         -> {$statement.st}
463     ;
464
465
466 localVariableDeclaration
467     :   ^(PRIMITIVE_VAR_DECLARATION localModifierList? simpleType variableDeclaratorList)
468         -> local_var_decl(
469             modList={null},
470             type={$simpleType.st},
471             declList={$variableDeclaratorList.st})
472     |   ^(OBJECT_VAR_DECLARATION localModifierList? objectType variableDeclaratorList)
473         -> local_var_decl(
474             modList={null},
475             type={$objectType.st},
476             declList={$variableDeclaratorList.st})
477     ;
478
479
480 statement
481     :   nonBlockStatement
482         -> {$nonBlockStatement.st}
483     |   block
484         -> {$block.st}
485     ;
486
487 nonBlockStatement
488     :   ^(ASSERT cond=expression msg=expression?)
489         -> assert(cond={$cond.st}, msg={$msg.st})
490     |   ^(IF parenthesizedExpression then=block else_=block?)
491         -> if(cond={$parenthesizedExpression.st}, then={$then.st}, else_={$else_.st})
492     |   ^(FOR forInit? FOR_EXPR cond=expression? FOR_UPDATE (update+=expression)* b=block)
493         -> for(initializer={$forInit.st}, cond={$cond.st}, update={$update}, body={$block.st})
494     |   ^(FOR_EACH localModifierList? type IDENT expression block) 
495         -> template(t={$text}) "/* foreach not implemented */ <t>"
496     |   ^(WHILE pe=parenthesizedExpression b=block)
497         -> while(cond={$pe.st}, body={$b.st})
498     |   ^(DO b=block pe=parenthesizedExpression)
499         -> dowhile(cond={$pe.st}, block={$b.st})
500     |   ^(SWITCH pe=parenthesizedExpression (scls+=switchCaseLabel)*)
501         -> switch(expr={$pe.st}, labels={$scls})
502     |   ^(RETURN e=expression?)
503         -> return(val={$e.st})
504     |   ^(THROW expression)
505         -> template(t={$text}) "/* throw not implemented */ <t>"
506     |   ^(BREAK IDENT?)
507         -> template() "break;" // TODO: support labeling
508     |   ^(CONTINUE IDENT?)
509         -> template() "continue;" // TODO: support labeling
510     |   ^(LABELED_STATEMENT i=IDENT s=statement)
511         -> label(text={$i.text}, stmt={$s.st})
512     |   expression
513         -> template(expr={$expression.st}) "<expr>;"
514     |   ^('delete' qualifiedIdentifier)
515         -> template(t={$qualifiedIdentifier.st}) "delete <t>;"
516     |   ^('embed' STRING_LITERAL EMBED_BLOCK)
517         ->  embed_cc(str={$STRING_LITERAL.text}, blk={$EMBED_BLOCK.text})
518     |   ';' // Empty statement.
519         -> {%{$start.getText()}}
520     ;
521         
522 switchCaseLabel
523     :   ^(CASE expression (b+=blockStatement)*)
524         -> case(expr={$expression.st}, block={$b})
525     |   ^(DEFAULT (b+=blockStatement)*)
526         -> template(block={$b}) "default: <block>"
527     ;
528     
529 forInit
530     :   localVariableDeclaration
531         -> template(lvd={$localVariableDeclaration.st}) "<lvd>"
532     |   (ex+=expression)+
533         -> template(ex={$ex}) "<ex; separator=\", \">"
534     ;
535
536 // EXPRESSIONS
537
538 parenthesizedExpression
539     :   ^(PAREN_EXPR exp=expression)
540         -> template(expr={$exp.st}) "(<expr>)"
541     ;
542     
543 expression
544     :   ^(EXPR expr)
545         -> {$expr.st}
546     ;
547
548 expr
549     :   ^('=' e1=expr e2=expr)
550         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> = <e2>"
551     |   ^('+=' e1=expr e2=expr)
552         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> += <e2>"
553     |   ^('-=' e1=expr e2=expr)
554         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> -= <e2>"
555     |   ^('*=' e1=expr e2=expr)
556         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> *= <e2>"
557     |   ^('/=' e1=expr e2=expr)
558         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> /= <e2>"
559     |   ^('&=' e1=expr e2=expr)
560         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> &= <e2>"
561     |   ^('|=' e1=expr e2=expr)
562         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> |= <e2>"
563     |   ^('^=' e1=expr e2=expr)
564         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> ^= <e2>"
565     |   ^('%=' e1=expr e2=expr)
566         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> %= <e2>"
567     |   ^('>>>=' e1=expr e2=expr)
568         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \>\>\>= <e2>"
569     |   ^('>>=' e1=expr e2=expr)
570         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \>\>= <e2>"
571     |   ^('<<=' e1=expr e2=expr)
572         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \<\<= <e2>"
573     |   ^('?' e1=expr e2=expr e3=expr)
574         -> template(e1={$e1.st}, e2={$e2.st}, e3={$e3.st}) "<e1> ? <e2> : <e3>"
575     |   ^('||' e1=expr e2=expr)
576         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> || <e2>"
577     |   ^('&&' e1=expr e2=expr)
578         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> && <e2>"
579     |   ^('|' e1=expr e2=expr)
580         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> | <e2>"
581     |   ^('^' e1=expr e2=expr)
582         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> ^ <e2>"
583     |   ^('&' e1=expr e2=expr)
584         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> & <e2>"
585     |   ^('==' e1=expr e2=expr)
586         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> == <e2>"
587     |   ^('!=' e1=expr e2=expr)
588         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> != <e2>"
589     |   ^('instanceof' expr type)
590         -> template(t={$text}) "/* instanceof not implemented */ <t>"
591     |   ^('<=' e1=expr e2=expr)
592         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \<= <e2>"
593     |   ^('>=' e1=expr e2=expr)
594         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \>= <e2>"
595     |   ^('>>>' e1=expr e2=expr)
596         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \>\>\> <e2>"
597     |   ^('>>' e1=expr e2=expr)
598         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \>\> <e2>"
599     |   ^('>' e1=expr e2=expr)
600         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \> <e2>"
601     |   ^('<<' e1=expr e2=expr)
602         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \<\< <e2>"
603     |   ^('<' e1=expr e2=expr)
604         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \< <e2>"
605     |   ^('+' e1=expr e2=expr)
606         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> + <e2>"
607     |   ^('-' e1=expr e2=expr)
608         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> - <e2>"
609     |   ^('*' e1=expr e2=expr)
610         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> * <e2>"
611     |   ^('/' e1=expr e2=expr)
612         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> / <e2>"
613     |   ^('%' e1=expr e2=expr)
614         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> % <e2>"
615     |   ^(UNARY_PLUS e1=expr)
616         -> template(e1={$e1.st}) "+<e1>"
617     |   ^(UNARY_MINUS e1=expr)
618         -> template(e1={$e1.st}) "-<e1>"
619     |   ^(PRE_INC e1=expr)
620         -> template(e1={$e1.st}) "++<e1>"
621     |   ^(PRE_DEC e1=expr)
622         -> template(e1={$e1.st}) "--<e1>"
623     |   ^(POST_INC e1=expr)
624         -> template(e1={$e1.st}) "<e1>++"
625     |   ^(POST_DEC e1=expr)
626         -> template(e1={$e1.st}) "<e1>--"
627     |   ^('~' e1=expr)
628         -> template(e1={$e1.st}) "~<e1>"
629     |   ^('!' e1=expr)
630         -> template(e1={$e1.st}) "!<e1>"
631     |   ^(CAST_EXPR ty=type e1=expr)
632         -> template(ty={$ty.st}, e1={$e1.st}) "(<ty>)<e1>"
633     |   primaryExpression
634         -> {$primaryExpression.st}
635     ;
636
637 primaryExpression
638     :   ^('.' prim=primaryExpression
639             ( IDENT     -> template(id={$IDENT}, prim={$prim.st}) "<prim>-><id>"
640             | THIS    -> template(prim={$prim.st}) "<prim>->this"
641             | SUPER   -> template(prim={$prim.st}) "<prim>->super"
642             )
643         )
644     |   parenthesizedExpression
645         -> {$parenthesizedExpression.st}
646     |   IDENT
647         -> {%{$start.getText()}}
648     |   ^(METHOD_CALL pe=primaryExpression gtal=genericTypeArgumentList? args=arguments)
649         -> method_call(primary={$pe.st}, generic_types={$gtal.st}, args={$args.st})
650     |   explicitConstructorCall
651         -> {$explicitConstructorCall.st}
652     |   ^(ARRAY_ELEMENT_ACCESS pe=primaryExpression ex=expression)
653         -> template(pe={$pe.st}, ex={$ex.st}) "<pe>[<ex>]"
654     |   literal
655         -> {$literal.st}
656     |   newExpression
657         -> {$newExpression.st}
658     |   THIS
659         -> {%{$start.getText()}}
660     |   arrayTypeDeclarator
661         -> {$arrayTypeDeclarator.st}
662     |   SUPER
663         -> {%{$start.getText()}}
664     ;
665     
666 explicitConstructorCall
667     :   ^(THIS_CONSTRUCTOR_CALL genericTypeArgumentList? arguments)
668         -> template(t={$text}) "<t>"
669     |   ^(SUPER_CONSTRUCTOR_CALL primaryExpression? genericTypeArgumentList? arguments)
670         -> template(t={$text}) "<t>"
671     ;
672
673 arrayTypeDeclarator
674     :   ^(ARRAY_DECLARATOR (arrayTypeDeclarator | qualifiedIdentifier | primitiveType))
675         -> template(t={$text}) "<t>"
676     ;
677
678 newExpression
679     :   ^(  STATIC_ARRAY_CREATOR
680             (   primitiveType newArrayConstruction
681             |   genericTypeArgumentList? qualifiedTypeIdent newArrayConstruction
682             )
683         )
684         -> template(t={$text}) "<t>"
685     |   ^('new' qualifiedTypeIdent arguments)
686         -> template(q={$qualifiedTypeIdent.st}, a={$arguments.st}) "new <q>(<a>)"
687     ;
688
689 newArrayConstruction
690     :   arrayDeclaratorList arrayInitializer
691         -> array_construction_with_init(
692                 array_decls={$arrayDeclaratorList.st},
693                 initializer={$arrayInitializer.st})
694     |   (ex+=expression)+ adl=arrayDeclaratorList?
695         -> array_construction(exprs={$ex}, array_decls={$adl.st})
696     ;
697
698 arguments
699     :   ^(ARGUMENT_LIST (ex+=expression)*)
700         -> arguments(exprs={$ex})
701     ;
702
703 literal
704 @init {
705 $st = %{$start.getText()};
706 }
707     :   HEX_LITERAL
708     |   OCTAL_LITERAL
709     |   DECIMAL_LITERAL
710     |   FLOATING_POINT_LITERAL
711     |   CHARACTER_LITERAL
712     |   STRING_LITERAL
713     |   TRUE
714     |   FALSE
715     |   NULL
716     ;
717