55407b8e35a31b588b38febbad35a03ce5638371
[charm.git] / src / langs / charj / src / charj / translator / CharjEmitter.g
1 /**
2  * ANTLR (v3) Tree Parser for the Charj Language
3  */
4
5 tree grammar CharjEmitter;
6
7 options {
8     backtrack = true; 
9     memoize = true;
10     tokenVocab = Charj;
11     ASTLabelType = CharjAST;
12     output = template;
13 }
14
15
16 @header {
17 package charj.translator;
18 }
19
20
21 @members {
22     SymbolTable symtab = null;
23
24     PackageScope currentPackage = null;
25     ClassSymbol currentClass = null;
26     MethodSymbol currentMethod = null;
27     LocalScope currentLocalScope = null;
28
29     Translator translator_;
30     OutputMode mode_;
31
32     private boolean emitCC() { return mode_ == OutputMode.cc; }
33     private boolean emitCI() { return mode_ == OutputMode.ci; }
34     private boolean emitH() { return mode_ == OutputMode.h; }
35     private boolean debug() { return translator_.debug(); }
36
37     /**
38      *  Override ANTLR's token mismatch behavior so we throw exceptions early.
39      */
40     protected void mismatch(IntStream input, int ttype, BitSet follow)
41         throws RecognitionException {
42         throw new MismatchedTokenException(ttype, input);
43     }
44
45     /**
46      *  Override ANTLR's set mismatch behavior so we throw exceptions early.
47      */
48     public Object recoverFromMismatchedSet(IntStream input, RecognitionException e, BitSet follow)
49         throws RecognitionException {
50         throw e;
51     }
52
53     /**
54      *  Test a list of CharjAST nodes to see if any of them has the given token
55      *  type.
56      */
57     public boolean listContainsToken(List<CharjAST> list, int tokenType) {
58         if (list == null) return false;
59         for (CharjAST node : list) {
60             if (node.token.getType() == tokenType) {
61                 return true;
62             }
63         }
64         return false;
65     }
66 }
67
68
69 // Replace default ANTLR generated catch clauses with this action, allowing early failure.
70 @rulecatch {
71     catch (RecognitionException re) {
72         reportError(re);
73         throw re;
74     }
75 }
76
77
78 // Starting point for parsing a Charj file.
79 charjSource[SymbolTable symtab, OutputMode m]
80 @init {
81     this.symtab = symtab;
82     this.translator_ = symtab.translator;
83     this.mode_ = m;
84 }
85     :   ^(CHARJ_SOURCE (p=packageDeclaration)? 
86         (i+=importDeclaration)* 
87         (t=typeDeclaration))
88         -> {emitCC()}? charjSource_cc(pd={$p.names}, ids={$i}, tds={$t.st}, debug={debug()})
89         -> {emitCI()}? charjSource_ci(pd={$p.names}, ids={$i}, tds={$t.st}, debug={debug()})
90         -> {emitH()}? charjSource_h(pd={$p.names}, ids={$i}, tds={$t.st}, debug={debug()})
91         ->
92     ;
93
94 packageDeclaration
95 returns [List names]
96     :   ^('package' (ids+=IDENT)+)
97         {
98             $names = $ids;
99         }
100         ->
101     ;
102     
103 importDeclaration
104 @init {
105     String importID = null;
106 }
107     :   ^('import' qualifiedIdentifier ds='.*'?)
108         {
109             importID = $qualifiedIdentifier.text;
110             if ($ds != null) {
111             }
112         }
113         {$ds == null}? // TODO: add support for importing x.*
114         -> {(emitCC() || emitH())}? importDeclaration_cc_h(
115             inc_id={importID.replace(".","/")},
116             use_id={importID.replace(".","::")})
117         ->
118     ;
119     
120 typeDeclaration
121     :   ^(TYPE 'class' IDENT (^('extends' su=type))? (^('implements' type+))? (csds+=classScopeDeclaration)*)
122         {
123             currentClass = (ClassSymbol)$IDENT.symbol;
124         }
125         -> {emitCC()}? classDeclaration_cc(
126                 sym={currentClass},
127                 ident={$IDENT.text}, 
128                 ext={$su.st}, 
129                 csds={$csds})
130         -> {emitH()}?  classDeclaration_h(
131                 sym={currentClass},
132                 ident={$IDENT.text}, 
133                 ext={$su.st}, 
134                 csds={$csds})
135         ->
136     |   ^('interface' IDENT (^('extends' type+))? interfaceScopeDeclaration*)
137         -> template(t={$text}) "/*INTERFACE-not implemented*/ <t>"
138     |   ^('enum' IDENT (^('implements' type+))? classScopeDeclaration*)
139         -> template(t={$text}) "/*ENUM-not implemented*/ <t>"
140     |   ^(TYPE chareType IDENT (^('extends' type))? (^('implements' type+))? (csds+=classScopeDeclaration)*)
141         {
142             currentClass = (ClassSymbol)$IDENT.symbol;
143         }
144         -> {emitCC()}? chareDeclaration_cc(
145                 sym={currentClass},
146                 ident={$IDENT.text}, 
147                 ext={$su.st}, 
148                 csds={$csds})
149         -> {emitCI()}? chareDeclaration_ci(
150                 sym={currentClass},
151                 chareType={$chareType.st},
152                 arrayDim={null},
153                 ident={$IDENT.text}, 
154                 ext={$su.st}, 
155                 csds={$csds})
156         -> {emitH()}? chareDeclaration_h(
157                 sym={currentClass},
158                 ident={$IDENT.text}, 
159                 ext={$su.st}, 
160                 csds={$csds})
161         ->
162     ;
163
164 chareType
165 @init {
166 $st = %{$start.getText()};
167 }
168     :   'chare'
169     |   'group'
170     |   'nodegroup'
171     |   ^('chare_array' ARRAY_DIMENSION)
172         -> template(t={$ARRAY_DIMENSION.text}) "array [<t>]"
173     ;
174
175 enumConstant
176     :   ^(IDENT arguments?)
177         -> template(t={$text}) "/*enumConstant-not implemented*/ <t>"
178     ;
179
180 classScopeDeclaration
181 @init {
182   boolean entry = false;
183   List<String> modList = new ArrayList<String>();
184
185 }
186     :   ^(FUNCTION_METHOD_DECL m=modifierList? g=genericTypeParameterList? 
187             ty=type IDENT f=formalParameterList a=arrayDeclaratorList? 
188             b=block?)
189         { 
190             if ($m.st != null) {
191                 // determine whether this is an entry method
192                 entry = listContainsToken($m.start.getChildren(), ENTRY);
193                 for(Object o : $m.names)
194                   if(o.equals("entry")) continue;
195                   else modList.add(o.toString());
196             }
197         }
198         -> {emitCC()}? funcMethodDecl_cc(
199                 modl={modList}, 
200                 gtpl={$g.st}, 
201                 ty={$ty.text},
202                 id={$IDENT.text}, 
203                 fpl={$f.st}, 
204                 adl={$a.st},
205                 block={$b.st})
206         -> {emitH()}? funcMethodDecl_h(
207                 modl={modList}, 
208                 gtpl={$g.st}, 
209                 ty={$ty.text},
210                 id={$IDENT.text}, 
211                 fpl={$f.st}, 
212                 adl={$a.st},
213                 block={$b.st})
214         -> {(emitCI() && entry)}? funcMethodDecl_ci(
215                 modl={$m.st}, 
216                 gtpl={$g.st}, 
217                 ty={$ty.text},
218                 id={$IDENT.text}, 
219                 fpl={$f.st}, 
220                 adl={$a.st},
221                 block={$b.st})
222         ->
223     |   ^(PRIMITIVE_VAR_DECLARATION modifierList? simpleType variableDeclaratorList)
224         -> {emitCC() || emitH()}? class_var_decl(
225             modl={$modifierList.st},
226             type={$simpleType.st},
227             declList={$variableDeclaratorList.st})
228         ->
229     |   ^(OBJECT_VAR_DECLARATION modifierList? objectType variableDeclaratorList)
230         -> {emitCC() || emitH()}? class_var_decl(
231             modl={$modifierList.st},
232             type={$objectType.st},
233             declList={$variableDeclaratorList.st})
234         ->
235     |   ^(CONSTRUCTOR_DECL m=modifierList? g=genericTypeParameterList? IDENT f=formalParameterList b=block)
236         { 
237             // determine whether this is an entry method
238             if ($m.st != null) {
239                 entry = listContainsToken($m.start.getChildren(), ENTRY);
240             }
241         }
242         -> {emitCC()}? ctorDecl_cc(
243                 modl={$m.st}, 
244                 gtpl={$g.st}, 
245                 id={$IDENT.text}, 
246                 fpl={$f.st}, 
247                 block={$b.st})
248         -> {emitCI() && entry}? ctorDecl_ci(
249                 modl={$m.st}, 
250                 gtpl={$g.st}, 
251                 id={$IDENT.text}, 
252                 fpl={$f.st}, 
253                 block={$b.st})
254         -> {emitH()}? ctorDecl_h(
255                 modl={$m.st}, 
256                 gtpl={$g.st}, 
257                 id={$IDENT.text}, 
258                 fpl={$f.st}, 
259                 block={$b.st})
260         ->
261     ;
262     
263 interfaceScopeDeclaration
264     :   ^(FUNCTION_METHOD_DECL modifierList? genericTypeParameterList? type IDENT formalParameterList arrayDeclaratorList?)
265         -> template(t={$text}) "/*interfaceScopeDeclarations-not implemented */ <t>"
266     |   ^(PRIMITIVE_VAR_DECLARATION modifierList? simpleType variableDeclaratorList)
267         -> template(t={$text}) "/*interfaceScopeDeclarations-not implemented */ <t>"
268     |   ^(OBJECT_VAR_DECLARATION modifierList? objectType variableDeclaratorList)
269         -> template(t={$text}) "/*interfaceScopeDeclarations-not implemented */ <t>"
270     ;
271
272 variableDeclaratorList
273     :   ^(VAR_DECLARATOR_LIST (var_decls+=variableDeclarator)+)
274         -> var_decl_list(var_decls={$var_decls})
275     ;
276
277 variableDeclarator
278     :   ^(VAR_DECLARATOR id=variableDeclaratorId initializer=variableInitializer?)
279         -> var_decl(id={$id.st}, initializer={$initializer.st})
280     ;
281     
282 variableDeclaratorId
283     :   ^(IDENT adl=arrayDeclaratorList?)
284         -> var_decl_id(id={$IDENT.text}, arrayDeclList={$adl.st})
285     ;
286
287 variableInitializer
288     :   arrayInitializer
289         -> {$arrayInitializer.st}
290     |   expression
291         -> {$expression.st}
292     ;
293
294 arrayDeclaratorList
295     :   ^(ARRAY_DECLARATOR_LIST ARRAY_DECLARATOR*)  
296         -> template(t={$text}) "<t>"
297     ;
298     
299 arrayInitializer
300     :   ^(ARRAY_INITIALIZER variableInitializer*)
301         -> template(t={$text}) "/* arrayInitializer-not implemented */ <t>"
302     ;
303
304 genericTypeParameterList
305     :   ^(GENERIC_TYPE_PARAM_LIST genericTypeParameter+)
306         -> template(t={$text}) "/*GENERIC_TYPE_PARAM_LIST-not implemented*/ <t>"
307     ;
308
309 genericTypeParameter
310     :   ^(IDENT bound?)
311         -> template(t={$text}) "/*genericTypeParameter-not implemented*/ <t>"
312     ;
313         
314 bound
315     :   ^(EXTENDS_BOUND_LIST type+)
316         -> template(t={$text}) "/*EXTENDS_BOUND_LIST-not implemented*/ <t>"
317     ;
318
319 throwsClause
320     :   ^(THROWS_CLAUSE qualifiedIdentifier+)
321         -> template(t={$text}) "/* throwsClause-not implemented */ <t>"
322     ;
323
324 modifierList
325 returns [List<String> names]
326     :   ^(MODIFIER_LIST (m+=modifier)+)
327         {
328           $names = new ArrayList<String>();
329           for(Object o : $m) $names.add(o.toString());
330         }
331         -> mod_list(mods={$m})
332     ;
333
334 modifier
335 @init {
336 $st = %{$start.getText()};
337 }
338     :   'public'
339     |   'protected'
340     |   'private'
341     |   'entry'
342     |   'abstract'
343     |   'native'
344     |   localModifier
345         -> {$localModifier.st}
346     ;
347
348 localModifierList
349     :   ^(LOCAL_MODIFIER_LIST (m+=localModifier)+)
350         -> local_mod_list(mods={$m})
351     ;
352
353 localModifier
354 @init {
355 $st = %{$start.getText()};
356 }
357     :   'final'
358     |   'static'
359     |   'volatile'
360     ;
361
362     
363 type
364     :   simpleType
365         -> {$simpleType.st}
366     |   objectType 
367         -> {$objectType.st}
368     |   'void'
369     ;
370
371 simpleType
372     :   ^(TYPE primitiveType arrayDeclaratorList?)
373         -> type(typeID={$primitiveType.st}, arrDeclList={$arrayDeclaratorList.st})
374     ;
375
376 objectType
377     :   ^(TYPE qualifiedTypeIdent arrayDeclaratorList?)
378         -> type(typeID={$qualifiedTypeIdent.st}, arrDeclList={$arrayDeclaratorList.st})
379     ;
380
381 qualifiedTypeIdent
382     :   ^(QUALIFIED_TYPE_IDENT (t+=typeIdent)+) 
383         -> template(types={$t}) "<types; separator=\".\">"
384     ;
385
386 typeIdent
387     :   ^(IDENT genericTypeArgumentList?)
388         -> typeIdent(typeID={$IDENT.text}, generics={$genericTypeArgumentList.st})
389     ;
390
391 primitiveType
392 @init {
393 $st = %{$start.getText()};
394 }
395     :   'boolean'
396         -> template() "bool"
397     |   'char'
398     |   'byte'
399         -> template() "char"
400     |   'short'
401     |   'int'
402     |   'long'
403     |   'float'
404     |   'double'
405     ;
406
407 genericTypeArgumentList
408     :   ^(GENERIC_TYPE_ARG_LIST (gta+=genericTypeArgument)+)
409         -> template(gtal={$gta}) "\<<gtal; separator=\", \">\>"
410     ;
411     
412 genericTypeArgument
413     :   type
414         -> {$type.st}
415     |   '?'
416         -> template(t={$text}) "/* genericTypeArgument: wildcard bound types not implemented */ <t>"
417     ;
418
419 formalParameterList
420     :   ^(FORMAL_PARAM_LIST (fpsd+=formalParameterStandardDecl)* fpvd=formalParameterVarargDecl?)
421         -> formal_param_list(sdecl={$fpsd}, vdecl={$fpvd.st})
422     ;
423     
424 formalParameterStandardDecl
425     :   ^(FORMAL_PARAM_STD_DECL lms=localModifierList? t=type vdid=variableDeclaratorId)
426         -> formal_param_decl(modList={$lms.st}, type={$t.st}, declID={$vdid.st})
427     ;
428     
429 formalParameterVarargDecl
430     :   ^(FORMAL_PARAM_VARARG_DECL localModifierList? type variableDeclaratorId)
431         -> template(t={$text}) "/*formal parameter varargs not implemented*/ <t>"
432     ;
433     
434 qualifiedIdentifier
435     :   IDENT
436         -> template(t={$text}) "<t>"
437     |   ^('.' qualifiedIdentifier IDENT)
438         -> template(t={$text}) "<t>"
439     ;
440     
441 block
442 @init { boolean emptyBlock = true; }
443     :   ^(BLOCK (b+=blockStatement)*)
444         { emptyBlock = ($b == null || $b.size() == 0); }
445         -> {emitCC() && emptyBlock}? template(bsl={$b}) "{ }"
446         -> {emitCC()}? block_cc(bsl={$b})
447         ->
448     ;
449     
450 blockStatement
451     :   localVariableDeclaration
452         -> {$localVariableDeclaration.st}
453     |   statement
454         -> {$statement.st}
455     ;
456
457
458 localVariableDeclaration
459     :   ^(PRIMITIVE_VAR_DECLARATION localModifierList? simpleType variableDeclaratorList)
460         -> local_var_decl(
461             modList={null},
462             type={$simpleType.st},
463             declList={$variableDeclaratorList.st})
464     |   ^(OBJECT_VAR_DECLARATION localModifierList? objectType variableDeclaratorList)
465         -> local_var_decl(
466             modList={null},
467             type={$objectType.st},
468             declList={$variableDeclaratorList.st})
469     ;
470
471
472 statement
473     :   block
474         -> {$block.st}
475     |   ^('assert' cond=expression msg=expression?)
476         -> assert(cond={$cond.st}, msg={$msg.st})
477     |   ^('if' parenthesizedExpression then=statement else_=statement?)
478         -> if(cond={$parenthesizedExpression.st}, then={$then.st}, else_={$else_.st})
479     |   ^('for' forInit? FOR_EXPR cond=expression? FOR_UPDATE (update+=expression)* s=statement)
480         -> for(initializer={$forInit.st}, cond={$cond.st}, update={$update}, body={$s.st})
481     |   ^(FOR_EACH localModifierList? type IDENT expression statement) 
482         -> template(t={$text}) "/* foreach not implemented */ <t>"
483     |   ^('while' pe=parenthesizedExpression s=statement)
484         -> while(cond={$pe.st}, body={$s.st})
485     |   ^('do' s=statement pe=parenthesizedExpression)
486         -> dowhile(cond={$pe.st}, block={$s.st})
487     |   ^('switch' pe=parenthesizedExpression (scls+=switchCaseLabel)*)
488         -> switch(expr={$pe.st}, labels={$scls})
489     |   ^('return' e=expression?)
490         -> return(val={$e.st})
491     |   ^('throw' expression)
492         -> template(t={$text}) "/* throw not implemented */ <t>"
493     |   ^('break' IDENT?)
494         -> template() "break;" // TODO: support labeling
495     |   ^('continue' IDENT?)
496         -> template() "continue;" // TODO: support labeling
497     |   ^(LABELED_STATEMENT i=IDENT s=statement)
498         -> label(text={$i.text}, stmt={$s.st})
499     |   expression
500         -> template(expr={$expression.st}) "<expr>;"
501     |   ^('embed' STRING_LITERAL EMBED_BLOCK)
502         ->  embed_cc(str={$STRING_LITERAL.text}, blk={$EMBED_BLOCK.text})
503     |   ';' // Empty statement.
504         -> {%{$start.getText()}}
505     ;
506         
507 switchCaseLabel
508     :   ^('case' expression (b+=blockStatement)*)
509         -> case(expr={$expression.st}, block={$b})
510     |   ^('default' (b+=blockStatement)*)
511         -> template(block={$b}) "default: <block>"
512     ;
513     
514 forInit
515     :   localVariableDeclaration
516         -> template(lvd={$localVariableDeclaration.st}) "<lvd>"
517     |   (ex+=expression)+
518         -> template(ex={$ex}) "<ex; separator=\", \">"
519     ;
520
521 // EXPRESSIONS
522
523 parenthesizedExpression
524     :   ^(PAREN_EXPR exp=expression)
525         -> template(expr={$exp.st}) "(<expr>)"
526     ;
527     
528 expression
529     :   ^(EXPR expr)
530         -> {$expr.st}
531     ;
532
533 expr
534     :   ^('=' e1=expr e2=expr)
535         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> = <e2>"
536     |   ^('+=' e1=expr e2=expr)
537         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> += <e2>"
538     |   ^('-=' e1=expr e2=expr)
539         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> -= <e2>"
540     |   ^('*=' e1=expr e2=expr)
541         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> *= <e2>"
542     |   ^('/=' e1=expr e2=expr)
543         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> /= <e2>"
544     |   ^('&=' e1=expr e2=expr)
545         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> &= <e2>"
546     |   ^('|=' e1=expr e2=expr)
547         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> |= <e2>"
548     |   ^('^=' e1=expr e2=expr)
549         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> ^= <e2>"
550     |   ^('%=' e1=expr e2=expr)
551         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> %= <e2>"
552     |   ^('>>>=' e1=expr e2=expr)
553         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \>\>\>= <e2>"
554     |   ^('>>=' e1=expr e2=expr)
555         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \>\>= <e2>"
556     |   ^('<<=' e1=expr e2=expr)
557         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \<\<= <e2>"
558     |   ^('?' e1=expr e2=expr e3=expr)
559         -> template(e1={$e1.st}, e2={$e2.st}, e3={$e3.st}) "<e1> ? <e2> : <e3>"
560     |   ^('||' e1=expr e2=expr)
561         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> || <e2>"
562     |   ^('&&' e1=expr e2=expr)
563         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> && <e2>"
564     |   ^('|' e1=expr e2=expr)
565         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> | <e2>"
566     |   ^('^' e1=expr e2=expr)
567         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> ^ <e2>"
568     |   ^('&' e1=expr e2=expr)
569         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> & <e2>"
570     |   ^('==' e1=expr e2=expr)
571         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> == <e2>"
572     |   ^('!=' e1=expr e2=expr)
573         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> != <e2>"
574     |   ^('instanceof' expr type)
575         -> template(t={$text}) "/* instanceof not implemented */ <t>"
576     |   ^('<=' e1=expr e2=expr)
577         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \<= <e2>"
578     |   ^('>=' e1=expr e2=expr)
579         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \>= <e2>"
580     |   ^('>>>' e1=expr e2=expr)
581         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \>\>\> <e2>"
582     |   ^('>>' e1=expr e2=expr)
583         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \>\> <e2>"
584     |   ^('>' e1=expr e2=expr)
585         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \> <e2>"
586     |   ^('<<' e1=expr e2=expr)
587         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \<\< <e2>"
588     |   ^('<' e1=expr e2=expr)
589         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \< <e2>"
590     |   ^('+' e1=expr e2=expr)
591         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> + <e2>"
592     |   ^('-' e1=expr e2=expr)
593         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> - <e2>"
594     |   ^('*' e1=expr e2=expr)
595         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> * <e2>"
596     |   ^('/' e1=expr e2=expr)
597         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> / <e2>"
598     |   ^('%' e1=expr e2=expr)
599         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> % <e2>"
600     |   ^(UNARY_PLUS e1=expr)
601         -> template(e1={$e1.st}) "+<e1>"
602     |   ^(UNARY_MINUS e1=expr)
603         -> template(e1={$e1.st}) "-<e1>"
604     |   ^(PRE_INC e1=expr)
605         -> template(e1={$e1.st}) "++<e1>"
606     |   ^(PRE_DEC e1=expr)
607         -> template(e1={$e1.st}) "--<e1>"
608     |   ^(POST_INC e1=expr)
609         -> template(e1={$e1.st}) "<e1>++"
610     |   ^(POST_DEC e1=expr)
611         -> template(e1={$e1.st}) "<e1>--"
612     |   ^('~' e1=expr)
613         -> template(e1={$e1.st}) "~<e1>"
614     |   ^('!' e1=expr)
615         -> template(e1={$e1.st}) "!<e1>"
616     |   ^(CAST_EXPR ty=type e1=expr)
617         -> template(ty={$ty.st}, e1={$e1.st}) "(<ty>)<e1>"
618     |   primaryExpression
619         -> {$primaryExpression.st}
620     ;
621     
622 primaryExpression
623     :   ^('.' prim=primaryExpression IDENT)
624         -> template(id={$IDENT}, prim={$prim.st}) "<prim>.<id>"
625     |   ^('.' prim=primaryExpression 'this')
626         -> template(prim={$prim.st}) "<prim>.this"
627     |   ^('.' prim=primaryExpression 'super')
628         -> template(prim={$prim.st}) "<prim>.super"
629     |   parenthesizedExpression
630         -> {$parenthesizedExpression.st}
631     |   IDENT
632         -> {%{$start.getText()}}
633     |   ^(METHOD_CALL pe=primaryExpression gtal=genericTypeArgumentList? args=arguments)
634         -> method_call(primary={$pe.st}, generic_types={$gtal.st}, args={$args.st})
635     |   explicitConstructorCall
636         -> {$explicitConstructorCall.st}
637     |   ^(ARRAY_ELEMENT_ACCESS pe=primaryExpression ex=expression)
638         -> template(pe={$pe.st}, ex={$ex.st}) "<pe>[<ex>]"
639     |   literal
640         -> {$literal.st}
641     |   newExpression
642         -> {$newExpression.st}
643     |   'this'
644         -> {%{$start.getText()}}
645     |   arrayTypeDeclarator
646         -> {$arrayTypeDeclarator.st}
647     |   'super'
648         -> {%{$start.getText()}}
649     ;
650     
651 explicitConstructorCall
652     :   ^(THIS_CONSTRUCTOR_CALL genericTypeArgumentList? arguments)
653         -> template(t={$text}) "<t>"
654     |   ^(SUPER_CONSTRUCTOR_CALL primaryExpression? genericTypeArgumentList? arguments)
655         -> template(t={$text}) "<t>"
656     ;
657
658 arrayTypeDeclarator
659     :   ^(ARRAY_DECLARATOR (arrayTypeDeclarator | qualifiedIdentifier | primitiveType))
660         -> template(t={$text}) "<t>"
661     ;
662
663 newExpression
664     :   ^(  STATIC_ARRAY_CREATOR
665             (   primitiveType newArrayConstruction
666             |   genericTypeArgumentList? qualifiedTypeIdent newArrayConstruction
667             )
668         )
669         -> template(t={$text}) "<t>"
670     ;
671
672 newArrayConstruction
673     :   arrayDeclaratorList arrayInitializer
674         -> array_construction_with_init(
675                 array_decls={$arrayDeclaratorList.st},
676                 initializer={$arrayInitializer.st})
677     |   (ex+=expression)+ adl=arrayDeclaratorList?
678         -> array_construction(exprs={$ex}, array_decls={$adl.st})
679     ;
680
681 arguments
682     :   ^(ARGUMENT_LIST (ex+=expression)*)
683         -> arguments(exprs={$ex})
684     ;
685
686 literal
687 @init {
688 $st = %{$start.getText()};
689 }
690     :   HEX_LITERAL
691     |   OCTAL_LITERAL
692     |   DECIMAL_LITERAL
693     |   FLOATING_POINT_LITERAL
694     |   CHARACTER_LITERAL
695     |   STRING_LITERAL
696     |   'true'
697     |   'false'
698     |   'null'
699     ;
700