Add grammar for SDAG 'when' and 'overlap' statements
[charm.git] / src / langs / charj / src / charj / translator / CharjEmitter.g
1 /**
2  * ANTLR (v3) Tree Parser for the Charj Language
3  */
4
5 tree grammar CharjEmitter;
6
7 options {
8     backtrack = true; 
9     memoize = true;
10     tokenVocab = Charj;
11     ASTLabelType = CharjAST;
12     output = template;
13 }
14
15
16 @header {
17 package charj.translator;
18 }
19
20
21 @members {
22     SymbolTable symtab = null;
23
24     PackageScope currentPackage = null;
25     ClassSymbol currentClass = null;
26     MethodSymbol currentMethod = null;
27     LocalScope currentLocalScope = null;
28
29     Translator translator_;
30     OutputMode mode_;
31
32     private boolean emitCC() { return mode_ == OutputMode.cc; }
33     private boolean emitCI() { return mode_ == OutputMode.ci; }
34     private boolean emitH() { return mode_ == OutputMode.h; }
35     private boolean debug() { return translator_.debug(); }
36     private String basename() { return translator_.basename(); }
37
38     /**
39      *  Override ANTLR's token mismatch behavior so we throw exceptions early.
40      */
41     protected void mismatch(IntStream input, int ttype, BitSet follow)
42         throws RecognitionException {
43         throw new MismatchedTokenException(ttype, input);
44     }
45
46     /**
47      *  Override ANTLR's set mismatch behavior so we throw exceptions early.
48      */
49     public Object recoverFromMismatchedSet(IntStream input, RecognitionException e, BitSet follow)
50         throws RecognitionException {
51         throw e;
52     }
53
54     /**
55      *  Test a list of CharjAST nodes to see if any of them has the given token
56      *  type.
57      */
58     public boolean listContainsToken(List<CharjAST> list, int tokenType) {
59         if (list == null) return false;
60         for (CharjAST node : list) {
61             if (node.token.getType() == tokenType) {
62                 return true;
63             }
64         }
65         return false;
66     }
67 }
68
69
70 // Replace default ANTLR generated catch clauses with this action, allowing early failure.
71 @rulecatch {
72     catch (RecognitionException re) {
73         reportError(re);
74         throw re;
75     }
76 }
77
78
79 // Starting point for parsing a Charj file.
80 charjSource[SymbolTable symtab, OutputMode m]
81 @init {
82     this.symtab = symtab;
83     this.translator_ = symtab.translator;
84     this.mode_ = m;
85 }
86     :   ^(CHARJ_SOURCE (p=packageDeclaration)? 
87         (i+=importDeclaration)*
88         (r+=readonlyDeclaration)*
89         (t+=typeDeclaration)*)
90         -> {emitCC()}? charjSource_cc(basename={basename()}, pd={$p.names}, imports={$i}, types={$t}, ros={$r}, debug={debug()})
91         -> {emitCI()}? charjSource_ci(basename={basename()}, pd={$p.names}, imports={$i}, types={$t}, ros={$r}, debug={debug()})
92         -> {emitH()}? charjSource_h(basename={basename()}, pd={$p.names}, imports={$i}, types={$t}, ros={$r}, debug={debug()})
93         ->
94     ;
95
96 topLevelDeclaration
97     :   importDeclaration -> {$importDeclaration.st;}
98     |   typeDeclaration -> {$typeDeclaration.st;}
99     ;
100
101 packageDeclaration returns [List names]
102     :   ^('package' (ids+=IDENT)+)
103         {
104             $names = $ids;
105         }
106         ->
107     ;
108
109 readonlyDeclaration
110     :   ^(READONLY lvd=localVariableDeclaration)
111         -> {emitCI()}? template(bn={basename()}, v={$lvd.st}) "readonly <v>"
112         -> {emitH()}? template(v={$lvd.st}) "extern <v>"
113         -> {emitCC()}? {$lvd.st;}
114         ->
115     ;
116     
117 importDeclaration
118 @init {
119     String importID = null;
120 }
121     :   ^('import' qualifiedIdentifier ds='.*'?)
122         {
123             importID = $qualifiedIdentifier.text;
124             if ($ds != null) {
125             }
126         }
127         {$ds == null}? // TODO: add support for importing x.*
128         -> {(emitCC() || emitH())}? importDeclaration_cc_h(
129             inc_id={importID.replace(".","/")},
130             use_id={importID.replace(".","::")})
131         ->
132     ;
133     
134 typeDeclaration
135 @init {
136     boolean needsMigration = false;
137     List<String> inits = new ArrayList<String>();
138     List<String> pupInits = new ArrayList<String>();
139 }
140     :   ^(TYPE CLASS IDENT (^('extends' su=type))? (^('implements' type+))?
141         {
142             currentClass = (ClassSymbol)$IDENT.def;
143
144             inits = currentClass.generateInits(currentClass.initializers);
145         }
146         (csds+=classScopeDeclaration)*)
147         -> {emitCC()}? classDeclaration_cc(
148                 sym={currentClass},
149                 ident={$IDENT.text}, 
150                 ext={$su.st}, 
151                 csds={$csds},
152                 inits={inits})
153         -> {emitH()}?  classDeclaration_h(
154                 sym={currentClass},
155                 ident={$IDENT.text}, 
156                 ext={$su.st}, 
157                 csds={$csds})
158         ->
159     |   ^('template' (i0+=IDENT*) ^('class' i1=IDENT (^('extends' su=type))? (^('implements' type+))? (csds+=classScopeDeclaration)*))
160         -> {emitH()}? templateDeclaration_h(
161             tident={$i0},
162             ident={$i1.text},
163             ext={$su.st},
164             csds={$csds})
165         -> 
166     |   ^(INTERFACE IDENT (^('extends' type+))? interfaceScopeDeclaration*)
167         -> template(t={$text}) "/*INTERFACE-not implemented*/ <t>"
168     |   ^(ENUM IDENT (^('implements' type+))? classScopeDeclaration*)
169         -> template(t={$text}) "/*ENUM-not implemented*/ <t>"
170     |   ^(TYPE chareType IDENT (^('extends' type))? (^('implements' type+))?
171         {
172             currentClass = (ClassSymbol)$IDENT.def;
173             needsMigration = currentClass.isChareArray && !currentClass.hasMigrationCtor;
174
175             inits = currentClass.generateInits(currentClass.initializers);
176             pupInits = currentClass.generateInits(currentClass.pupInitializers);
177         }
178         (csds+=classScopeDeclaration)*)
179         -> {emitCC()}? chareDeclaration_cc(
180                 sym={currentClass},
181                 ident={$IDENT.text}, 
182                 ext={$su.st}, 
183                 csds={$csds},
184                 pupInits={pupInits},
185                 pupers={currentClass.generatePUPers()},
186                 needsMigration={needsMigration},
187                 inits={inits})
188         -> {emitCI()}? chareDeclaration_ci(
189                 basename={basename()},
190                 sym={currentClass},
191                 chareType={$chareType.st},
192                 arrayDim={null},
193                 ident={$IDENT.text}, 
194                 ext={$su.st}, 
195                 csds={$csds})
196         -> {emitH()}? chareDeclaration_h(
197                 sym={currentClass},
198                 ident={$IDENT.text}, 
199                 ext={$su.st}, 
200                 csds={$csds},
201                 needsPupInit={pupInits.size() > 0},
202                 needsMigration={needsMigration})
203         ->
204     ;
205
206 chareType
207 @init {
208 $st = %{$start.getText()};
209 }
210     :   CHARE
211     |   GROUP
212     |   NODEGROUP
213     |   MAINCHARE
214     |   ^(CHARE_ARRAY ARRAY_DIMENSION)
215         -> template(t={$ARRAY_DIMENSION.text}) "array [<t>]"
216     ;
217
218 enumConstant
219     :   ^(IDENT arguments?)
220         -> template(t={$text}) "/*enumConstant-not implemented*/ <t>"
221     ;
222
223 classScopeDeclaration
224 @init
225 {
226     boolean entry = false;
227     boolean migrationCtor = false;
228 }
229     :   ^(FUNCTION_METHOD_DECL m=modifierList? g=genericTypeParameterList? 
230             ty=type IDENT f=formalParameterList
231             b=block?) {
232             currentMethod = (MethodSymbol)$IDENT.def;
233         }
234         -> {emitCC()}? funcMethodDecl_cc(
235                 classSym={currentClass},
236                 methodSym={currentMethod},
237                 modl={$m.st}, 
238                 gtpl={$g.st}, 
239                 ty={$ty.st},
240                 id={$IDENT.text}, 
241                 fpl={$f.st}, 
242                 block={$b.st})
243         -> {emitH()}? funcMethodDecl_h(
244                 modl={$m.st}, 
245                 gtpl={$g.st}, 
246                 ty={$ty.st},
247                 id={$IDENT.text}, 
248                 fpl={$f.st}, 
249                 block={$b.st})
250         -> {emitCI()}? // do nothing, since it's not an entry method
251         ->
252     |   ^(ENTRY_FUNCTION_DECL m=modifierList? g=genericTypeParameterList? 
253             ty=type IDENT f=formalParameterList a=domainExpression[null]? 
254             b=block?) {
255             currentMethod = (MethodSymbol)$IDENT.def;
256         }
257         -> {emitCC()}? funcMethodDecl_cc(
258                 classSym={currentClass},
259                 methodSym={currentMethod},
260                 modl={$m.st}, 
261                 gtpl={$g.st}, 
262                 ty={$ty.st},
263                 id={$IDENT.text}, 
264                 fpl={$f.st}, 
265                 adl={$a.st},
266                 block={$b.st})
267         -> {emitH()}? funcMethodDecl_h(
268                 modl={$m.st}, 
269                 gtpl={$g.st}, 
270                 ty={$ty.st},
271                 id={$IDENT.text}, 
272                 fpl={$f.st}, 
273                 adl={$a.st},
274                 block={$b.st})
275         -> {emitCI()}? funcMethodDecl_ci(
276                 modl={$m.st}, 
277                 gtpl={$g.st}, 
278                 ty={$ty.st},
279                 id={$IDENT.text}, 
280                 fpl={$f.st}, 
281                 block={$b.st})
282         ->
283     |   ^(PRIMITIVE_VAR_DECLARATION modifierList? simpleType variableDeclaratorList[null])
284         -> {emitH()}? class_var_decl(
285             modl={$modifierList.st},
286             type={$simpleType.st},
287             declList={$variableDeclaratorList.st})
288         ->
289     |   ^(OBJECT_VAR_DECLARATION modifierList? objectType variableDeclaratorList[$objectType.st])
290         -> {emitH()}? class_var_decl(
291             modl={$modifierList.st},
292             type={$objectType.st},
293             declList={$variableDeclaratorList.st})
294         ->
295     |   ^(CONSTRUCTOR_DECL m=modifierList? g=genericTypeParameterList? IDENT f=formalParameterList b=block)
296         {
297             currentMethod = (MethodSymbol)$IDENT.def;
298         }
299         -> {emitCC()}? ctorDecl_cc(
300                 modl={$m.st},
301                 gtpl={$g.st}, 
302                 id={$IDENT.text}, 
303                 fpl={$f.st}, 
304                 block={$b.st})
305         -> {emitCI()}? // do nothing, it's not an entry constructor
306         -> {emitH()}? ctorDecl_h(
307                 modl={$m.st},
308                 gtpl={$g.st}, 
309                 id={$IDENT.text}, 
310                 fpl={$f.st}, 
311                 block={$b.st})
312         ->
313     |   ^(ENTRY_CONSTRUCTOR_DECL m=modifierList? g=genericTypeParameterList? IDENT f=formalParameterList b=block)
314         {
315             currentMethod = (MethodSymbol)$IDENT.def;
316             migrationCtor = currentClass.migrationCtor == $ENTRY_CONSTRUCTOR_DECL;
317         }
318         -> {emitCC()}? ctorDecl_cc(
319                 modl={$m.st},
320                 gtpl={$g.st}, 
321                 id={$IDENT.text}, 
322                 fpl={$f.st}, 
323                 block={$b.st})
324         -> {emitCI() && !migrationCtor}? ctorDecl_ci(
325                 modl={$m.st},
326                 gtpl={$g.st}, 
327                 id={$IDENT.text}, 
328                 fpl={$f.st}, 
329                 block={$b.st})
330         -> {emitH()}? ctorDecl_h(
331                 modl={$m.st},
332                 gtpl={$g.st}, 
333                 id={$IDENT.text}, 
334                 fpl={$f.st}, 
335                 block={$b.st})
336         ->
337     ;
338     
339 interfaceScopeDeclaration
340     :   ^(FUNCTION_METHOD_DECL modifierList? genericTypeParameterList? type IDENT formalParameterList)
341         -> template(t={$text}) "/*interfaceScopeDeclarations-not implemented */ <t>"
342     |   ^(PRIMITIVE_VAR_DECLARATION modifierList? simpleType variableDeclaratorList[$simpleType.st])
343         -> template(t={$text}) "/*interfaceScopeDeclarations-not implemented */ <t>"
344     |   ^(OBJECT_VAR_DECLARATION modifierList? objectType variableDeclaratorList[$objectType.st])
345         -> template(t={$text}) "/*interfaceScopeDeclarations-not implemented */ <t>"
346     ;
347
348 variableDeclaratorList[StringTemplate obtype]
349     :   ^(VAR_DECLARATOR_LIST (var_decls+=variableDeclarator[obtype])+ )
350         -> var_decl_list(var_decls={$var_decls})
351     ;
352
353 variableDeclarator[StringTemplate obtype]
354     :   ^(VAR_DECLARATOR id=variableDeclaratorId initializer=variableInitializer[obtype]?)
355         -> {emitCC()}? var_decl_cc(id={$id.st}, initializer={$initializer.st})
356         -> {emitH()}?  var_decl_h(id={$id.st}, initializer={$initializer.st})
357         -> {emitCI()}? var_decl_ci(id={$id.st}, initializer={$initializer.st})
358         ->
359     ; 
360     
361 variableDeclaratorId
362     :   ^(IDENT de=domainExpression[null]?)
363         -> var_decl_id(id={$IDENT.text}, domainExp={$de.st})
364     ;
365
366 variableInitializer[StringTemplate obtype]
367     :   arrayInitializer
368         -> {$arrayInitializer.st}
369     |   newExpression[obtype]
370         -> {$newExpression.st}
371     |   expression
372         -> {$expression.st}
373     ;
374
375 rangeItem
376     :   dl=DECIMAL_LITERAL
377         -> template(t={$dl.text}) "<t>"
378     |   IDENT
379         -> template(t={$IDENT.text}) "<t>"
380     ;
381
382 rangeExpression
383     :   ^(RANGE_EXPRESSION (ri+=rangeItem)*)
384         -> template(t={$ri}) "Range(<t; separator=\",\">)"
385     ;
386
387 rangeList returns [int len]
388     :   (r+=rangeExpression)*
389         { $len = $r.size(); }
390         -> template(t={$r}) "<t; separator=\", \">"
391     ;
392
393 domainExpression[List<StringTemplate> otherParams]
394     :   ^(DOMAIN_EXPRESSION rl=rangeList)
395         -> range_constructor(range={$rl.st}, others={$otherParams}, len={$rl.len})
396     ;
397
398 domainExpressionAccess
399     :   ^(DOMAIN_EXPRESSION rl=rangeListAccess)
400         -> template(t={$rangeListAccess.st}) "<t>"
401     ;
402
403 rangeListAccess
404     :   (r+=rangeExpressionAccess)*
405         -> template(t={$r}) "<t; separator=\", \">"
406     ;
407
408 rangeExpressionAccess
409     :   ^(RANGE_EXPRESSION (ri+=rangeItem)*)
410         -> template(t={$ri}) "<t; separator=\",\">"
411     ;
412
413 arrayInitializer
414     :   ^(ARRAY_INITIALIZER variableInitializer[null]*)
415         -> template(t={$text}) "/* arrayInitializer-not implemented */ <t>"
416     ;
417
418 genericTypeParameterList
419     :   ^(GENERIC_TYPE_PARAM_LIST genericTypeParameter+)
420         -> template(t={$text}) "/*GENERIC_TYPE_PARAM_LIST-not implemented*/ <t>"
421     ;
422
423 genericTypeParameter
424     :   ^(IDENT bound?)
425         -> template(t={$text}) "/*genericTypeParameter-not implemented*/ <t>"
426     ;
427         
428 bound
429     :   ^(EXTENDS_BOUND_LIST type+)
430         -> template(t={$text}) "/*EXTENDS_BOUND_LIST-not implemented*/ <t>"
431     ;
432
433 throwsClause
434     :   ^(THROWS_CLAUSE qualifiedIdentifier+)
435         -> template(t={$text}) "/* throwsClause-not implemented */ <t>"
436     ;
437
438 modifierList
439     :   ^(MODIFIER_LIST accessModifierList localModifierList charjModifierList otherModifierList)
440         ->  {emitCC()}? mod_list_cc(accmods = {$accessModifierList.names}, localmods = {$localModifierList.names}, charjmods = {$charjModifierList.names}, othermods = {$otherModifierList.names})
441         ->  {emitH()}? mod_list_h(accmods = {$accessModifierList.names}, localmods = {$localModifierList.names}, charjmods = {$charjModifierList.names}, othermods = {$otherModifierList.names})
442         ->  {emitCI()}? mod_list_ci(accmods = {$accessModifierList.names}, localmods = {$localModifierList.names}, charjmods = {$charjModifierList.names}, othermods = {$otherModifierList.names})
443         ->
444     ;
445
446 modifier
447     :   accessModifier
448     |   localModifier
449     |   charjModifier
450     |   otherModifier
451     ;
452
453 accessModifierList
454 returns [List names]
455     :   ^(ACCESS_MODIFIER_LIST (m+=accessModifier)*)
456         {
457             $names = $m;
458         }
459     ;
460 localModifierList
461 returns [List names]
462     :   ^(LOCAL_MODIFIER_LIST (m+=localModifier)*)
463         {
464             $names = $m;
465         }
466         ->  local_mod_list(mods = {$names})
467     ;
468
469 charjModifierList
470 returns [List names]
471     :   ^(CHARJ_MODIFIER_LIST (m+=charjModifier)*)
472         {
473             $names = $m;
474         }
475     ;
476
477 otherModifierList
478 returns [List names]
479     :   ^(OTHER_MODIFIER_LIST (m+=otherModifier)*)
480         {
481             $names = $m;
482         }
483     ;
484     
485 localModifier
486 @init
487 {
488     $st = %{$start.getText()};
489 }
490     :   FINAL
491     |   STATIC
492     |   VOLATILE
493     ;
494
495 accessModifier
496 @init
497 {
498     $st = %{$start.getText()};
499 }
500     :   PUBLIC
501     |   PROTECTED
502     |   PRIVATE
503         {
504             $st = %{"private"};
505         }
506     ;
507
508 charjModifier
509     :   ENTRY -> {%{$ENTRY.text}}
510     |   TRACED
511     ;
512
513 otherModifier
514 @init
515 {
516     $st = %{$start.getText()};
517 }
518     :   ABSTRACT
519     |   NATIVE
520     ;
521     
522 type
523     :   simpleType
524         -> {$simpleType.st}
525     |   objectType 
526         -> {$objectType.st}
527     |   VOID
528         {
529             $st = %{"void"};
530         }
531     ;
532
533 simpleType
534     :   ^(SIMPLE_TYPE primitiveType domainExpression[null]?)
535         -> simple_type(typeID={$primitiveType.st}, arrDeclList={$domainExpression.st})
536     ;
537
538 objectType //[boolean forNewExpression]
539     : proxyType -> {$proxyType.st;}
540     | nonProxyType -> {$nonProxyType.st}
541     ;
542
543 nonProxyType
544     :   ^(OBJECT_TYPE qualifiedTypeIdent domainExpression[null]?)
545         -> obj_type(typeID={$qualifiedTypeIdent.st}, arrDeclList={$domainExpression.st})
546     |   ^(POINTER_TYPE qualifiedTypeIdent domainExpression[null]?)
547         -> pointer_type(typeID={$qualifiedTypeIdent.st}, arrDeclList={$domainExpression.st})
548     |   ^(REFERENCE_TYPE qualifiedTypeIdent domainExpression[null]?)
549         -> reference_type(typeID={$qualifiedTypeIdent.st}, arrDeclList={$domainExpression.st})
550     ;
551
552 proxyType
553     :   ^(PROXY_TYPE qualifiedTypeIdent domainExpression[null]?)
554         -> proxy_type(typeID={$qualifiedTypeIdent.st}, arrDeclList={$domainExpression.st})
555     ;
556
557 qualifiedTypeIdent returns [ClassSymbol type]
558     :   ^(QUALIFIED_TYPE_IDENT (t+=typeIdent)+)
559         {$type = (ClassSymbol)$QUALIFIED_TYPE_IDENT.def;}
560         -> template(types={$t}) "<types; separator=\"::\">"
561     ;
562
563 typeIdent
564     :   ^(IDENT templateInstantiation?)
565         -> typeIdent(typeID={$IDENT.text}, generics={$templateInstantiation.st})
566     ;
567
568 primitiveType
569 @init {
570 $st = %{$start.getText()};
571 }
572     :   BOOLEAN
573         -> template() "bool"
574     |   CHAR
575     |   BYTE
576         -> template() "char"
577     |   SHORT
578     |   INT
579     |   LONG
580     |   FLOAT
581     |   DOUBLE
582     ;
583
584 templateArg
585     :   genericTypeArgument
586         -> {$genericTypeArgument.st}
587     |   literal
588         -> {$literal.st}
589     ;
590
591 templateArgList
592     :   params+=templateArg+
593         -> template(params={$params}) "<params; separator=\", \">"
594     ;
595
596 templateInstantiation
597     :   ^(TEMPLATE_INST templateArgList)
598         -> template(args={$templateArgList.st}) "\<<args>\>"
599     |   ^(TEMPLATE_INST ts=templateInstantiation)
600         -> template(inst={$ts.st}) "\<<inst>\>"
601     ;
602
603 genericTypeArgumentList
604     :   ^(GENERIC_TYPE_ARG_LIST (gta+=genericTypeArgument)+)
605         -> template(gtal={$gta}) "\<<gtal; separator=\", \">\>"
606     ;
607
608 genericTypeArgument
609     :   type
610         -> {$type.st}
611     |   '?'
612         -> template(t={$text}) "/* genericTypeArgument: wildcard bound types not implemented */ <t>"
613     ;
614
615 formalParameterList
616     :   ^(FORMAL_PARAM_LIST (fpsd+=formalParameterStandardDecl)* fpvd=formalParameterVarargDecl?)
617         -> formal_param_list(sdecl={$fpsd}, vdecl={$fpvd.st})
618     ;
619     
620 formalParameterStandardDecl
621     :   ^(FORMAL_PARAM_STD_DECL lms=localModifierList? t=type vdid=variableDeclaratorId)
622         -> formal_param_decl(modList={$lms.st}, type={$t.st}, declID={$vdid.st})
623     ;
624     
625 formalParameterVarargDecl
626     :   ^(FORMAL_PARAM_VARARG_DECL localModifierList? type variableDeclaratorId)
627         -> template(t={$text}) "/*formal parameter varargs not implemented*/ <t>"
628     ;
629     
630 qualifiedIdentifier
631     :   IDENT
632         -> template(t={$text}) "<t>"
633     |   ^(DOT qualifiedIdentifier IDENT)
634         -> template(t={$text}) "<t>"
635     ;
636     
637 block
638 @init { boolean emptyBlock = true; }
639     :   ^(BLOCK (b+=blockStatement)*)
640         { emptyBlock = ($b == null || $b.size() == 0); }
641         -> {emitCC() && emptyBlock}? template(bsl={$b}) "{ }"
642         -> {emitCC()}? block_cc(bsl={$b})
643         ->
644     ;
645     
646 blockStatement
647     :   localVariableDeclaration
648         -> {$localVariableDeclaration.st}
649     |   statement
650         -> {$statement.st}
651     ;
652
653
654 localVariableDeclaration
655     :   ^(PRIMITIVE_VAR_DECLARATION localModifierList? simpleType vdl=variableDeclaratorList[null])
656         -> local_var_decl(
657             modList={$localModifierList.st},
658             type={$simpleType.st},
659             declList={$vdl.st})
660     |   ^(OBJECT_VAR_DECLARATION localModifierList? objectType vdl=variableDeclaratorList[$objectType.st])
661         -> local_var_decl(
662             modList={$localModifierList.st},
663             type={$objectType.st},
664             declList={$vdl.st})
665     ;
666
667
668 statement
669     :   nonBlockStatement
670         -> {$nonBlockStatement.st}
671     |   sdagStatement
672         -> {$sdagStatement.st}
673     |   block
674         -> {$block.st}
675     ;
676
677 sdagStatement
678     :   ^(OVERLAP block)
679         -> template(b={$block.st}) "/* !!overlap not implemented <block> */
680     |   ^(WHEN (IDENT type IDENT)+ block)
681         -> template(b={$block.st}) "/* !!when not implemented <block> */
682     ;
683
684 nonBlockStatement
685     :   ^(ASSERT cond=expression msg=expression?)
686         -> assert(cond={$cond.st}, msg={$msg.st})
687     |   ^(IF parenthesizedExpression then=block else_=block?)
688         -> if(cond={$parenthesizedExpression.st}, then={$then.st}, else_={$else_.st})
689     |   ^(FOR forInit? FOR_EXPR cond=expression? FOR_UPDATE (update+=expression)* b=block)
690         -> for(initializer={$forInit.st}, cond={$cond.st}, update={$update}, body={$block.st})
691     |   ^(FOR_EACH localModifierList? type IDENT expression block) 
692         -> template(t={$text}) "/* foreach not implemented */ <t>"
693     |   ^(WHILE pe=parenthesizedExpression b=block)
694         -> while(cond={$pe.st}, body={$b.st})
695     |   ^(DO b=block pe=parenthesizedExpression)
696         -> dowhile(cond={$pe.st}, block={$b.st})
697     |   ^(SWITCH pe=parenthesizedExpression (scls+=switchCaseLabel)*)
698         -> switch(expr={$pe.st}, labels={$scls})
699     |   ^(RETURN e=expression?)
700         -> return(val={$e.st})
701     |   ^(THROW expression)
702         -> template(t={$text}) "/* throw not implemented */ <t>"
703     |   ^(BREAK IDENT?)
704         -> template() "break;" // TODO: support labeling
705     |   ^(CONTINUE IDENT?)
706         -> template() "continue;" // TODO: support labeling
707     |   ^(LABELED_STATEMENT i=IDENT s=statement)
708         -> label(text={$i.text}, stmt={$s.st})
709     |   expression
710         -> template(expr={$expression.st}) "<expr>;"
711     |   ^('delete' expression)
712         -> template(t={$expression.st}) "delete <t>;"
713     |   ^('embed' STRING_LITERAL EMBED_BLOCK)
714         ->  embed_cc(str={$STRING_LITERAL.text}, blk={$EMBED_BLOCK.text})
715     |   ';' // Empty statement.
716         -> {%{$start.getText()}}
717     |   ^(PRINT (exprs += expression)*)
718         ->  print(exprs = {$exprs})
719     |   ^(PRINTLN (exprs += expression)*)
720         ->  println(exprs = {$exprs})
721     |   ^(EXIT expression?)
722         ->  exit(expr = {$expression.st})
723     |   EXITALL
724         ->  exitall()
725     ;
726         
727 switchCaseLabel
728     :   ^(CASE expression (b+=blockStatement)*)
729         -> case(expr={$expression.st}, block={$b})
730     |   ^(DEFAULT (b+=blockStatement)*)
731         -> template(block={$b}) "default: <block>"
732     ;
733     
734 forInit
735     :   localVariableDeclaration
736         -> template(lvd={$localVariableDeclaration.st}) "<lvd>"
737     |   (ex+=expression)+
738         -> template(ex={$ex}) "<ex; separator=\", \">"
739     ;
740
741 // EXPRESSIONS
742
743 parenthesizedExpression
744     :   ^(PAREN_EXPR exp=expression)
745         -> template(expr={$exp.st}) "(<expr>)"
746     ;
747
748 expressionArrayAccess
749     :   ^(EXPR expr)
750         -> {$expr.st}
751     |    domainExpressionAccess
752         -> {$domainExpressionAccess.st}
753     ;
754     
755 expression
756     :   ^(EXPR expr)
757         -> {$expr.st}
758     |   domainExpression[null]
759         -> {$domainExpression.st}
760     ;
761
762 expr
763     :   ^(ASSIGNMENT e1=expr e2=expr)
764         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> = <e2>"
765     |   ^('+=' e1=expr e2=expr)
766         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> += <e2>"
767     |   ^('-=' e1=expr e2=expr)
768         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> -= <e2>"
769     |   ^('*=' e1=expr e2=expr)
770         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> *= <e2>"
771     |   ^('/=' e1=expr e2=expr)
772         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> /= <e2>"
773     |   ^('&=' e1=expr e2=expr)
774         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> &= <e2>"
775     |   ^('|=' e1=expr e2=expr)
776         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> |= <e2>"
777     |   ^('^=' e1=expr e2=expr)
778         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> ^= <e2>"
779     |   ^('%=' e1=expr e2=expr)
780         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> %= <e2>"
781     |   ^('>>>=' e1=expr e2=expr)
782         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \>\>\>= <e2>"
783     |   ^('>>=' e1=expr e2=expr)
784         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \>\>= <e2>"
785     |   ^('<<=' e1=expr e2=expr)
786         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \<\<= <e2>"
787     |   ^('?' e1=expr e2=expr e3=expr)
788         -> template(e1={$e1.st}, e2={$e2.st}, e3={$e3.st}) "<e1> ? <e2> : <e3>"
789     |   ^('||' e1=expr e2=expr)
790         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> || <e2>"
791     |   ^('&&' e1=expr e2=expr)
792         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> && <e2>"
793     |   ^(BITWISE_OR e1=expr e2=expr)
794         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> | <e2>"
795     |   ^('^' e1=expr e2=expr)
796         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> ^ <e2>"
797     |   ^('&' e1=expr e2=expr)
798         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> & <e2>"
799     |   ^(EQUALS e1=expr e2=expr)
800         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> == <e2>"
801     |   ^('!=' e1=expr e2=expr)
802         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> != <e2>"
803     |   ^('instanceof' expr type)
804         -> template(t={$text}) "/* instanceof not implemented */ <t>"
805     |   ^('<=' e1=expr e2=expr)
806         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \<= <e2>"
807     |   ^('>=' e1=expr e2=expr)
808         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \>= <e2>"
809     |   ^('>>>' e1=expr e2=expr)
810         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \>\>\> <e2>"
811     |   ^('>>' e1=expr e2=expr)
812         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \>\> <e2>"
813     |   ^('>' e1=expr e2=expr)
814         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \> <e2>"
815     |   ^('<<' e1=expr e2=expr)
816         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \<\< <e2>"
817     |   ^('<' e1=expr e2=expr)
818         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \< <e2>"
819     |   ^('+' e1=expr e2=expr)
820         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> + <e2>"
821     |   ^('-' e1=expr e2=expr)
822         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> - <e2>"
823     |   ^('*' e1=expr e2=expr)
824         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> * <e2>"
825     |   ^('/' e1=expr e2=expr)
826         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> / <e2>"
827     |   ^('%' e1=expr e2=expr)
828         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> % <e2>"
829     |   ^(UNARY_PLUS e1=expr)
830         -> template(e1={$e1.st}) "+<e1>"
831     |   ^(UNARY_MINUS e1=expr)
832         -> template(e1={$e1.st}) "-<e1>"
833     |   ^(PRE_INC e1=expr)
834         -> template(e1={$e1.st}) "++<e1>"
835     |   ^(PRE_DEC e1=expr)
836         -> template(e1={$e1.st}) "--<e1>"
837     |   ^(POST_INC e1=expr)
838         -> template(e1={$e1.st}) "<e1>++"
839     |   ^(POST_DEC e1=expr)
840         -> template(e1={$e1.st}) "<e1>--"
841     |   ^(TILDE e1=expr)
842         -> template(e1={$e1.st}) "~<e1>"
843     |   ^(NOT e1=expr)
844         -> template(e1={$e1.st}) "!<e1>"
845     |   ^(CAST_EXPR ty=type e1=expr)
846         -> template(ty={$ty.st}, e1={$e1.st}) "(<ty>)<e1>"
847     |   primaryExpression
848         -> {$primaryExpression.st}
849     |   ^(POINTER_DEREFERENCE e1 = expr)
850         ->  template(e = {$e1.st}) "*(<e>)"
851     ;
852
853 primaryExpression
854 @init { int dims = 1; }
855     :   ^(DOT prim=primaryExpression
856             ( IDENT   -> template(id={$IDENT.text}, prim={$prim.st}) "<prim>.<id>"
857             | THIS    -> template(prim={$prim.st}) "<prim>.this"
858             | SUPER   -> template(prim={$prim.st}) "<prim>.super"
859             )
860         )
861     |   ^(ARROW prim=primaryExpression
862             ( IDENT   -> template(id={$IDENT.text}, prim={$prim.st}) "<prim>-><id>"
863             | THIS    -> template(prim={$prim.st}) "<prim>->this"
864             | SUPER   -> template(prim={$prim.st}) "<prim>->super"
865             )
866         )
867     |   parenthesizedExpression
868         -> {$parenthesizedExpression.st}
869     |   IDENT
870         -> {%{$IDENT.text}}
871     |   CHELPER
872         -> {%{"constructorHelper"}}
873     |   ^(METHOD_CALL pe=primaryExpression gtal=genericTypeArgumentList? args=arguments)
874         -> method_call(primary={$pe.st}, generic_types={$gtal.st}, args={$args.st})
875     |   ^(ENTRY_METHOD_CALL pe=primaryExpression gtal=genericTypeArgumentList? args=arguments)
876         -> method_call(primary={$pe.st}, generic_types={$gtal.st}, args={$args.st})
877     |   explicitConstructorCall
878         -> {$explicitConstructorCall.st}
879     |   ^(ARRAY_ELEMENT_ACCESS pe=primaryExpression ex=expressionArrayAccess) {
880             if ($pe.start.symbolType != null && $pe.start.symbolType instanceof PointerType) {
881                 PointerType p = (PointerType)($pe.start.symbolType);
882                 if (p.baseType instanceof ClassSymbol) {
883                     ClassSymbol cs = (ClassSymbol)(p.baseType);
884                     if (cs.templateArgs != null && cs.templateArgs.size() > 1 &&
885                         cs.templateArgs.get(1) instanceof LiteralType) {
886                         LiteralType l = (LiteralType)(cs.templateArgs.get(1));
887                         dims = Integer.valueOf(l.literal);
888                     }
889                 }
890             }
891         }
892         -> {$pe.start.symbolType != null && $pe.start.symbolType instanceof PointerType && dims == 1}?
893                template(pe={$pe.st}, ex={$ex.st}) "(*(<pe>))[<ex>]"
894         -> {$pe.start.symbolType != null && $pe.start.symbolType instanceof PointerType && dims == 2}?
895                template(pe={$pe.st}, ex={$ex.st}) "(*(<pe>)).access(<ex>)"
896         -> template(pe={$pe.st}, ex={$ex.st}) "(<pe>)[<ex>]"
897     |   literal
898         -> {$literal.st}
899     |   newExpression[null]
900         -> {$newExpression.st}
901     |   THIS
902         -> {%{$start.getText()}}
903     |   arrayTypeDeclarator
904         -> {$arrayTypeDeclarator.st}
905     |   SUPER
906         -> {%{$start.getText()}}
907     |   GETNUMPES
908         ->  template() "CkNumPes()"
909     |   GETNUMNODES
910         ->  template() "CkNumNodes()"
911     |   GETMYPE
912         ->  template() "CkMyPe()"
913     |   GETMYNODE
914         ->  template() "CkMyNode()"
915     |   GETMYRANK
916         ->  template() "CkMyRank()"
917     |   domainExpression[null]
918         ->  {$domainExpression.st}
919     ;
920     
921 explicitConstructorCall
922     :   ^(THIS_CONSTRUCTOR_CALL genericTypeArgumentList? arguments)
923         -> template(t={$text}) "<t>"
924     |   ^(SUPER_CONSTRUCTOR_CALL primaryExpression? genericTypeArgumentList? arguments)
925         -> template(t={$text}) "<t>"
926     ;
927
928 arrayTypeDeclarator
929     :   ^(ARRAY_DECLARATOR (arrayTypeDeclarator | qualifiedIdentifier | primitiveType))
930         -> template(t={$text}) "<t>"
931     ;
932
933 newExpression[StringTemplate obtype]
934     :   ^(NEW_EXPRESSION arguments? domainExpression[$arguments.args])
935         -> template(domain={$domainExpression.st},type={$obtype}) "new <type>(<domain>)"
936     |   ^(NEW proxyType arguments)
937         -> template(t={$proxyType.st}, a={$arguments.st}) "<t>::ckNew(<a>)"
938     |   ^(NEW nonProxyType arguments)
939         -> template(q={$nonProxyType.st}, a={$arguments.st}) "new <q>(<a>)"
940     ;
941
942 arguments returns [List<StringTemplate> args]
943 @init {
944     $args = new ArrayList<StringTemplate>();
945 }
946     :   ^(ARGUMENT_LIST (e=expression { $args.add($e.st); } )*)        
947         ->  arguments(exprs={$args})
948     ;
949
950 literal
951 @init {
952 $st = %{$start.getText()};
953 }
954     :   HEX_LITERAL
955     |   OCTAL_LITERAL
956     |   DECIMAL_LITERAL
957     |   FLOATING_POINT_LITERAL
958     |   CHARACTER_LITERAL
959     |   STRING_LITERAL
960     |   TRUE
961     |   FALSE
962     |   NULL
963     ;
964