Charj: made SDAG grammar reflect actual SDAG implementation
[charm.git] / src / langs / charj / src / charj / translator / CharjEmitter.g
1 /**
2  * ANTLR (v3) Tree Parser for the Charj Language
3  */
4
5 tree grammar CharjEmitter;
6
7 options {
8     backtrack = true; 
9     memoize = true;
10     tokenVocab = Charj;
11     ASTLabelType = CharjAST;
12     output = template;
13 }
14
15
16 @header {
17 package charj.translator;
18 }
19
20
21 @members {
22     SymbolTable symtab = null;
23
24     PackageScope currentPackage = null;
25     ClassSymbol currentClass = null;
26     MethodSymbol currentMethod = null;
27     LocalScope currentLocalScope = null;
28
29     Translator translator_;
30     OutputMode mode_;
31
32     private boolean emitCC() { return mode_ == OutputMode.cc; }
33     private boolean emitCI() { return mode_ == OutputMode.ci; }
34     private boolean emitH() { return mode_ == OutputMode.h; }
35     private boolean debug() { return translator_.debug(); }
36     private String basename() { return translator_.basename(); }
37
38     /**
39      *  Override ANTLR's token mismatch behavior so we throw exceptions early.
40      */
41     protected void mismatch(IntStream input, int ttype, BitSet follow)
42         throws RecognitionException {
43         throw new MismatchedTokenException(ttype, input);
44     }
45
46     /**
47      *  Override ANTLR's set mismatch behavior so we throw exceptions early.
48      */
49     public Object recoverFromMismatchedSet(IntStream input, RecognitionException e, BitSet follow)
50         throws RecognitionException {
51         throw e;
52     }
53
54     /**
55      *  Test a list of CharjAST nodes to see if any of them has the given token
56      *  type.
57      */
58     public boolean listContainsToken(List<CharjAST> list, int tokenType) {
59         if (list == null) return false;
60         for (CharjAST node : list) {
61             if (node.token.getType() == tokenType) {
62                 return true;
63             }
64         }
65         return false;
66     }
67 }
68
69
70 // Replace default ANTLR generated catch clauses with this action, allowing early failure.
71 @rulecatch {
72     catch (RecognitionException re) {
73         reportError(re);
74         throw re;
75     }
76 }
77
78
79 // Starting point for parsing a Charj file.
80 charjSource[SymbolTable symtab, OutputMode m]
81 @init {
82     this.symtab = symtab;
83     this.translator_ = symtab.translator;
84     this.mode_ = m;
85 }
86     :   ^(CHARJ_SOURCE (p=packageDeclaration)? 
87         (i+=importDeclaration)*
88         (r+=readonlyDeclaration)*
89         (t+=typeDeclaration)*)
90         -> {emitCC()}? charjSource_cc(basename={basename()}, pd={$p.names}, imports={$i}, types={$t}, ros={$r}, debug={debug()})
91         -> {emitCI()}? charjSource_ci(basename={basename()}, pd={$p.names}, imports={$i}, types={$t}, ros={$r}, debug={debug()})
92         -> {emitH()}? charjSource_h(basename={basename()}, pd={$p.names}, imports={$i}, types={$t}, ros={$r}, debug={debug()})
93         ->
94     ;
95
96 topLevelDeclaration
97     :   importDeclaration -> {$importDeclaration.st;}
98     |   typeDeclaration -> {$typeDeclaration.st;}
99     ;
100
101 packageDeclaration returns [List names]
102     :   ^('package' (ids+=IDENT)+)
103         {
104             $names = $ids;
105         }
106         ->
107     ;
108
109 readonlyDeclaration
110     :   ^(READONLY lvd=localVariableDeclaration)
111         -> {emitCI()}? template(bn={basename()}, v={$lvd.st}) "readonly <v>"
112         -> {emitH()}? template(v={$lvd.st}) "extern <v>"
113         -> {emitCC()}? {$lvd.st;}
114         ->
115     ;
116     
117 importDeclaration
118 @init {
119     String importID = null;
120 }
121     :   ^('import' qualifiedIdentifier ds='.*'?)
122         {
123             importID = $qualifiedIdentifier.text;
124             if ($ds != null) {
125             }
126         }
127         {$ds == null}? // TODO: add support for importing x.*
128         -> {(emitCC() || emitH())}? importDeclaration_cc_h(
129             inc_id={importID.replace(".","/")},
130             use_id={importID.replace(".","::")})
131         ->
132     ;
133     
134 typeDeclaration
135 @init {
136     boolean needsMigration = false;
137     List<String> inits = new ArrayList<String>();
138     List<String> pupInits = new ArrayList<String>();
139 }
140     :   ^(TYPE CLASS IDENT (^('extends' su=type))? (^('implements' type+))?
141         {
142             currentClass = (ClassSymbol)$IDENT.def;
143
144             inits = currentClass.generateInits(currentClass.initializers);
145         }
146         (csds+=classScopeDeclaration)*)
147         -> {emitCC()}? classDeclaration_cc(
148                 sym={currentClass},
149                 ident={$IDENT.text}, 
150                 ext={$su.st}, 
151                 csds={$csds},
152                 inits={inits})
153         -> {emitH()}?  classDeclaration_h(
154                 sym={currentClass},
155                 ident={$IDENT.text}, 
156                 ext={$su.st}, 
157                 csds={$csds})
158         ->
159     |   ^('template' (i0+=IDENT*) ^('class' i1=IDENT (^('extends' su=type))? (^('implements' type+))? (csds+=classScopeDeclaration)*))
160         -> {emitH()}? templateDeclaration_h(
161             tident={$i0},
162             ident={$i1.text},
163             ext={$su.st},
164             csds={$csds})
165         -> 
166     |   ^(INTERFACE IDENT (^('extends' type+))? interfaceScopeDeclaration*)
167         -> template(t={$text}) "/*INTERFACE-not implemented*/ <t>"
168     |   ^(ENUM IDENT (^('implements' type+))? classScopeDeclaration*)
169         -> template(t={$text}) "/*ENUM-not implemented*/ <t>"
170     |   ^(TYPE chareType IDENT (^('extends' type))? (^('implements' type+))?
171         {
172             currentClass = (ClassSymbol)$IDENT.def;
173             needsMigration = currentClass.isChareArray && !currentClass.hasMigrationCtor;
174
175             inits = currentClass.generateInits(currentClass.initializers);
176             pupInits = currentClass.generateInits(currentClass.pupInitializers);
177         }
178         (csds+=classScopeDeclaration)*)
179         -> {emitCC()}? chareDeclaration_cc(
180                 sym={currentClass},
181                 ident={$IDENT.text}, 
182                 ext={$su.st}, 
183                 csds={$csds},
184                 pupInits={pupInits},
185                 pupers={currentClass.generatePUPers()},
186                 needsMigration={needsMigration},
187                 inits={inits})
188         -> {emitCI()}? chareDeclaration_ci(
189                 basename={basename()},
190                 sym={currentClass},
191                 chareType={$chareType.st},
192                 arrayDim={null},
193                 ident={$IDENT.text}, 
194                 ext={$su.st}, 
195                 csds={$csds})
196         -> {emitH()}? chareDeclaration_h(
197                 sym={currentClass},
198                 ident={$IDENT.text}, 
199                 ext={$su.st}, 
200                 csds={$csds},
201                 needsPupInit={pupInits.size() > 0},
202                 needsMigration={needsMigration})
203         ->
204     ;
205
206 chareType
207 @init {
208 $st = %{$start.getText()};
209 }
210     :   CHARE
211     |   GROUP
212     |   NODEGROUP
213     |   MAINCHARE
214     |   ^(CHARE_ARRAY ARRAY_DIMENSION)
215         -> template(t={$ARRAY_DIMENSION.text}) "array [<t>]"
216     ;
217
218 enumConstant
219     :   ^(IDENT arguments?)
220         -> template(t={$text}) "/*enumConstant-not implemented*/ <t>"
221     ;
222
223 classScopeDeclaration
224 @init
225 {
226     boolean entry = false;
227     boolean migrationCtor = false;
228     boolean sdagMethod = false;
229 }
230     :   ^(FUNCTION_METHOD_DECL m=modifierList? g=genericTypeParameterList? 
231             ty=type IDENT f=formalParameterList
232             { currentMethod = (MethodSymbol)$IDENT.def; }
233             b=block?)
234         -> {emitCC()}? funcMethodDecl_cc(
235                 classSym={currentClass},
236                 methodSym={currentMethod},
237                 modl={$m.st}, 
238                 gtpl={$g.st}, 
239                 ty={$ty.st},
240                 id={$IDENT.text}, 
241                 fpl={$f.st}, 
242                 block={$b.st})
243         -> {emitH()}? funcMethodDecl_h(
244                 modl={$m.st}, 
245                 gtpl={$g.st}, 
246                 ty={$ty.st},
247                 id={$IDENT.text}, 
248                 fpl={$f.st}, 
249                 block={$b.st})
250         -> {emitCI()}? // do nothing, since it's not an entry method
251         ->
252     |   ^(ENTRY_FUNCTION_DECL m=modifierList? g=genericTypeParameterList? 
253             ty=type IDENT f=formalParameterList a=domainExpression[null]? 
254             {
255                 currentMethod = (MethodSymbol)$IDENT.def;
256                 sdagMethod = currentMethod.hasSDAG;
257             }
258             b=block?) 
259         -> {emitCC() && !sdagMethod}? funcMethodDecl_cc(
260                 classSym={currentClass},
261                 methodSym={currentMethod},
262                 modl={$m.st}, 
263                 gtpl={$g.st}, 
264                 ty={$ty.st},
265                 id={$IDENT.text}, 
266                 fpl={$f.st}, 
267                 adl={$a.st},
268                 block={$b.st})
269         -> {emitH() && !sdagMethod}? funcMethodDecl_h(
270                 modl={$m.st}, 
271                 gtpl={$g.st}, 
272                 ty={$ty.st},
273                 id={$IDENT.text}, 
274                 fpl={$f.st}, 
275                 adl={$a.st},
276                 block={$b.st})
277         -> {emitCI() && sdagMethod}? funcMethodDecl_sdag_ci(
278                 classSym={currentClass},
279                 methodSym={currentMethod},
280                 modl={$m.st}, 
281                 gtpl={$g.st}, 
282                 ty={$ty.st},
283                 id={$IDENT.text}, 
284                 fpl={$f.st}, 
285                 adl={$a.st},
286                 block={$b.st})
287         -> {emitCI() && !sdagMethod}? funcMethodDecl_ci(
288                 modl={$m.st}, 
289                 gtpl={$g.st}, 
290                 ty={$ty.st},
291                 id={$IDENT.text}, 
292                 fpl={$f.st}, 
293                 block={$b.st})
294         ->
295     |   ^(PRIMITIVE_VAR_DECLARATION modifierList? simpleType variableDeclaratorList[null])
296         -> {emitH()}? class_var_decl(
297             modl={$modifierList.st},
298             type={$simpleType.st},
299             declList={$variableDeclaratorList.st})
300         ->
301     |   ^(OBJECT_VAR_DECLARATION modifierList? objectType variableDeclaratorList[$objectType.st])
302         -> {emitH()}? class_var_decl(
303             modl={$modifierList.st},
304             type={$objectType.st},
305             declList={$variableDeclaratorList.st})
306         ->
307     |   ^(CONSTRUCTOR_DECL m=modifierList? g=genericTypeParameterList? IDENT f=formalParameterList
308             {
309                 currentMethod = (MethodSymbol)$IDENT.def;
310             }
311             b=block)
312         -> {emitCC()}? ctorDecl_cc(
313                 modl={$m.st},
314                 gtpl={$g.st}, 
315                 id={$IDENT.text}, 
316                 fpl={$f.st}, 
317                 block={$b.st})
318         -> {emitCI()}? // do nothing, it's not an entry constructor
319         -> {emitH()}? ctorDecl_h(
320                 modl={$m.st},
321                 gtpl={$g.st}, 
322                 id={$IDENT.text}, 
323                 fpl={$f.st}, 
324                 block={$b.st})
325         ->
326     |   ^(ENTRY_CONSTRUCTOR_DECL m=modifierList? g=genericTypeParameterList? IDENT f=formalParameterList
327             {
328                 currentMethod = (MethodSymbol)$IDENT.def;
329                 migrationCtor = currentClass.migrationCtor == $ENTRY_CONSTRUCTOR_DECL;
330             }
331             b=block)
332
333         -> {emitCC()}? ctorDecl_cc(
334                 modl={$m.st},
335                 gtpl={$g.st}, 
336                 id={$IDENT.text}, 
337                 fpl={$f.st}, 
338                 block={$b.st})
339         -> {emitCI() && !migrationCtor}? ctorDecl_ci(
340                 modl={$m.st},
341                 gtpl={$g.st}, 
342                 id={$IDENT.text}, 
343                 fpl={$f.st}, 
344                 block={$b.st})
345         -> {emitH()}? ctorDecl_h(
346                 modl={$m.st},
347                 gtpl={$g.st}, 
348                 id={$IDENT.text}, 
349                 fpl={$f.st}, 
350                 block={$b.st})
351         ->
352     ;
353     
354 interfaceScopeDeclaration
355     :   ^(FUNCTION_METHOD_DECL modifierList? genericTypeParameterList? type IDENT formalParameterList)
356         -> template(t={$text}) "/*interfaceScopeDeclarations-not implemented */ <t>"
357     |   ^(PRIMITIVE_VAR_DECLARATION modifierList? simpleType variableDeclaratorList[$simpleType.st])
358         -> template(t={$text}) "/*interfaceScopeDeclarations-not implemented */ <t>"
359     |   ^(OBJECT_VAR_DECLARATION modifierList? objectType variableDeclaratorList[$objectType.st])
360         -> template(t={$text}) "/*interfaceScopeDeclarations-not implemented */ <t>"
361     ;
362
363 variableDeclaratorList[StringTemplate obtype]
364     :   ^(VAR_DECLARATOR_LIST (var_decls+=variableDeclarator[obtype])+ )
365         -> var_decl_list(var_decls={$var_decls})
366     ;
367
368 variableDeclarator[StringTemplate obtype]
369     :   ^(VAR_DECLARATOR id=variableDeclaratorId initializer=variableInitializer[obtype]?)
370         -> {emitCC()}? var_decl_cc(id={$id.st}, initializer={$initializer.st})
371         -> {emitH()}?  var_decl_h(id={$id.st}, initializer={$initializer.st})
372         -> {emitCI()}? var_decl_ci(id={$id.st}, initializer={$initializer.st})
373         ->
374     ; 
375     
376 variableDeclaratorId
377     :   ^(IDENT de=domainExpression[null]?)
378         -> var_decl_id(id={$IDENT.text}, domainExp={$de.st})
379     ;
380
381 variableInitializer[StringTemplate obtype]
382     :   arrayInitializer
383         -> {$arrayInitializer.st}
384     |   newExpression[obtype]
385         -> {$newExpression.st}
386     |   expression
387         -> {$expression.st}
388     ;
389
390 rangeItem
391     :   dl=DECIMAL_LITERAL
392         -> template(t={$dl.text}) "<t>"
393     |   IDENT
394         -> template(t={$IDENT.text}) "<t>"
395     ;
396
397 rangeExpression
398     :   ^(RANGE_EXPRESSION (ri+=rangeItem)*)
399         -> template(t={$ri}) "Range(<t; separator=\",\">)"
400     ;
401
402 rangeList returns [int len]
403     :   (r+=rangeExpression)*
404         { $len = $r.size(); }
405         -> template(t={$r}) "<t; separator=\", \">"
406     ;
407
408 domainExpression[List<StringTemplate> otherParams]
409     :   ^(DOMAIN_EXPRESSION rl=rangeList)
410         -> range_constructor(range={$rl.st}, others={$otherParams}, len={$rl.len})
411     ;
412
413 domainExpressionAccess
414     :   ^(DOMAIN_EXPRESSION rl=rangeListAccess)
415         -> template(t={$rangeListAccess.st}) "<t>"
416     ;
417
418 rangeListAccess
419     :   (r+=rangeExpressionAccess)*
420         -> template(t={$r}) "<t; separator=\", \">"
421     ;
422
423 rangeExpressionAccess
424     :   ^(RANGE_EXPRESSION (ri+=rangeItem)*)
425         -> template(t={$ri}) "<t; separator=\",\">"
426     ;
427
428 arrayInitializer
429     :   ^(ARRAY_INITIALIZER variableInitializer[null]*)
430         -> template(t={$text}) "/* arrayInitializer-not implemented */ <t>"
431     ;
432
433 genericTypeParameterList
434     :   ^(GENERIC_TYPE_PARAM_LIST genericTypeParameter+)
435         -> template(t={$text}) "/*GENERIC_TYPE_PARAM_LIST-not implemented*/ <t>"
436     ;
437
438 genericTypeParameter
439     :   ^(IDENT bound?)
440         -> template(t={$text}) "/*genericTypeParameter-not implemented*/ <t>"
441     ;
442         
443 bound
444     :   ^(EXTENDS_BOUND_LIST type+)
445         -> template(t={$text}) "/*EXTENDS_BOUND_LIST-not implemented*/ <t>"
446     ;
447
448 throwsClause
449     :   ^(THROWS_CLAUSE qualifiedIdentifier+)
450         -> template(t={$text}) "/* throwsClause-not implemented */ <t>"
451     ;
452
453 modifierList
454     :   ^(MODIFIER_LIST accessModifierList localModifierList charjModifierList otherModifierList)
455         ->  {emitCC()}? mod_list_cc(accmods = {$accessModifierList.names}, localmods = {$localModifierList.names}, charjmods = {$charjModifierList.names}, othermods = {$otherModifierList.names})
456         ->  {emitH()}? mod_list_h(accmods = {$accessModifierList.names}, localmods = {$localModifierList.names}, charjmods = {$charjModifierList.names}, othermods = {$otherModifierList.names})
457         ->  {emitCI()}? mod_list_ci(accmods = {$accessModifierList.names}, localmods = {$localModifierList.names}, charjmods = {$charjModifierList.names}, othermods = {$otherModifierList.names})
458         ->
459     ;
460
461 modifier
462     :   accessModifier
463     |   localModifier
464     |   charjModifier
465     |   otherModifier
466     ;
467
468 accessModifierList
469 returns [List names]
470     :   ^(ACCESS_MODIFIER_LIST (m+=accessModifier)*)
471         {
472             $names = $m;
473         }
474     ;
475 localModifierList
476 returns [List names]
477     :   ^(LOCAL_MODIFIER_LIST (m+=localModifier)*)
478         {
479             $names = $m;
480         }
481         ->  local_mod_list(mods = {$names})
482     ;
483
484 charjModifierList
485 returns [List names]
486     :   ^(CHARJ_MODIFIER_LIST (m+=charjModifier)*)
487         {
488             $names = $m;
489         }
490     ;
491
492 otherModifierList
493 returns [List names]
494     :   ^(OTHER_MODIFIER_LIST (m+=otherModifier)*)
495         {
496             $names = $m;
497         }
498     ;
499     
500 localModifier
501 @init
502 {
503     $st = %{$start.getText()};
504 }
505     :   FINAL
506     |   STATIC
507     |   VOLATILE
508     ;
509
510 accessModifier
511 @init
512 {
513     $st = %{$start.getText()};
514 }
515     :   PUBLIC
516     |   PROTECTED
517     |   PRIVATE
518         {
519             $st = %{"private"};
520         }
521     ;
522
523 charjModifier
524     :   ENTRY -> {%{$ENTRY.text}}
525     |   SDAGENTRY -> template() "entry"
526     |   TRACED
527     ;
528
529 otherModifier
530 @init
531 {
532     $st = %{$start.getText()};
533 }
534     :   ABSTRACT
535     |   NATIVE
536     ;
537     
538 type
539     :   simpleType
540         -> {$simpleType.st}
541     |   objectType 
542         -> {$objectType.st}
543     |   VOID
544         {
545             $st = %{"void"};
546         }
547     ;
548
549 simpleType
550     :   ^(SIMPLE_TYPE primitiveType domainExpression[null]?)
551         -> simple_type(typeID={$primitiveType.st}, arrDeclList={$domainExpression.st})
552     ;
553
554 objectType //[boolean forNewExpression]
555     : proxyType -> {$proxyType.st;}
556     | nonProxyType -> {$nonProxyType.st}
557     ;
558
559 nonProxyType
560     :   ^(OBJECT_TYPE qualifiedTypeIdent domainExpression[null]?)
561         -> obj_type(typeID={$qualifiedTypeIdent.st}, arrDeclList={$domainExpression.st})
562     |   ^(POINTER_TYPE qualifiedTypeIdent domainExpression[null]?)
563         -> pointer_type(typeID={$qualifiedTypeIdent.st}, arrDeclList={$domainExpression.st})
564     |   ^(REFERENCE_TYPE qualifiedTypeIdent domainExpression[null]?)
565         -> reference_type(typeID={$qualifiedTypeIdent.st}, arrDeclList={$domainExpression.st})
566     ;
567
568 proxyType
569     :   ^(PROXY_TYPE qualifiedTypeIdent domainExpression[null]?)
570         -> proxy_type(typeID={$qualifiedTypeIdent.st}, arrDeclList={$domainExpression.st})
571     ;
572
573 qualifiedTypeIdent returns [ClassSymbol type]
574     :   ^(QUALIFIED_TYPE_IDENT (t+=typeIdent)+)
575         {$type = (ClassSymbol)$QUALIFIED_TYPE_IDENT.def;}
576         -> template(types={$t}) "<types; separator=\"::\">"
577     ;
578
579 typeIdent
580     :   ^(IDENT templateInstantiation?)
581         -> typeIdent(typeID={$IDENT.text}, generics={$templateInstantiation.st})
582     ;
583
584 primitiveType
585 @init {
586 $st = %{$start.getText()};
587 }
588     :   BOOLEAN
589         -> template() "bool"
590     |   CHAR
591     |   BYTE
592         -> template() "char"
593     |   SHORT
594     |   INT
595     |   LONG
596     |   FLOAT
597     |   DOUBLE
598     ;
599
600 templateArg
601     :   genericTypeArgument
602         -> {$genericTypeArgument.st}
603     |   literal
604         -> {$literal.st}
605     ;
606
607 templateArgList
608     :   params+=templateArg+
609         -> template(params={$params}) "<params; separator=\", \">"
610     ;
611
612 templateInstantiation
613     :   ^(TEMPLATE_INST templateArgList)
614         -> template(args={$templateArgList.st}) "\<<args>\>"
615     |   ^(TEMPLATE_INST ts=templateInstantiation)
616         -> template(inst={$ts.st}) "\<<inst>\>"
617     ;
618
619 genericTypeArgumentList
620     :   ^(GENERIC_TYPE_ARG_LIST (gta+=genericTypeArgument)+)
621         -> template(gtal={$gta}) "\<<gtal; separator=\", \">\>"
622     ;
623
624 genericTypeArgument
625     :   type
626         -> {$type.st}
627     |   '?'
628         -> template(t={$text}) "/* genericTypeArgument: wildcard bound types not implemented */ <t>"
629     ;
630
631 formalParameterList
632     :   ^(FORMAL_PARAM_LIST (fpsd+=formalParameterStandardDecl)* fpvd=formalParameterVarargDecl?)
633         -> formal_param_list(sdecl={$fpsd}, vdecl={$fpvd.st})
634     ;
635     
636 formalParameterStandardDecl
637     :   ^(FORMAL_PARAM_STD_DECL lms=localModifierList? t=type vdid=variableDeclaratorId)
638         -> formal_param_decl(modList={$lms.st}, type={$t.st}, declID={$vdid.st})
639     ;
640     
641 formalParameterVarargDecl
642     :   ^(FORMAL_PARAM_VARARG_DECL localModifierList? type variableDeclaratorId)
643         -> template(t={$text}) "/*formal parameter varargs not implemented*/ <t>"
644     ;
645     
646 qualifiedIdentifier
647     :   IDENT
648         -> template(t={$text}) "<t>"
649     |   ^(DOT qualifiedIdentifier IDENT)
650         -> template(t={$text}) "<t>"
651     ;
652     
653 block
654 @init { boolean emptyBlock = true; }
655     :   ^(BLOCK (b+=blockStatement)*)
656         { emptyBlock = ($b == null || $b.size() == 0); }
657         -> {((emitCC() && (currentMethod == null || !currentMethod.hasSDAG)) ||
658             (emitCI() && (currentMethod != null && currentMethod.hasSDAG))) && emptyBlock}? template(bsl={$b}) "{ }"
659         -> {emitCC() && (currentMethod == null || !currentMethod.hasSDAG)}? block_cc(bsl={$b})
660         -> {emitCI() && (currentMethod != null && currentMethod.hasSDAG)}? block_sdag_ci(bsl={$b})
661         ->
662     ;
663     
664 blockStatement
665     :   localVariableDeclaration
666         -> {$localVariableDeclaration.st}
667     |   statement
668         -> {$statement.st}
669     ;
670
671
672 localVariableDeclaration
673     :   ^(PRIMITIVE_VAR_DECLARATION localModifierList? simpleType vdl=variableDeclaratorList[null])
674         -> local_var_decl(
675             modList={$localModifierList.st},
676             type={$simpleType.st},
677             declList={$vdl.st})
678     |   ^(OBJECT_VAR_DECLARATION localModifierList? objectType vdl=variableDeclaratorList[$objectType.st])
679         -> local_var_decl(
680             modList={$localModifierList.st},
681             type={$objectType.st},
682             declList={$vdl.st})
683     ;
684
685
686 statement
687     :   nonBlockStatement
688         -> {$nonBlockStatement.st}
689     |   sdagStatement
690         -> {$sdagStatement.st}
691     |   block
692         -> {$block.st}
693     ;
694
695 sdagStatement
696     :   ^(OVERLAP block)
697         -> template(b={$block.st}) "} overlap <b> atomic {"
698     |   ^(WHEN (wa+=whenArgument)* block)
699         -> template(w={wa}, b={$block.st}) "} when <w> <b> atomic {"
700     ;
701
702 whenArgument
703     :   IDENT expression? formalParameterList
704         -> template(i={$IDENT}, e={$expression.st}, f={$formalParameterList.st}) "<i> <if(e)>[<e>] <endif><f>"
705     ;
706
707 nonBlockStatement
708     :   ^(ASSERT cond=expression msg=expression?)
709         -> assert(cond={$cond.st}, msg={$msg.st})
710     |   ^(IF parenthesizedExpression then=block else_=block?)
711         -> if(cond={$parenthesizedExpression.st}, then={$then.st}, else_={$else_.st})
712     |   ^(FOR forInit? FOR_EXPR cond=expression? FOR_UPDATE (update+=expression)* b=block)
713         -> for(initializer={$forInit.st}, cond={$cond.st}, update={$update}, body={$block.st})
714     |   ^(FOR_EACH localModifierList? type IDENT expression block) 
715         -> template(t={$text}) "/* foreach not implemented */ <t>"
716     |   ^(WHILE pe=parenthesizedExpression b=block)
717         -> while(cond={$pe.st}, body={$b.st})
718     |   ^(DO b=block pe=parenthesizedExpression)
719         -> dowhile(cond={$pe.st}, block={$b.st})
720     |   ^(SWITCH pe=parenthesizedExpression (scls+=switchCaseLabel)*)
721         -> switch(expr={$pe.st}, labels={$scls})
722     |   ^(RETURN e=expression?)
723         -> return(val={$e.st})
724     |   ^(THROW expression)
725         -> template(t={$text}) "/* throw not implemented */ <t>"
726     |   ^(BREAK IDENT?)
727         -> template() "break;" // TODO: support labeling
728     |   ^(CONTINUE IDENT?)
729         -> template() "continue;" // TODO: support labeling
730     |   ^(LABELED_STATEMENT i=IDENT s=statement)
731         -> label(text={$i.text}, stmt={$s.st})
732     |   expression
733         -> template(expr={$expression.st}) "<expr>;"
734     |   ^('delete' expression)
735         -> template(t={$expression.st}) "delete <t>;"
736     |   ^('embed' STRING_LITERAL EMBED_BLOCK)
737         ->  embed_cc(str={$STRING_LITERAL.text}, blk={$EMBED_BLOCK.text})
738     |   ';' // Empty statement.
739         -> {%{$start.getText()}}
740     |   ^(PRINT (exprs += expression)*)
741         ->  print(exprs = {$exprs})
742     |   ^(PRINTLN (exprs += expression)*)
743         ->  println(exprs = {$exprs})
744     |   ^(EXIT expression?)
745         ->  exit(expr = {$expression.st})
746     |   EXITALL
747         ->  exitall()
748     ;
749         
750 switchCaseLabel
751     :   ^(CASE expression (b+=blockStatement)*)
752         -> case(expr={$expression.st}, block={$b})
753     |   ^(DEFAULT (b+=blockStatement)*)
754         -> template(block={$b}) "default: <block>"
755     ;
756     
757 forInit
758     :   localVariableDeclaration
759         -> template(lvd={$localVariableDeclaration.st}) "<lvd>"
760     |   (ex+=expression)+
761         -> template(ex={$ex}) "<ex; separator=\", \">"
762     ;
763
764 // EXPRESSIONS
765
766 parenthesizedExpression
767     :   ^(PAREN_EXPR exp=expression)
768         -> template(expr={$exp.st}) "(<expr>)"
769     ;
770
771 expressionArrayAccess
772     :   ^(EXPR expr)
773         -> {$expr.st}
774     |    domainExpressionAccess
775         -> {$domainExpressionAccess.st}
776     ;
777     
778 expression
779     :   ^(EXPR expr)
780         -> {$expr.st}
781     |   domainExpression[null]
782         -> {$domainExpression.st}
783     ;
784
785 expr
786     :   ^(ASSIGNMENT e1=expr e2=expr)
787         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> = <e2>"
788     |   ^('+=' e1=expr e2=expr)
789         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> += <e2>"
790     |   ^('-=' e1=expr e2=expr)
791         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> -= <e2>"
792     |   ^('*=' e1=expr e2=expr)
793         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> *= <e2>"
794     |   ^('/=' e1=expr e2=expr)
795         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> /= <e2>"
796     |   ^('&=' e1=expr e2=expr)
797         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> &= <e2>"
798     |   ^('|=' e1=expr e2=expr)
799         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> |= <e2>"
800     |   ^('^=' e1=expr e2=expr)
801         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> ^= <e2>"
802     |   ^('%=' e1=expr e2=expr)
803         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> %= <e2>"
804     |   ^('>>>=' e1=expr e2=expr)
805         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \>\>\>= <e2>"
806     |   ^('>>=' e1=expr e2=expr)
807         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \>\>= <e2>"
808     |   ^('<<=' e1=expr e2=expr)
809         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \<\<= <e2>"
810     |   ^('?' e1=expr e2=expr e3=expr)
811         -> template(e1={$e1.st}, e2={$e2.st}, e3={$e3.st}) "<e1> ? <e2> : <e3>"
812     |   ^('||' e1=expr e2=expr)
813         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> || <e2>"
814     |   ^('&&' e1=expr e2=expr)
815         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> && <e2>"
816     |   ^(BITWISE_OR e1=expr e2=expr)
817         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> | <e2>"
818     |   ^('^' e1=expr e2=expr)
819         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> ^ <e2>"
820     |   ^('&' e1=expr e2=expr)
821         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> & <e2>"
822     |   ^(EQUALS e1=expr e2=expr)
823         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> == <e2>"
824     |   ^('!=' e1=expr e2=expr)
825         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> != <e2>"
826     |   ^('instanceof' expr type)
827         -> template(t={$text}) "/* instanceof not implemented */ <t>"
828     |   ^('<=' e1=expr e2=expr)
829         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \<= <e2>"
830     |   ^('>=' e1=expr e2=expr)
831         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \>= <e2>"
832     |   ^('>>>' e1=expr e2=expr)
833         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \>\>\> <e2>"
834     |   ^('>>' e1=expr e2=expr)
835         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \>\> <e2>"
836     |   ^('>' e1=expr e2=expr)
837         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \> <e2>"
838     |   ^('<<' e1=expr e2=expr)
839         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \<\< <e2>"
840     |   ^('<' e1=expr e2=expr)
841         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \< <e2>"
842     |   ^('+' e1=expr e2=expr)
843         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> + <e2>"
844     |   ^('-' e1=expr e2=expr)
845         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> - <e2>"
846     |   ^('*' e1=expr e2=expr)
847         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> * <e2>"
848     |   ^('/' e1=expr e2=expr)
849         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> / <e2>"
850     |   ^('%' e1=expr e2=expr)
851         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> % <e2>"
852     |   ^(UNARY_PLUS e1=expr)
853         -> template(e1={$e1.st}) "+<e1>"
854     |   ^(UNARY_MINUS e1=expr)
855         -> template(e1={$e1.st}) "-<e1>"
856     |   ^(PRE_INC e1=expr)
857         -> template(e1={$e1.st}) "++<e1>"
858     |   ^(PRE_DEC e1=expr)
859         -> template(e1={$e1.st}) "--<e1>"
860     |   ^(POST_INC e1=expr)
861         -> template(e1={$e1.st}) "<e1>++"
862     |   ^(POST_DEC e1=expr)
863         -> template(e1={$e1.st}) "<e1>--"
864     |   ^(TILDE e1=expr)
865         -> template(e1={$e1.st}) "~<e1>"
866     |   ^(NOT e1=expr)
867         -> template(e1={$e1.st}) "!<e1>"
868     |   ^(CAST_EXPR ty=type e1=expr)
869         -> template(ty={$ty.st}, e1={$e1.st}) "(<ty>)<e1>"
870     |   primaryExpression
871         -> {$primaryExpression.st}
872     |   ^(POINTER_DEREFERENCE e1 = expr)
873         ->  template(e = {$e1.st}) "*(<e>)"
874     ;
875
876 primaryExpression
877 @init { int dims = 1; }
878     :   ^(DOT prim=primaryExpression
879             ( IDENT   -> template(id={$IDENT.text}, prim={$prim.st}) "<prim>.<id>"
880             | THIS    -> template(prim={$prim.st}) "<prim>.this"
881             | SUPER   -> template(prim={$prim.st}) "<prim>.super"
882             )
883         )
884     |   ^(ARROW prim=primaryExpression
885             ( IDENT   -> template(id={$IDENT.text}, prim={$prim.st}) "<prim>-><id>"
886             | THIS    -> template(prim={$prim.st}) "<prim>->this"
887             | SUPER   -> template(prim={$prim.st}) "<prim>->super"
888             )
889         )
890     |   parenthesizedExpression
891         -> {$parenthesizedExpression.st}
892     |   IDENT
893         -> {%{$IDENT.text}}
894     |   CHELPER
895         -> {%{"constructorHelper"}}
896     |   ^(METHOD_CALL pe=primaryExpression gtal=genericTypeArgumentList? args=arguments)
897         -> method_call(primary={$pe.st}, generic_types={$gtal.st}, args={$args.st})
898     |   ^(ENTRY_METHOD_CALL pe=primaryExpression gtal=genericTypeArgumentList? args=arguments)
899         -> method_call(primary={$pe.st}, generic_types={$gtal.st}, args={$args.st})
900     |   explicitConstructorCall
901         -> {$explicitConstructorCall.st}
902     |   ^(ARRAY_ELEMENT_ACCESS pe=primaryExpression ex=expressionArrayAccess) {
903             if ($pe.start.symbolType != null && $pe.start.symbolType instanceof PointerType) {
904                 PointerType p = (PointerType)($pe.start.symbolType);
905                 if (p.baseType instanceof ClassSymbol) {
906                     ClassSymbol cs = (ClassSymbol)(p.baseType);
907                     if (cs.templateArgs != null && cs.templateArgs.size() > 1 &&
908                         cs.templateArgs.get(1) instanceof LiteralType) {
909                         LiteralType l = (LiteralType)(cs.templateArgs.get(1));
910                         dims = Integer.valueOf(l.literal);
911                     }
912                 }
913             }
914         }
915         -> {$pe.start.symbolType != null && $pe.start.symbolType instanceof PointerType && dims == 1}?
916                template(pe={$pe.st}, ex={$ex.st}) "(*(<pe>))[<ex>]"
917         -> {$pe.start.symbolType != null && $pe.start.symbolType instanceof PointerType && dims == 2}?
918                template(pe={$pe.st}, ex={$ex.st}) "(*(<pe>)).access(<ex>)"
919         -> template(pe={$pe.st}, ex={$ex.st}) "(<pe>)[<ex>]"
920     |   literal
921         -> {$literal.st}
922     |   newExpression[null]
923         -> {$newExpression.st}
924     |   THIS
925         -> {%{$start.getText()}}
926     |   arrayTypeDeclarator
927         -> {$arrayTypeDeclarator.st}
928     |   SUPER
929         -> {%{$start.getText()}}
930     |   GETNUMPES
931         ->  template() "CkNumPes()"
932     |   GETNUMNODES
933         ->  template() "CkNumNodes()"
934     |   GETMYPE
935         ->  template() "CkMyPe()"
936     |   GETMYNODE
937         ->  template() "CkMyNode()"
938     |   GETMYRANK
939         ->  template() "CkMyRank()"
940     |   domainExpression[null]
941         ->  {$domainExpression.st}
942     ;
943     
944 explicitConstructorCall
945     :   ^(THIS_CONSTRUCTOR_CALL genericTypeArgumentList? arguments)
946         -> template(t={$text}) "<t>"
947     |   ^(SUPER_CONSTRUCTOR_CALL primaryExpression? genericTypeArgumentList? arguments)
948         -> template(t={$text}) "<t>"
949     ;
950
951 arrayTypeDeclarator
952     :   ^(ARRAY_DECLARATOR (arrayTypeDeclarator | qualifiedIdentifier | primitiveType))
953         -> template(t={$text}) "<t>"
954     ;
955
956 newExpression[StringTemplate obtype]
957     :   ^(NEW_EXPRESSION arguments? domainExpression[$arguments.args])
958         -> template(domain={$domainExpression.st},type={$obtype}) "new <type>(<domain>)"
959     |   ^(NEW proxyType arguments)
960         -> template(t={$proxyType.st}, a={$arguments.st}) "<t>::ckNew(<a>)"
961     |   ^(NEW nonProxyType arguments)
962         -> template(q={$nonProxyType.st}, a={$arguments.st}) "new <q>(<a>)"
963     ;
964
965 arguments returns [List<StringTemplate> args]
966 @init {
967     $args = new ArrayList<StringTemplate>();
968 }
969     :   ^(ARGUMENT_LIST (e=expression { $args.add($e.st); } )*)        
970         ->  arguments(exprs={$args})
971     ;
972
973 literal
974 @init {
975 $st = %{$start.getText()};
976 }
977     :   HEX_LITERAL
978     |   OCTAL_LITERAL
979     |   DECIMAL_LITERAL
980     |   FLOATING_POINT_LITERAL
981     |   CHARACTER_LITERAL
982     |   STRING_LITERAL
983     |   TRUE
984     |   FALSE
985     |   NULL
986     ;
987