Charj : added support for exit and exitAll (exit and CkExit)
[charm.git] / src / langs / charj / src / charj / translator / CharjEmitter.g
1 /**
2  * ANTLR (v3) Tree Parser for the Charj Language
3  */
4
5 tree grammar CharjEmitter;
6
7 options {
8     backtrack = true; 
9     memoize = true;
10     tokenVocab = Charj;
11     ASTLabelType = CharjAST;
12     output = template;
13 }
14
15
16 @header {
17 package charj.translator;
18 }
19
20
21 @members {
22     SymbolTable symtab = null;
23
24     PackageScope currentPackage = null;
25     ClassSymbol currentClass = null;
26     MethodSymbol currentMethod = null;
27     LocalScope currentLocalScope = null;
28
29     Translator translator_;
30     OutputMode mode_;
31
32     private boolean emitCC() { return mode_ == OutputMode.cc; }
33     private boolean emitCI() { return mode_ == OutputMode.ci; }
34     private boolean emitH() { return mode_ == OutputMode.h; }
35     private boolean debug() { return translator_.debug(); }
36     private String basename() { return translator_.basename(); }
37
38     /**
39      *  Override ANTLR's token mismatch behavior so we throw exceptions early.
40      */
41     protected void mismatch(IntStream input, int ttype, BitSet follow)
42         throws RecognitionException {
43         throw new MismatchedTokenException(ttype, input);
44     }
45
46     /**
47      *  Override ANTLR's set mismatch behavior so we throw exceptions early.
48      */
49     public Object recoverFromMismatchedSet(IntStream input, RecognitionException e, BitSet follow)
50         throws RecognitionException {
51         throw e;
52     }
53
54     /**
55      *  Test a list of CharjAST nodes to see if any of them has the given token
56      *  type.
57      */
58     public boolean listContainsToken(List<CharjAST> list, int tokenType) {
59         if (list == null) return false;
60         for (CharjAST node : list) {
61             if (node.token.getType() == tokenType) {
62                 return true;
63             }
64         }
65         return false;
66     }
67 }
68
69
70 // Replace default ANTLR generated catch clauses with this action, allowing early failure.
71 @rulecatch {
72     catch (RecognitionException re) {
73         reportError(re);
74         throw re;
75     }
76 }
77
78
79 // Starting point for parsing a Charj file.
80 charjSource[SymbolTable symtab, OutputMode m]
81 @init {
82     this.symtab = symtab;
83     this.translator_ = symtab.translator;
84     this.mode_ = m;
85 }
86     :   ^(CHARJ_SOURCE (p=packageDeclaration)? 
87         (i+=importDeclaration)*
88         (r+=readonlyDeclaration)*
89         (t+=typeDeclaration)*)
90         -> {emitCC()}? charjSource_cc(basename={basename()}, pd={$p.names}, imports={$i}, types={$t}, ros={$r}, debug={debug()})
91         -> {emitCI()}? charjSource_ci(basename={basename()}, pd={$p.names}, imports={$i}, types={$t}, ros={$r}, debug={debug()})
92         -> {emitH()}? charjSource_h(basename={basename()}, pd={$p.names}, imports={$i}, types={$t}, ros={$r}, debug={debug()})
93         ->
94     ;
95
96 topLevelDeclaration
97     :   importDeclaration -> {$importDeclaration.st;}
98     |   typeDeclaration -> {$typeDeclaration.st;}
99     ;
100
101 packageDeclaration returns [List names]
102     :   ^('package' (ids+=IDENT)+)
103         {
104             $names = $ids;
105         }
106         ->
107     ;
108
109 readonlyDeclaration
110     :   ^(READONLY lvd=localVariableDeclaration)
111         -> {emitCI()}? template(bn={basename()}, v={$lvd.st}) "readonly <v>"
112         -> {emitH()}? template(v={$lvd.st}) "extern <v>"
113         -> {emitCC()}? {$lvd.st;}
114         ->
115     ;
116     
117 importDeclaration
118 @init {
119     String importID = null;
120 }
121     :   ^('import' qualifiedIdentifier ds='.*'?)
122         {
123             importID = $qualifiedIdentifier.text;
124             if ($ds != null) {
125             }
126         }
127         {$ds == null}? // TODO: add support for importing x.*
128         -> {(emitCC() || emitH())}? importDeclaration_cc_h(
129             inc_id={importID.replace(".","/")},
130             use_id={importID.replace(".","::")})
131         ->
132     ;
133     
134 typeDeclaration
135     :   ^(TYPE CLASS IDENT (^('extends' su=type))? (^('implements' type+))?
136         {
137             currentClass = (ClassSymbol)$IDENT.symbol;
138         }
139         (csds+=classScopeDeclaration)*)
140         -> {emitCC()}? classDeclaration_cc(
141                 sym={currentClass},
142                 ident={$IDENT.text}, 
143                 ext={$su.st}, 
144                 csds={$csds})
145         -> {emitH()}?  classDeclaration_h(
146                 sym={currentClass},
147                 ident={$IDENT.text}, 
148                 ext={$su.st}, 
149                 csds={$csds})
150         ->
151     |   ^(INTERFACE IDENT (^('extends' type+))? interfaceScopeDeclaration*)
152         -> template(t={$text}) "/*INTERFACE-not implemented*/ <t>"
153     |   ^(ENUM IDENT (^('implements' type+))? classScopeDeclaration*)
154         -> template(t={$text}) "/*ENUM-not implemented*/ <t>"
155     |   ^(TYPE chareType IDENT (^('extends' type))? (^('implements' type+))?
156         {
157             currentClass = (ClassSymbol)$IDENT.symbol;
158         }
159         (csds+=classScopeDeclaration)*)
160         -> {emitCC()}? chareDeclaration_cc(
161                 sym={currentClass},
162                 ident={$IDENT.text}, 
163                 ext={$su.st}, 
164                 csds={$csds})
165         -> {emitCI()}? chareDeclaration_ci(
166                 sym={currentClass},
167                 chareType={$chareType.st},
168                 arrayDim={null},
169                 ident={$IDENT.text}, 
170                 ext={$su.st}, 
171                 csds={$csds})
172         -> {emitH()}? chareDeclaration_h(
173                 sym={currentClass},
174                 ident={$IDENT.text}, 
175                 ext={$su.st}, 
176                 csds={$csds})
177         ->
178     ;
179
180 chareType
181 @init {
182 $st = %{$start.getText()};
183 }
184     :   CHARE
185     |   GROUP
186     |   NODEGROUP
187     |   MAINCHARE
188     |   ^(CHARE_ARRAY ARRAY_DIMENSION)
189         -> template(t={$ARRAY_DIMENSION.text}) "array [<t>]"
190     ;
191
192 enumConstant
193     :   ^(IDENT arguments?)
194         -> template(t={$text}) "/*enumConstant-not implemented*/ <t>"
195     ;
196
197 classScopeDeclaration
198 @init
199 {
200     boolean entry = false;
201     boolean migrationCtor = false;
202 }
203     :   ^(FUNCTION_METHOD_DECL m=modifierList? g=genericTypeParameterList? 
204             ty=type IDENT f=formalParameterList a=arrayDeclaratorList? 
205             b=block?)
206         {
207             // determine whether it's an entry method
208             if($m.start != null)
209                 entry = listContainsToken($m.start.getChildren(), CHARJ_MODIFIER_LIST);
210         }
211         -> {emitCC()}? funcMethodDecl_cc(
212                 sym={currentClass},
213                 modl={$m.st}, 
214                 gtpl={$g.st}, 
215                 ty={$ty.st},
216                 id={$IDENT.text}, 
217                 fpl={$f.st}, 
218                 adl={$a.st},
219                 block={$b.st})
220         -> {emitH()}? funcMethodDecl_h(
221                 modl={$m.st}, 
222                 gtpl={$g.st}, 
223                 ty={$ty.st},
224                 id={$IDENT.text}, 
225                 fpl={$f.st}, 
226                 adl={$a.st},
227                 block={$b.st})
228         -> {(emitCI() && entry)}? funcMethodDecl_ci(
229                 modl={$m.st}, 
230                 gtpl={$g.st}, 
231                 ty={$ty.st},
232                 id={$IDENT.text}, 
233                 fpl={$f.st}, 
234                 adl={$a.st},
235                 block={$b.st})
236         ->
237     |   ^(PRIMITIVE_VAR_DECLARATION modifierList? simpleType variableDeclaratorList)
238         -> {emitH()}? class_var_decl(
239             modl={$modifierList.st},
240             type={$simpleType.st},
241             declList={$variableDeclaratorList.st})
242         ->
243     |   ^(OBJECT_VAR_DECLARATION modifierList? objectType variableDeclaratorList)
244         -> {emitH()}? class_var_decl(
245             modl={$modifierList.st},
246             type={$objectType.st},
247             declList={$variableDeclaratorList.st})
248         ->
249     |   ^(CONSTRUCTOR_DECL m=modifierList? g=genericTypeParameterList? IDENT f=formalParameterList b=block)
250         {
251             // determine whether it's an entry method
252             if ($m.start != null) {
253                 entry = listContainsToken($m.start.getChildren(), CHARJ_MODIFIER_LIST);
254             }
255             migrationCtor = currentClass.migrationCtor == $CONSTRUCTOR_DECL;
256         }
257         -> {emitCC()}? ctorDecl_cc(
258                 modl={$m.st},
259                 gtpl={$g.st}, 
260                 id={$IDENT.text}, 
261                 fpl={$f.st}, 
262                 block={$b.st})
263         -> {emitCI() && entry && !migrationCtor}? ctorDecl_ci(
264                 modl={$m.st},
265                 gtpl={$g.st}, 
266                 id={$IDENT.text}, 
267                 fpl={$f.st}, 
268                 block={$b.st})
269         -> {emitH()}? ctorDecl_h(
270                 modl={$m.st},
271                 gtpl={$g.st}, 
272                 id={$IDENT.text}, 
273                 fpl={$f.st}, 
274                 block={$b.st})
275         ->
276     ;
277     
278 interfaceScopeDeclaration
279     :   ^(FUNCTION_METHOD_DECL modifierList? genericTypeParameterList? type IDENT formalParameterList arrayDeclaratorList?)
280         -> template(t={$text}) "/*interfaceScopeDeclarations-not implemented */ <t>"
281     |   ^(PRIMITIVE_VAR_DECLARATION modifierList? simpleType variableDeclaratorList)
282         -> template(t={$text}) "/*interfaceScopeDeclarations-not implemented */ <t>"
283     |   ^(OBJECT_VAR_DECLARATION modifierList? objectType variableDeclaratorList)
284         -> template(t={$text}) "/*interfaceScopeDeclarations-not implemented */ <t>"
285     ;
286
287 variableDeclaratorList
288     :   ^(VAR_DECLARATOR_LIST (var_decls+=variableDeclarator)+)
289         -> var_decl_list(var_decls={$var_decls})
290     ;
291
292 variableDeclarator
293     :   ^(VAR_DECLARATOR id=variableDeclaratorId initializer=variableInitializer?)
294         -> var_decl(id={$id.st}, initializer={$initializer.st})
295     ;
296     
297 variableDeclaratorId
298     :   ^(IDENT adl=arrayDeclaratorList?)
299         -> var_decl_id(id={$IDENT.text}, arrayDeclList={$adl.st})
300     ;
301
302 variableInitializer
303     :   arrayInitializer
304         -> {$arrayInitializer.st}
305     |   expression
306         -> {$expression.st}
307     ;
308
309 arrayDeclaratorList
310     :   ^(ARRAY_DECLARATOR_LIST ARRAY_DECLARATOR*)  
311         -> template(t={$text}) "<t>"
312     ;
313     
314 arrayInitializer
315     :   ^(ARRAY_INITIALIZER variableInitializer*)
316         -> template(t={$text}) "/* arrayInitializer-not implemented */ <t>"
317     ;
318
319 genericTypeParameterList
320     :   ^(GENERIC_TYPE_PARAM_LIST genericTypeParameter+)
321         -> template(t={$text}) "/*GENERIC_TYPE_PARAM_LIST-not implemented*/ <t>"
322     ;
323
324 genericTypeParameter
325     :   ^(IDENT bound?)
326         -> template(t={$text}) "/*genericTypeParameter-not implemented*/ <t>"
327     ;
328         
329 bound
330     :   ^(EXTENDS_BOUND_LIST type+)
331         -> template(t={$text}) "/*EXTENDS_BOUND_LIST-not implemented*/ <t>"
332     ;
333
334 throwsClause
335     :   ^(THROWS_CLAUSE qualifiedIdentifier+)
336         -> template(t={$text}) "/* throwsClause-not implemented */ <t>"
337     ;
338
339 modifierList
340     :   ^(MODIFIER_LIST accessModifierList? localModifierList? charjModifierList? otherModifierList?)
341         ->  {emitCC()}? mod_list_cc(accmods = {$accessModifierList.names}, localmods = {$localModifierList.names}, charjmods = {$charjModifierList.names}, othermods = {$otherModifierList.names})
342         ->  {emitH()}? mod_list_h(accmods = {$accessModifierList.names}, localmods = {$localModifierList.names}, charjmods = {$charjModifierList.names}, othermods = {$otherModifierList.names})
343         ->  {emitCI()}? mod_list_ci(accmods = {$accessModifierList.names}, localmods = {$localModifierList.names}, charjmods = {$charjModifierList.names}, othermods = {$otherModifierList.names})
344         ->
345     ;
346
347 modifier
348     :   accessModifier
349     |   localModifier
350     |   charjModifier
351     |   otherModifier
352     ;
353
354 accessModifierList
355 returns [List names]
356     :   ^(ACCESS_MODIFIER_LIST (m+=accessModifier)+)
357         {
358             $names = $m;
359         }
360     ;
361 localModifierList
362 returns [List names]
363     :   ^(LOCAL_MODIFIER_LIST (m+=localModifier)+)
364         {
365             $names = $m;
366         }
367         ->  local_mod_list(mods = {$names})
368     ;
369
370 charjModifierList
371 returns [List names]
372     :   ^(CHARJ_MODIFIER_LIST (m+=charjModifier)+)
373         {
374             $names = $m;
375         }
376     ;
377
378 otherModifierList
379 returns [List names]
380     :   ^(OTHER_MODIFIER_LIST (m+=otherModifier)+)
381         {
382             $names = $m;
383         }
384     ;
385     
386 localModifier
387 @init
388 {
389     $st = %{$start.getText()};
390 }
391     :   FINAL
392     |   STATIC
393     |   VOLATILE
394     ;
395
396 accessModifier
397 @init
398 {
399     $st = %{$start.getText()};
400 }
401     :   PUBLIC
402     |   PROTECTED
403     |   PRIVATE
404     ;
405
406 charjModifier
407 @init
408 {
409     $st = %{$start.getText()};
410 }
411     :   ENTRY
412     ;
413
414 otherModifier
415 @init
416 {
417     $st = %{$start.getText()};
418 }
419     :   ABSTRACT
420     |   NATIVE
421     ;
422     
423 type
424     :   simpleType
425         -> {$simpleType.st}
426     |   objectType 
427         -> {$objectType.st}
428     |   VOID
429         {
430             $st = %{$start.getText()};
431         }
432     ;
433
434 simpleType
435     :   ^(SIMPLE_TYPE primitiveType arrayDeclaratorList?)
436         -> simple_type(typeID={$primitiveType.st}, arrDeclList={$arrayDeclaratorList.st})
437     ;
438
439 objectType
440     : proxyType -> {$proxyType.st;}
441     | nonProxyType -> {$nonProxyType.st}
442     ;
443
444 nonProxyType
445     :   ^(OBJECT_TYPE qualifiedTypeIdent arrayDeclaratorList?)
446         -> obj_type(typeID={$qualifiedTypeIdent.st}, arrDeclList={$arrayDeclaratorList.st})
447     |   ^(POINTER_TYPE qualifiedTypeIdent arrayDeclaratorList?)
448         -> pointer_type(typeID={$qualifiedTypeIdent.st}, arrDeclList={$arrayDeclaratorList.st})
449     |   ^(REFERENCE_TYPE qualifiedTypeIdent arrayDeclaratorList?)
450         -> reference_type(typeID={$qualifiedTypeIdent.st}, arrDeclList={$arrayDeclaratorList.st})
451     ;
452
453 proxyType
454     :   ^(PROXY_TYPE qualifiedTypeIdent arrayDeclaratorList?)
455         -> proxy_type(typeID={$qualifiedTypeIdent.st}, arrDeclList={$arrayDeclaratorList.st})
456     ;
457
458 qualifiedTypeIdent returns [ClassSymbol type]
459     :   ^(QUALIFIED_TYPE_IDENT (t+=typeIdent)+)
460         {$type = (ClassSymbol)$QUALIFIED_TYPE_IDENT.symbol;}
461         -> template(types={$t}) "<types; separator=\"::\">"
462     ;
463
464 typeIdent
465     :   ^(IDENT genericTypeArgumentList?)
466         -> typeIdent(typeID={$IDENT.text}, generics={$genericTypeArgumentList.st})
467     ;
468
469 primitiveType
470 @init {
471 $st = %{$start.getText()};
472 }
473     :   BOOLEAN
474         -> template() "bool"
475     |   CHAR
476     |   BYTE
477         -> template() "char"
478     |   SHORT
479     |   INT
480     |   LONG
481     |   FLOAT
482     |   DOUBLE
483     ;
484
485 genericTypeArgumentList
486     :   ^(GENERIC_TYPE_ARG_LIST (gta+=genericTypeArgument)+)
487         -> template(gtal={$gta}) "\<<gtal; separator=\", \">\>"
488     ;
489     
490 genericTypeArgument
491     :   type
492         -> {$type.st}
493     |   '?'
494         -> template(t={$text}) "/* genericTypeArgument: wildcard bound types not implemented */ <t>"
495     ;
496
497 formalParameterList
498     :   ^(FORMAL_PARAM_LIST (fpsd+=formalParameterStandardDecl)* fpvd=formalParameterVarargDecl?)
499         -> formal_param_list(sdecl={$fpsd}, vdecl={$fpvd.st})
500     ;
501     
502 formalParameterStandardDecl
503     :   ^(FORMAL_PARAM_STD_DECL lms=localModifierList? t=type vdid=variableDeclaratorId)
504         -> formal_param_decl(modList={$lms.st}, type={$t.st}, declID={$vdid.st})
505     ;
506     
507 formalParameterVarargDecl
508     :   ^(FORMAL_PARAM_VARARG_DECL localModifierList? type variableDeclaratorId)
509         -> template(t={$text}) "/*formal parameter varargs not implemented*/ <t>"
510     ;
511     
512 qualifiedIdentifier
513     :   IDENT
514         -> template(t={$text}) "<t>"
515     |   ^(DOT qualifiedIdentifier IDENT)
516         -> template(t={$text}) "<t>"
517     ;
518     
519 block
520 @init { boolean emptyBlock = true; }
521     :   ^(BLOCK (b+=blockStatement)*)
522         { emptyBlock = ($b == null || $b.size() == 0); }
523         -> {emitCC() && emptyBlock}? template(bsl={$b}) "{ }"
524         -> {emitCC()}? block_cc(bsl={$b})
525         ->
526     ;
527     
528 blockStatement
529     :   localVariableDeclaration
530         -> {$localVariableDeclaration.st}
531     |   statement
532         -> {$statement.st}
533     ;
534
535
536 localVariableDeclaration
537     :   ^(PRIMITIVE_VAR_DECLARATION localModifierList? simpleType variableDeclaratorList)
538         -> local_var_decl(
539             modList={$localModifierList.st},
540             type={$simpleType.st},
541             declList={$variableDeclaratorList.st})
542     |   ^(OBJECT_VAR_DECLARATION localModifierList? objectType variableDeclaratorList)
543         -> local_var_decl(
544             modList={$localModifierList.st},
545             type={$objectType.st},
546             declList={$variableDeclaratorList.st})
547     ;
548
549
550 statement
551     :   nonBlockStatement
552         -> {$nonBlockStatement.st}
553     |   block
554         -> {$block.st}
555     ;
556
557 nonBlockStatement
558     :   ^(ASSERT cond=expression msg=expression?)
559         -> assert(cond={$cond.st}, msg={$msg.st})
560     |   ^(IF parenthesizedExpression then=block else_=block?)
561         -> if(cond={$parenthesizedExpression.st}, then={$then.st}, else_={$else_.st})
562     |   ^(FOR forInit? FOR_EXPR cond=expression? FOR_UPDATE (update+=expression)* b=block)
563         -> for(initializer={$forInit.st}, cond={$cond.st}, update={$update}, body={$block.st})
564     |   ^(FOR_EACH localModifierList? type IDENT expression block) 
565         -> template(t={$text}) "/* foreach not implemented */ <t>"
566     |   ^(WHILE pe=parenthesizedExpression b=block)
567         -> while(cond={$pe.st}, body={$b.st})
568     |   ^(DO b=block pe=parenthesizedExpression)
569         -> dowhile(cond={$pe.st}, block={$b.st})
570     |   ^(SWITCH pe=parenthesizedExpression (scls+=switchCaseLabel)*)
571         -> switch(expr={$pe.st}, labels={$scls})
572     |   ^(RETURN e=expression?)
573         -> return(val={$e.st})
574     |   ^(THROW expression)
575         -> template(t={$text}) "/* throw not implemented */ <t>"
576     |   ^(BREAK IDENT?)
577         -> template() "break;" // TODO: support labeling
578     |   ^(CONTINUE IDENT?)
579         -> template() "continue;" // TODO: support labeling
580     |   ^(LABELED_STATEMENT i=IDENT s=statement)
581         -> label(text={$i.text}, stmt={$s.st})
582     |   expression
583         -> template(expr={$expression.st}) "<expr>;"
584     |   ^('delete' qualifiedIdentifier)
585         -> template(t={$qualifiedIdentifier.st}) "delete <t>;"
586     |   ^('embed' STRING_LITERAL EMBED_BLOCK)
587         ->  embed_cc(str={$STRING_LITERAL.text}, blk={$EMBED_BLOCK.text})
588     |   ';' // Empty statement.
589         -> {%{$start.getText()}}
590     |   ^(PRINT (exprs += expression)*)
591         ->  print(exprs = {$exprs})
592     |   ^(PRINTLN (exprs += expression)*)
593         ->  println(exprs = {$exprs})
594     |   ^(EXIT expression?)
595         ->  exit(expr = {$expression.st})
596     |   EXITALL
597         ->  exitall()
598     ;
599         
600 switchCaseLabel
601     :   ^(CASE expression (b+=blockStatement)*)
602         -> case(expr={$expression.st}, block={$b})
603     |   ^(DEFAULT (b+=blockStatement)*)
604         -> template(block={$b}) "default: <block>"
605     ;
606     
607 forInit
608     :   localVariableDeclaration
609         -> template(lvd={$localVariableDeclaration.st}) "<lvd>"
610     |   (ex+=expression)+
611         -> template(ex={$ex}) "<ex; separator=\", \">"
612     ;
613
614 // EXPRESSIONS
615
616 parenthesizedExpression
617     :   ^(PAREN_EXPR exp=expression)
618         -> template(expr={$exp.st}) "(<expr>)"
619     ;
620     
621 expression
622     :   ^(EXPR expr)
623         -> {$expr.st}
624     ;
625
626 expr
627     :   ^(ASSIGNMENT e1=expr e2=expr)
628         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> = <e2>"
629     |   ^('+=' e1=expr e2=expr)
630         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> += <e2>"
631     |   ^('-=' e1=expr e2=expr)
632         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> -= <e2>"
633     |   ^('*=' e1=expr e2=expr)
634         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> *= <e2>"
635     |   ^('/=' e1=expr e2=expr)
636         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> /= <e2>"
637     |   ^('&=' e1=expr e2=expr)
638         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> &= <e2>"
639     |   ^('|=' e1=expr e2=expr)
640         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> |= <e2>"
641     |   ^('^=' e1=expr e2=expr)
642         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> ^= <e2>"
643     |   ^('%=' e1=expr e2=expr)
644         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> %= <e2>"
645     |   ^('>>>=' e1=expr e2=expr)
646         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \>\>\>= <e2>"
647     |   ^('>>=' e1=expr e2=expr)
648         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \>\>= <e2>"
649     |   ^('<<=' e1=expr e2=expr)
650         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \<\<= <e2>"
651     |   ^('?' e1=expr e2=expr e3=expr)
652         -> template(e1={$e1.st}, e2={$e2.st}, e3={$e3.st}) "<e1> ? <e2> : <e3>"
653     |   ^('||' e1=expr e2=expr)
654         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> || <e2>"
655     |   ^('&&' e1=expr e2=expr)
656         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> && <e2>"
657     |   ^(BITWISE_OR e1=expr e2=expr)
658         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> | <e2>"
659     |   ^('^' e1=expr e2=expr)
660         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> ^ <e2>"
661     |   ^('&' e1=expr e2=expr)
662         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> & <e2>"
663     |   ^(EQUALS e1=expr e2=expr)
664         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> == <e2>"
665     |   ^('!=' e1=expr e2=expr)
666         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> != <e2>"
667     |   ^('instanceof' expr type)
668         -> template(t={$text}) "/* instanceof not implemented */ <t>"
669     |   ^('<=' e1=expr e2=expr)
670         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \<= <e2>"
671     |   ^('>=' e1=expr e2=expr)
672         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \>= <e2>"
673     |   ^('>>>' e1=expr e2=expr)
674         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \>\>\> <e2>"
675     |   ^('>>' e1=expr e2=expr)
676         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \>\> <e2>"
677     |   ^('>' e1=expr e2=expr)
678         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \> <e2>"
679     |   ^('<<' e1=expr e2=expr)
680         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \<\< <e2>"
681     |   ^('<' e1=expr e2=expr)
682         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \< <e2>"
683     |   ^('+' e1=expr e2=expr)
684         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> + <e2>"
685     |   ^('-' e1=expr e2=expr)
686         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> - <e2>"
687     |   ^('*' e1=expr e2=expr)
688         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> * <e2>"
689     |   ^('/' e1=expr e2=expr)
690         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> / <e2>"
691     |   ^('%' e1=expr e2=expr)
692         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> % <e2>"
693     |   ^(UNARY_PLUS e1=expr)
694         -> template(e1={$e1.st}) "+<e1>"
695     |   ^(UNARY_MINUS e1=expr)
696         -> template(e1={$e1.st}) "-<e1>"
697     |   ^(PRE_INC e1=expr)
698         -> template(e1={$e1.st}) "++<e1>"
699     |   ^(PRE_DEC e1=expr)
700         -> template(e1={$e1.st}) "--<e1>"
701     |   ^(POST_INC e1=expr)
702         -> template(e1={$e1.st}) "<e1>++"
703     |   ^(POST_DEC e1=expr)
704         -> template(e1={$e1.st}) "<e1>--"
705     |   ^(TILDE e1=expr)
706         -> template(e1={$e1.st}) "~<e1>"
707     |   ^(NOT e1=expr)
708         -> template(e1={$e1.st}) "!<e1>"
709     |   ^(CAST_EXPR ty=type e1=expr)
710         -> template(ty={$ty.st}, e1={$e1.st}) "(<ty>)<e1>"
711     |   primaryExpression
712         -> {$primaryExpression.st}
713     ;
714
715 primaryExpression
716     :   ^(DOT prim=primaryExpression
717             ( IDENT   -> template(id={$IDENT}, prim={$prim.st}) "<prim>.<id>"
718             | THIS    -> template(prim={$prim.st}) "<prim>.this"
719             | SUPER   -> template(prim={$prim.st}) "<prim>.super"
720             )
721         )
722     |   ^(ARROW prim=primaryExpression
723             ( IDENT   -> template(id={$IDENT}, prim={$prim.st}) "<prim>-><id>"
724             | THIS    -> template(prim={$prim.st}) "<prim>->this"
725             | SUPER   -> template(prim={$prim.st}) "<prim>->super"
726             )
727         )
728     |   parenthesizedExpression
729         -> {$parenthesizedExpression.st}
730     |   IDENT
731         -> {%{$start.getText()}}
732     |   ^(METHOD_CALL pe=primaryExpression gtal=genericTypeArgumentList? args=arguments)
733         -> method_call(primary={$pe.st}, generic_types={$gtal.st}, args={$args.st})
734     |   ^(ENTRY_METHOD_CALL pe=primaryExpression gtal=genericTypeArgumentList? args=arguments)
735         -> method_call(primary={$pe.st}, generic_types={$gtal.st}, args={$args.st})
736     |   explicitConstructorCall
737         -> {$explicitConstructorCall.st}
738     |   ^(ARRAY_ELEMENT_ACCESS pe=primaryExpression ex=expression)
739         -> template(pe={$pe.st}, ex={$ex.st}) "<pe>[<ex>]"
740     |   literal
741         -> {$literal.st}
742     |   newExpression
743         -> {$newExpression.st}
744     |   THIS
745         -> {%{$start.getText()}}
746     |   arrayTypeDeclarator
747         -> {$arrayTypeDeclarator.st}
748     |   SUPER
749         -> {%{$start.getText()}}
750     ;
751     
752 explicitConstructorCall
753     :   ^(THIS_CONSTRUCTOR_CALL genericTypeArgumentList? arguments)
754         -> template(t={$text}) "<t>"
755     |   ^(SUPER_CONSTRUCTOR_CALL primaryExpression? genericTypeArgumentList? arguments)
756         -> template(t={$text}) "<t>"
757     ;
758
759 arrayTypeDeclarator
760     :   ^(ARRAY_DECLARATOR (arrayTypeDeclarator | qualifiedIdentifier | primitiveType))
761         -> template(t={$text}) "<t>"
762     ;
763
764 newExpression
765     :   ^(  STATIC_ARRAY_CREATOR
766             (   primitiveType newArrayConstruction
767             |   genericTypeArgumentList? qualifiedTypeIdent newArrayConstruction
768             )
769         )
770         -> template(t={$text}) "<t>"
771     |   ^(NEW proxyType arguments)
772         -> template(t={$proxyType.st}, a={$arguments.st}) "<t>::ckNew(<a>)"
773     |   ^(NEW nonProxyType arguments)
774         -> template(q={$nonProxyType.st}, a={$arguments.st}) "new <q>(<a>)"
775     ;
776
777 newArrayConstruction
778     :   arrayDeclaratorList arrayInitializer
779         -> array_construction_with_init(
780                 array_decls={$arrayDeclaratorList.st},
781                 initializer={$arrayInitializer.st})
782     |   (ex+=expression)+ adl=arrayDeclaratorList?
783         -> array_construction(exprs={$ex}, array_decls={$adl.st})
784     ;
785
786 arguments
787     :   ^(ARGUMENT_LIST (ex+=expression)*)
788         -> arguments(exprs={$ex})
789     ;
790
791 literal
792 @init {
793 $st = %{$start.getText()};
794 }
795     :   HEX_LITERAL
796     |   OCTAL_LITERAL
797     |   DECIMAL_LITERAL
798     |   FLOATING_POINT_LITERAL
799     |   CHARACTER_LITERAL
800     |   STRING_LITERAL
801     |   TRUE
802     |   FALSE
803     |   NULL
804     ;
805