0f8562f059fff402e316f9ed8f9946040474a17c
[charm.git] / src / langs / charj / src / charj / translator / CharjEmitter.g
1 /**
2  * ANTLR (v3) Tree Parser for the Charj Language
3  */
4
5 tree grammar CharjEmitter;
6
7 options {
8     backtrack = true; 
9     memoize = true;
10     tokenVocab = Charj;
11     ASTLabelType = CharjAST;
12     output = template;
13 }
14
15
16 @header {
17 package charj.translator;
18 }
19
20
21 @members {
22     SymbolTable symtab = null;
23
24     PackageScope currentPackage = null;
25     ClassSymbol currentClass = null;
26     MethodSymbol currentMethod = null;
27     LocalScope currentLocalScope = null;
28
29     Translator translator_;
30     OutputMode mode_;
31
32     private boolean emitCC() { return mode_ == OutputMode.cc; }
33     private boolean emitCI() { return mode_ == OutputMode.ci; }
34     private boolean emitH() { return mode_ == OutputMode.h; }
35     private boolean debug() { return translator_.debug(); }
36     private String basename() { return translator_.basename(); }
37
38     /**
39      *  Override ANTLR's token mismatch behavior so we throw exceptions early.
40      */
41     protected void mismatch(IntStream input, int ttype, BitSet follow)
42         throws RecognitionException {
43         throw new MismatchedTokenException(ttype, input);
44     }
45
46     /**
47      *  Override ANTLR's set mismatch behavior so we throw exceptions early.
48      */
49     public Object recoverFromMismatchedSet(IntStream input, RecognitionException e, BitSet follow)
50         throws RecognitionException {
51         throw e;
52     }
53
54     /**
55      *  Test a list of CharjAST nodes to see if any of them has the given token
56      *  type.
57      */
58     public boolean listContainsToken(List<CharjAST> list, int tokenType) {
59         if (list == null) return false;
60         for (CharjAST node : list) {
61             if (node.token.getType() == tokenType) {
62                 return true;
63             }
64         }
65         return false;
66     }
67 }
68
69
70 // Replace default ANTLR generated catch clauses with this action, allowing early failure.
71 @rulecatch {
72     catch (RecognitionException re) {
73         reportError(re);
74         throw re;
75     }
76 }
77
78
79 // Starting point for parsing a Charj file.
80 charjSource[SymbolTable symtab, OutputMode m]
81 @init {
82     this.symtab = symtab;
83     this.translator_ = symtab.translator;
84     this.mode_ = m;
85 }
86     :   ^(CHARJ_SOURCE (p=packageDeclaration)? 
87         (i+=importDeclaration)*
88         (r+=readonlyDeclaration)*
89         (t+=typeDeclaration)*)
90         -> {emitCC()}? charjSource_cc(basename={basename()}, pd={$p.names}, imports={$i}, types={$t}, ros={$r}, debug={debug()})
91         -> {emitCI()}? charjSource_ci(basename={basename()}, pd={$p.names}, imports={$i}, types={$t}, ros={$r}, debug={debug()})
92         -> {emitH()}? charjSource_h(basename={basename()}, pd={$p.names}, imports={$i}, types={$t}, ros={$r}, debug={debug()})
93         ->
94     ;
95
96 topLevelDeclaration
97     :   importDeclaration -> {$importDeclaration.st;}
98     |   typeDeclaration -> {$typeDeclaration.st;}
99     ;
100
101 packageDeclaration returns [List names]
102     :   ^('package' (ids+=IDENT)+)
103         {
104             $names = $ids;
105         }
106         ->
107     ;
108
109 readonlyDeclaration
110     :   ^(READONLY lvd=localVariableDeclaration)
111         -> {emitCI()}? template(bn={basename()}, v={$lvd.st}) "readonly <v>"
112         -> {emitH()}? template(v={$lvd.st}) "extern <v>"
113         -> {emitCC()}? {$lvd.st;}
114         ->
115     ;
116     
117 importDeclaration
118 @init {
119     String importID = null;
120 }
121     :   ^('import' qualifiedIdentifier ds='.*'?)
122         {
123             importID = $qualifiedIdentifier.text;
124             if ($ds != null) {
125             }
126         }
127         {$ds == null}? // TODO: add support for importing x.*
128         -> {(emitCC() || emitH())}? importDeclaration_cc_h(
129             inc_id={importID.replace(".","/")},
130             use_id={importID.replace(".","::")})
131         ->
132     ;
133     
134 typeDeclaration
135 @init {
136     boolean needsMigration = false;
137     List<String> inits = new ArrayList<String>();
138     List<String> pupInits = new ArrayList<String>();
139 }
140     :   ^(TYPE CLASS IDENT (^('extends' su=type))? (^('implements' type+))?
141         {
142             currentClass = (ClassSymbol)$IDENT.def;
143
144             inits = currentClass.generateInits(currentClass.initializers);
145         }
146         (csds+=classScopeDeclaration)*)
147         -> {emitCC()}? classDeclaration_cc(
148                 sym={currentClass},
149                 ident={$IDENT.text}, 
150                 ext={$su.st}, 
151                 csds={$csds},
152                 inits={inits})
153         -> {emitH()}?  classDeclaration_h(
154                 sym={currentClass},
155                 ident={$IDENT.text}, 
156                 ext={$su.st}, 
157                 csds={$csds})
158         ->
159     |   ^('template' (i0+=IDENT*) ^('class' i1=IDENT (^('extends' su=type))? (^('implements' type+))? (csds+=classScopeDeclaration)*))
160         -> {emitH()}? templateDeclaration_h(
161             tident={$i0},
162             ident={$i1.text},
163             ext={$su.st},
164             csds={$csds})
165         -> 
166     |   ^(INTERFACE IDENT (^('extends' type+))? interfaceScopeDeclaration*)
167         -> template(t={$text}) "/*INTERFACE-not implemented*/ <t>"
168     |   ^(ENUM IDENT (^('implements' type+))? classScopeDeclaration*)
169         -> template(t={$text}) "/*ENUM-not implemented*/ <t>"
170     |   ^(TYPE chareType IDENT (^('extends' type))? (^('implements' type+))?
171         {
172             currentClass = (ClassSymbol)$IDENT.def;
173             needsMigration = currentClass.isChareArray && !currentClass.hasMigrationCtor;
174
175             inits = currentClass.generateInits(currentClass.initializers);
176             pupInits = currentClass.generateInits(currentClass.pupInitializers);
177         }
178         (csds+=classScopeDeclaration)*)
179         -> {emitCC()}? chareDeclaration_cc(
180                 sym={currentClass},
181                 ident={$IDENT.text}, 
182                 ext={$su.st}, 
183                 csds={$csds},
184                 pupInits={pupInits},
185                 pupers={currentClass.generatePUPers()},
186                 needsMigration={needsMigration},
187                 inits={inits})
188         -> {emitCI()}? chareDeclaration_ci(
189                 basename={basename()},
190                 sym={currentClass},
191                 chareType={$chareType.st},
192                 arrayDim={null},
193                 ident={$IDENT.text}, 
194                 ext={$su.st}, 
195                 csds={$csds})
196         -> {emitH()}? chareDeclaration_h(
197                 sym={currentClass},
198                 ident={$IDENT.text}, 
199                 ext={$su.st}, 
200                 csds={$csds},
201                 needsPupInit={pupInits.size() > 0},
202                 needsMigration={needsMigration})
203         ->
204     ;
205
206 chareType
207 @init {
208 $st = %{$start.getText()};
209 }
210     :   CHARE
211     |   GROUP
212     |   NODEGROUP
213     |   MAINCHARE
214     |   ^(CHARE_ARRAY ARRAY_DIMENSION)
215         -> template(t={$ARRAY_DIMENSION.text}) "array [<t>]"
216     ;
217
218 enumConstant
219     :   ^(IDENT arguments?)
220         -> template(t={$text}) "/*enumConstant-not implemented*/ <t>"
221     ;
222
223 classScopeDeclaration
224 @init
225 {
226     boolean entry = false;
227     boolean migrationCtor = false;
228     boolean sdagMethod = false;
229 }
230     :   ^(FUNCTION_METHOD_DECL m=modifierList? g=genericTypeParameterList? 
231             ty=type IDENT f=formalParameterList
232             { currentMethod = (MethodSymbol)$IDENT.def; }
233             b=block?)
234         -> {emitCC()}? funcMethodDecl_cc(
235                 classSym={currentClass},
236                 methodSym={currentMethod},
237                 modl={$m.st}, 
238                 gtpl={$g.st}, 
239                 ty={$ty.st},
240                 id={$IDENT.text}, 
241                 fpl={$f.st}, 
242                 block={$b.st})
243         -> {emitH()}? funcMethodDecl_h(
244                 modl={$m.st}, 
245                 gtpl={$g.st}, 
246                 ty={$ty.st},
247                 id={$IDENT.text}, 
248                 fpl={$f.st}, 
249                 block={$b.st})
250         -> {emitCI()}? // do nothing, since it's not an entry method
251         ->
252     |   ^(ENTRY_FUNCTION_DECL m=modifierList? g=genericTypeParameterList? 
253             ty=type IDENT f=formalParameterList a=domainExpression[null]? 
254             {
255                 currentMethod = (MethodSymbol)$IDENT.def;
256                 sdagMethod = currentMethod.hasSDAG;
257             }
258             b=block?) 
259         -> {emitCC() && !sdagMethod}? funcMethodDecl_cc(
260                 classSym={currentClass},
261                 methodSym={currentMethod},
262                 modl={$m.st}, 
263                 gtpl={$g.st}, 
264                 ty={$ty.st},
265                 id={$IDENT.text}, 
266                 fpl={$f.st}, 
267                 adl={$a.st},
268                 block={$b.st})
269         -> {emitH() && !sdagMethod}? funcMethodDecl_h(
270                 modl={$m.st}, 
271                 gtpl={$g.st}, 
272                 ty={$ty.st},
273                 id={$IDENT.text}, 
274                 fpl={$f.st}, 
275                 adl={$a.st},
276                 block={$b.st})
277         -> {emitCI() && sdagMethod}? funcMethodDecl_sdag_ci(
278                 classSym={currentClass},
279                 methodSym={currentMethod},
280                 modl={$m.st}, 
281                 gtpl={$g.st}, 
282                 ty={$ty.st},
283                 id={$IDENT.text}, 
284                 fpl={$f.st}, 
285                 adl={$a.st},
286                 block={$b.st})
287         -> {emitCI() && !sdagMethod}? funcMethodDecl_ci(
288                 modl={$m.st}, 
289                 gtpl={$g.st}, 
290                 ty={$ty.st},
291                 id={$IDENT.text}, 
292                 fpl={$f.st}, 
293                 block={$b.st})
294         ->
295     |   ^(DIVCON_METHOD_DECL modifierList? type IDENT formalParameterList divconBlock)
296     |   ^(PRIMITIVE_VAR_DECLARATION modifierList? simpleType variableDeclaratorList[null])
297         -> {emitH()}? class_var_decl(
298             modl={$modifierList.st},
299             type={$simpleType.st},
300             declList={$variableDeclaratorList.st})
301         ->
302     |   ^(OBJECT_VAR_DECLARATION modifierList? objectType variableDeclaratorList[$objectType.st])
303         -> {emitH()}? class_var_decl(
304             modl={$modifierList.st},
305             type={$objectType.st},
306             declList={$variableDeclaratorList.st})
307         ->
308     |   ^(CONSTRUCTOR_DECL m=modifierList? g=genericTypeParameterList? IDENT f=formalParameterList
309             {
310                 currentMethod = (MethodSymbol)$IDENT.def;
311             }
312             b=block)
313         -> {emitCC()}? ctorDecl_cc(
314                 modl={$m.st},
315                 gtpl={$g.st}, 
316                 id={$IDENT.text}, 
317                 fpl={$f.st}, 
318                 block={$b.st})
319         -> {emitCI()}? // do nothing, it's not an entry constructor
320         -> {emitH()}? ctorDecl_h(
321                 modl={$m.st},
322                 gtpl={$g.st}, 
323                 id={$IDENT.text}, 
324                 fpl={$f.st}, 
325                 block={$b.st})
326         ->
327     |   ^(ENTRY_CONSTRUCTOR_DECL m=modifierList? g=genericTypeParameterList? IDENT f=formalParameterList
328             {
329                 currentMethod = (MethodSymbol)$IDENT.def;
330                 migrationCtor = currentClass.migrationCtor == $ENTRY_CONSTRUCTOR_DECL;
331             }
332             b=block)
333
334         -> {emitCC()}? ctorDecl_cc(
335                 modl={$m.st},
336                 gtpl={$g.st}, 
337                 id={$IDENT.text}, 
338                 fpl={$f.st}, 
339                 block={$b.st})
340         -> {emitCI() && !migrationCtor}? ctorDecl_ci(
341                 modl={$m.st},
342                 gtpl={$g.st}, 
343                 id={$IDENT.text}, 
344                 fpl={$f.st}, 
345                 block={$b.st})
346         -> {emitH()}? ctorDecl_h(
347                 modl={$m.st},
348                 gtpl={$g.st}, 
349                 id={$IDENT.text}, 
350                 fpl={$f.st}, 
351                 block={$b.st})
352         ->
353     ;
354     
355 interfaceScopeDeclaration
356     :   ^(FUNCTION_METHOD_DECL modifierList? genericTypeParameterList? type IDENT formalParameterList)
357         -> template(t={$text}) "/*interfaceScopeDeclarations-not implemented */ <t>"
358     |   ^(PRIMITIVE_VAR_DECLARATION modifierList? simpleType variableDeclaratorList[$simpleType.st])
359         -> template(t={$text}) "/*interfaceScopeDeclarations-not implemented */ <t>"
360     |   ^(OBJECT_VAR_DECLARATION modifierList? objectType variableDeclaratorList[$objectType.st])
361         -> template(t={$text}) "/*interfaceScopeDeclarations-not implemented */ <t>"
362     ;
363
364 variableDeclaratorList[StringTemplate obtype]
365     :   ^(VAR_DECLARATOR_LIST (var_decls+=variableDeclarator[obtype])+ )
366         -> var_decl_list(var_decls={$var_decls})
367     ;
368
369 variableDeclarator[StringTemplate obtype]
370     :   ^(VAR_DECLARATOR id=variableDeclaratorId initializer=variableInitializer[obtype]?)
371         -> {emitCC()}? var_decl_cc(id={$id.st}, initializer={$initializer.st})
372         -> {emitH()}?  var_decl_h(id={$id.st}, initializer={$initializer.st})
373         -> {emitCI()}? var_decl_ci(id={$id.st}, initializer={$initializer.st})
374         ->
375     ; 
376     
377 variableDeclaratorId
378     :   ^(IDENT de=domainExpression[null]?)
379         -> var_decl_id(id={$IDENT.text}, domainExp={$de.st})
380     ;
381
382 variableInitializer[StringTemplate obtype]
383     :   arrayInitializer
384         -> {$arrayInitializer.st}
385     |   newExpression[obtype]
386         -> {$newExpression.st}
387     |   expression
388         -> {$expression.st}
389     ;
390
391 rangeItem
392     :   dl=DECIMAL_LITERAL
393         -> template(t={$dl.text}) "<t>"
394     |   IDENT
395         -> template(t={$IDENT.text}) "<t>"
396     ;
397
398 rangeExpression
399     :   ^(RANGE_EXPRESSION (ri+=rangeItem)*)
400         -> template(t={$ri}) "Range(<t; separator=\",\">)"
401     ;
402
403 rangeList returns [int len]
404     :   (r+=rangeExpression)*
405         { $len = $r.size(); }
406         -> template(t={$r}) "<t; separator=\", \">"
407     ;
408
409 domainExpression[List<StringTemplate> otherParams]
410     :   ^(DOMAIN_EXPRESSION rl=rangeList)
411         -> range_constructor(range={$rl.st}, others={$otherParams}, len={$rl.len})
412     ;
413
414 domainExpressionAccess
415     :   ^(DOMAIN_EXPRESSION rl=rangeListAccess)
416         -> template(t={$rangeListAccess.st}) "<t>"
417     ;
418
419 rangeListAccess
420     :   (r+=rangeExpressionAccess)*
421         -> template(t={$r}) "<t; separator=\", \">"
422     ;
423
424 rangeExpressionAccess
425     :   ^(RANGE_EXPRESSION (ri+=rangeItem)*)
426         -> template(t={$ri}) "<t; separator=\",\">"
427     ;
428
429 arrayInitializer
430     :   ^(ARRAY_INITIALIZER variableInitializer[null]*)
431         -> template(t={$text}) "/* arrayInitializer-not implemented */ <t>"
432     ;
433
434 genericTypeParameterList
435     :   ^(GENERIC_TYPE_PARAM_LIST genericTypeParameter+)
436         -> template(t={$text}) "/*GENERIC_TYPE_PARAM_LIST-not implemented*/ <t>"
437     ;
438
439 genericTypeParameter
440     :   ^(IDENT bound?)
441         -> template(t={$text}) "/*genericTypeParameter-not implemented*/ <t>"
442     ;
443         
444 bound
445     :   ^(EXTENDS_BOUND_LIST type+)
446         -> template(t={$text}) "/*EXTENDS_BOUND_LIST-not implemented*/ <t>"
447     ;
448
449 throwsClause
450     :   ^(THROWS_CLAUSE qualifiedIdentifier+)
451         -> template(t={$text}) "/* throwsClause-not implemented */ <t>"
452     ;
453
454 modifierList
455     :   ^(MODIFIER_LIST accessModifierList localModifierList charjModifierList otherModifierList)
456         ->  {emitCC()}? mod_list_cc(accmods = {$accessModifierList.names}, localmods = {$localModifierList.names}, charjmods = {$charjModifierList.names}, othermods = {$otherModifierList.names})
457         ->  {emitH()}? mod_list_h(accmods = {$accessModifierList.names}, localmods = {$localModifierList.names}, charjmods = {$charjModifierList.names}, othermods = {$otherModifierList.names})
458         ->  {emitCI()}? mod_list_ci(accmods = {$accessModifierList.names}, localmods = {$localModifierList.names}, charjmods = {$charjModifierList.names}, othermods = {$otherModifierList.names})
459         ->
460     ;
461
462 modifier
463     :   accessModifier
464     |   localModifier
465     |   charjModifier
466     |   otherModifier
467     ;
468
469 accessModifierList
470 returns [List names]
471     :   ^(ACCESS_MODIFIER_LIST (m+=accessModifier)*)
472         {
473             $names = $m;
474         }
475     ;
476 localModifierList
477 returns [List names]
478     :   ^(LOCAL_MODIFIER_LIST (m+=localModifier)*)
479         {
480             $names = $m;
481         }
482         ->  local_mod_list(mods = {$names})
483     ;
484
485 charjModifierList
486 returns [List names]
487     :   ^(CHARJ_MODIFIER_LIST (m+=charjModifier)*)
488         {
489             $names = $m;
490         }
491     ;
492
493 otherModifierList
494 returns [List names]
495     :   ^(OTHER_MODIFIER_LIST (m+=otherModifier)*)
496         {
497             $names = $m;
498         }
499     ;
500     
501 localModifier
502 @init
503 {
504     $st = %{$start.getText()};
505 }
506     :   FINAL
507     |   STATIC
508     |   VOLATILE
509     ;
510
511 accessModifier
512 @init
513 {
514     $st = %{$start.getText()};
515 }
516     :   PUBLIC
517     |   PROTECTED
518     |   PRIVATE
519         {
520             $st = %{"private"};
521         }
522     ;
523
524 charjModifier
525     :   ENTRY -> {%{$ENTRY.text}}
526     |   SDAGENTRY -> template() "entry"
527     |   TRACED
528     ;
529
530 otherModifier
531 @init
532 {
533     $st = %{$start.getText()};
534 }
535     :   ABSTRACT
536     |   NATIVE
537     ;
538     
539 type
540     :   simpleType
541         -> {$simpleType.st}
542     |   objectType 
543         -> {$objectType.st}
544     |   VOID
545         {
546             $st = %{"void"};
547         }
548     ;
549
550 simpleType
551     :   ^(SIMPLE_TYPE primitiveType domainExpression[null]?)
552         -> simple_type(typeID={$primitiveType.st}, arrDeclList={$domainExpression.st})
553     ;
554
555 objectType //[boolean forNewExpression]
556     : proxyType -> {$proxyType.st;}
557     | nonProxyType -> {$nonProxyType.st}
558     ;
559
560 nonProxyType
561     :   ^(OBJECT_TYPE qualifiedTypeIdent domainExpression[null]?)
562         -> obj_type(typeID={$qualifiedTypeIdent.st}, arrDeclList={$domainExpression.st})
563     |   ^(POINTER_TYPE qualifiedTypeIdent domainExpression[null]?)
564         -> pointer_type(typeID={$qualifiedTypeIdent.st}, arrDeclList={$domainExpression.st})
565     |   ^(REFERENCE_TYPE qualifiedTypeIdent domainExpression[null]?)
566         -> reference_type(typeID={$qualifiedTypeIdent.st}, arrDeclList={$domainExpression.st})
567     ;
568
569 proxyType
570     :   ^(PROXY_TYPE qualifiedTypeIdent domainExpression[null]?)
571         -> proxy_type(typeID={$qualifiedTypeIdent.st}, arrDeclList={$domainExpression.st})
572     ;
573
574 qualifiedTypeIdent returns [ClassSymbol type]
575     :   ^(QUALIFIED_TYPE_IDENT (t+=typeIdent)+)
576         {$type = (ClassSymbol)$QUALIFIED_TYPE_IDENT.def;}
577         -> template(types={$t}) "<types; separator=\"::\">"
578     ;
579
580 typeIdent
581     :   ^(IDENT templateInstantiation?)
582         -> typeIdent(typeID={$IDENT.text}, generics={$templateInstantiation.st})
583     ;
584
585 primitiveType
586 @init {
587 $st = %{$start.getText()};
588 }
589     :   BOOLEAN
590         -> template() "bool"
591     |   CHAR
592     |   BYTE
593         -> template() "char"
594     |   SHORT
595     |   INT
596     |   LONG
597     |   FLOAT
598     |   DOUBLE
599     ;
600
601 templateArg
602     :   genericTypeArgument
603         -> {$genericTypeArgument.st}
604     |   literal
605         -> {$literal.st}
606     ;
607
608 templateArgList
609     :   params+=templateArg+
610         -> template(params={$params}) "<params; separator=\", \">"
611     ;
612
613 templateInstantiation
614     :   ^(TEMPLATE_INST templateArgList)
615         -> template(args={$templateArgList.st}) "\<<args>\>"
616     |   ^(TEMPLATE_INST ts=templateInstantiation)
617         -> template(inst={$ts.st}) "\<<inst>\>"
618     ;
619
620 genericTypeArgumentList
621     :   ^(GENERIC_TYPE_ARG_LIST (gta+=genericTypeArgument)+)
622         -> template(gtal={$gta}) "\<<gtal; separator=\", \">\>"
623     ;
624
625 genericTypeArgument
626     :   type
627         -> {$type.st}
628     |   '?'
629         -> template(t={$text}) "/* genericTypeArgument: wildcard bound types not implemented */ <t>"
630     ;
631
632 formalParameterList
633     :   ^(FORMAL_PARAM_LIST (fpsd+=formalParameterStandardDecl)* fpvd=formalParameterVarargDecl?)
634         -> formal_param_list(sdecl={$fpsd}, vdecl={$fpvd.st})
635     ;
636     
637 formalParameterStandardDecl
638     :   ^(FORMAL_PARAM_STD_DECL lms=localModifierList? t=type vdid=variableDeclaratorId)
639         -> formal_param_decl(modList={$lms.st}, type={$t.st}, declID={$vdid.st})
640     ;
641     
642 formalParameterVarargDecl
643     :   ^(FORMAL_PARAM_VARARG_DECL localModifierList? type variableDeclaratorId)
644         -> template(t={$text}) "/*formal parameter varargs not implemented*/ <t>"
645     ;
646     
647 qualifiedIdentifier
648     :   IDENT
649         -> template(t={$text}) "<t>"
650     |   ^(DOT qualifiedIdentifier IDENT)
651         -> template(t={$text}) "<t>"
652     ;
653     
654 block
655 @init { boolean emptyBlock = true; }
656     :   ^(BLOCK (b+=blockStatement)*)
657         { emptyBlock = ($b == null || $b.size() == 0); }
658         -> {((emitCC() && (currentMethod == null || !currentMethod.hasSDAG)) ||
659             (emitCI() && (currentMethod != null && currentMethod.hasSDAG))) && emptyBlock}? template(bsl={$b}) "{ }"
660         -> {emitCC() && (currentMethod == null || !currentMethod.hasSDAG)}? block_cc(bsl={$b})
661         -> {emitCI() && (currentMethod != null && currentMethod.hasSDAG)}? block_sdag_ci(bsl={$b})
662         ->
663     ;
664     
665 blockStatement
666     :   localVariableDeclaration
667         -> {$localVariableDeclaration.st}
668     |   statement
669         -> {$statement.st}
670     ;
671
672
673 localVariableDeclaration
674     :   ^(PRIMITIVE_VAR_DECLARATION localModifierList? simpleType vdl=variableDeclaratorList[null])
675         -> local_var_decl(
676             modList={$localModifierList.st},
677             type={$simpleType.st},
678             declList={$vdl.st})
679     |   ^(OBJECT_VAR_DECLARATION localModifierList? objectType vdl=variableDeclaratorList[$objectType.st])
680         -> local_var_decl(
681             modList={$localModifierList.st},
682             type={$objectType.st},
683             declList={$vdl.st})
684     ;
685
686
687 statement
688     :   nonBlockStatement
689         -> {$nonBlockStatement.st}
690     |   sdagStatement
691         -> {$sdagStatement.st}
692     |   block
693         -> {$block.st}
694     ;
695
696 divconBlock
697     :   ^(DIVCON_BLOCK divconExpr)
698     ;
699
700 divconAssignment
701     :   ^(LET_ASSIGNMENT IDENT expression)
702     ;
703
704 divconAssignmentList
705     :   divconAssignment+
706     ;
707
708 divconExpr
709     :   ^(IF parenthesizedExpression divconExpr divconExpr?)
710     |   ^(LET divconAssignmentList IN divconExpr)
711     |   expression
712     ;
713
714 sdagStatement
715     :   ^(OVERLAP block)
716         -> template(b={$block.st}) "} overlap <b> atomic {"
717     |   ^(WHEN (wa+=whenArgument)* block)
718         -> template(w={wa}, b={$block.st}) "} when <w> <b> atomic {"
719     |   ^(SDAG_IF parenthesizedExpression ifblock=block elseblock=block?)
720     |   ^(SDAG_FOR forInit? FOR_EXPR expression? FOR_UPDATE expression* block)
721     |   ^(SDAG_WHILE parenthesizedExpression block)
722     |   ^(SDAG_DO block parenthesizedExpression)
723     ;
724
725 whenArgument
726     :   IDENT expression? formalParameterList
727         -> template(i={$IDENT}, e={$expression.st}, f={$formalParameterList.st}) "<i> <if(e)>[<e>] <endif><f>"
728     ;
729
730 nonBlockStatement
731     :   ^(ASSERT cond=expression msg=expression?)
732         -> assert(cond={$cond.st}, msg={$msg.st})
733     |   ^(IF parenthesizedExpression then=block else_=block?)
734         -> if(cond={$parenthesizedExpression.st}, then={$then.st}, else_={$else_.st})
735     |   ^(FOR forInit? FOR_EXPR cond=expression? FOR_UPDATE (update+=expression)* b=block)
736         -> for(initializer={$forInit.st}, cond={$cond.st}, update={$update}, body={$block.st})
737     |   ^(FOR_EACH localModifierList? type IDENT expression block) 
738         -> template(t={$text}) "/* foreach not implemented */ <t>"
739     |   ^(WHILE pe=parenthesizedExpression b=block)
740         -> while(cond={$pe.st}, body={$b.st})
741     |   ^(DO b=block pe=parenthesizedExpression)
742         -> dowhile(cond={$pe.st}, block={$b.st})
743     |   ^(SWITCH pe=parenthesizedExpression (scls+=switchCaseLabel)*)
744         -> switch(expr={$pe.st}, labels={$scls})
745     |   ^(RETURN e=expression?)
746         -> return(val={$e.st})
747     |   ^(THROW expression)
748         -> template(t={$text}) "/* throw not implemented */ <t>"
749     |   ^(BREAK IDENT?)
750         -> template() "break;" // TODO: support labeling
751     |   ^(CONTINUE IDENT?)
752         -> template() "continue;" // TODO: support labeling
753     |   ^(LABELED_STATEMENT i=IDENT s=statement)
754         -> label(text={$i.text}, stmt={$s.st})
755     |   expression
756         -> template(expr={$expression.st}) "<expr>;"
757     |   ^('delete' expression)
758         -> template(t={$expression.st}) "delete <t>;"
759     |   ^('embed' STRING_LITERAL EMBED_BLOCK)
760         ->  embed_cc(str={$STRING_LITERAL.text}, blk={$EMBED_BLOCK.text})
761     |   ';' // Empty statement.
762         -> {%{$start.getText()}}
763     |   ^(PRINT (exprs += expression)*)
764         ->  print(exprs = {$exprs})
765     |   ^(PRINTLN (exprs += expression)*)
766         ->  println(exprs = {$exprs})
767     |   ^(EXIT expression?)
768         ->  exit(expr = {$expression.st})
769     |   EXITALL
770         ->  exitall()
771     ;
772         
773 switchCaseLabel
774     :   ^(CASE expression (b+=blockStatement)*)
775         -> case(expr={$expression.st}, block={$b})
776     |   ^(DEFAULT (b+=blockStatement)*)
777         -> template(block={$b}) "default: <block>"
778     ;
779     
780 forInit
781     :   localVariableDeclaration
782         -> template(lvd={$localVariableDeclaration.st}) "<lvd>"
783     |   (ex+=expression)+
784         -> template(ex={$ex}) "<ex; separator=\", \">"
785     ;
786
787 // EXPRESSIONS
788
789 parenthesizedExpression
790     :   ^(PAREN_EXPR exp=expression)
791         -> template(expr={$exp.st}) "(<expr>)"
792     ;
793
794 expressionArrayAccess
795     :   ^(EXPR expr)
796         -> {$expr.st}
797     |    domainExpressionAccess
798         -> {$domainExpressionAccess.st}
799     ;
800     
801 expression
802     :   ^(EXPR expr)
803         -> {$expr.st}
804     |   domainExpression[null]
805         -> {$domainExpression.st}
806     ;
807
808 expr
809     :   ^(ASSIGNMENT e1=expr e2=expr)
810         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> = <e2>"
811     |   ^('+=' e1=expr e2=expr)
812         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> += <e2>"
813     |   ^('-=' e1=expr e2=expr)
814         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> -= <e2>"
815     |   ^('*=' e1=expr e2=expr)
816         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> *= <e2>"
817     |   ^('/=' e1=expr e2=expr)
818         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> /= <e2>"
819     |   ^('&=' e1=expr e2=expr)
820         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> &= <e2>"
821     |   ^('|=' e1=expr e2=expr)
822         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> |= <e2>"
823     |   ^('^=' e1=expr e2=expr)
824         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> ^= <e2>"
825     |   ^('%=' e1=expr e2=expr)
826         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> %= <e2>"
827     |   ^('>>>=' e1=expr e2=expr)
828         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \>\>\>= <e2>"
829     |   ^('>>=' e1=expr e2=expr)
830         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \>\>= <e2>"
831     |   ^('<<=' e1=expr e2=expr)
832         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \<\<= <e2>"
833     |   ^('?' e1=expr e2=expr e3=expr)
834         -> template(e1={$e1.st}, e2={$e2.st}, e3={$e3.st}) "<e1> ? <e2> : <e3>"
835     |   ^('||' e1=expr e2=expr)
836         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> || <e2>"
837     |   ^('&&' e1=expr e2=expr)
838         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> && <e2>"
839     |   ^(BITWISE_OR e1=expr e2=expr)
840         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> | <e2>"
841     |   ^('^' e1=expr e2=expr)
842         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> ^ <e2>"
843     |   ^('&' e1=expr e2=expr)
844         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> & <e2>"
845     |   ^(EQUALS e1=expr e2=expr)
846         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> == <e2>"
847     |   ^('!=' e1=expr e2=expr)
848         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> != <e2>"
849     |   ^('instanceof' expr type)
850         -> template(t={$text}) "/* instanceof not implemented */ <t>"
851     |   ^('<=' e1=expr e2=expr)
852         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \<= <e2>"
853     |   ^('>=' e1=expr e2=expr)
854         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \>= <e2>"
855     |   ^('>>>' e1=expr e2=expr)
856         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \>\>\> <e2>"
857     |   ^('>>' e1=expr e2=expr)
858         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \>\> <e2>"
859     |   ^('>' e1=expr e2=expr)
860         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \> <e2>"
861     |   ^('<<' e1=expr e2=expr)
862         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \<\< <e2>"
863     |   ^('<' e1=expr e2=expr)
864         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \< <e2>"
865     |   ^('+' e1=expr e2=expr)
866         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> + <e2>"
867     |   ^('-' e1=expr e2=expr)
868         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> - <e2>"
869     |   ^('*' e1=expr e2=expr)
870         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> * <e2>"
871     |   ^('/' e1=expr e2=expr)
872         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> / <e2>"
873     |   ^('%' e1=expr e2=expr)
874         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> % <e2>"
875     |   ^(UNARY_PLUS e1=expr)
876         -> template(e1={$e1.st}) "+<e1>"
877     |   ^(UNARY_MINUS e1=expr)
878         -> template(e1={$e1.st}) "-<e1>"
879     |   ^(PRE_INC e1=expr)
880         -> template(e1={$e1.st}) "++<e1>"
881     |   ^(PRE_DEC e1=expr)
882         -> template(e1={$e1.st}) "--<e1>"
883     |   ^(POST_INC e1=expr)
884         -> template(e1={$e1.st}) "<e1>++"
885     |   ^(POST_DEC e1=expr)
886         -> template(e1={$e1.st}) "<e1>--"
887     |   ^(TILDE e1=expr)
888         -> template(e1={$e1.st}) "~<e1>"
889     |   ^(NOT e1=expr)
890         -> template(e1={$e1.st}) "!<e1>"
891     |   ^(CAST_EXPR ty=type e1=expr)
892         -> template(ty={$ty.st}, e1={$e1.st}) "(<ty>)<e1>"
893     |   primaryExpression
894         -> {$primaryExpression.st}
895     |   ^(POINTER_DEREFERENCE e1 = expr)
896         ->  template(e = {$e1.st}) "*(<e>)"
897     ;
898
899 primaryExpression
900 @init { int dims = 1; }
901     :   ^(DOT prim=primaryExpression
902             ( IDENT   -> template(id={$IDENT.text}, prim={$prim.st}) "<prim>.<id>"
903             | THIS    -> template(prim={$prim.st}) "<prim>.this"
904             | SUPER   -> template(prim={$prim.st}) "<prim>.super"
905             )
906         )
907     |   ^(ARROW prim=primaryExpression
908             ( IDENT   -> template(id={$IDENT.text}, prim={$prim.st}) "<prim>-><id>"
909             | THIS    -> template(prim={$prim.st}) "<prim>->this"
910             | SUPER   -> template(prim={$prim.st}) "<prim>->super"
911             )
912         )
913     |   parenthesizedExpression
914         -> {$parenthesizedExpression.st}
915     |   IDENT
916         -> {%{$IDENT.text}}
917     |   CHELPER
918         -> {%{"constructorHelper"}}
919     |   ^(METHOD_CALL pe=primaryExpression gtal=genericTypeArgumentList? args=arguments)
920         -> method_call(primary={$pe.st}, generic_types={$gtal.st}, args={$args.st})
921     |   ^(ENTRY_METHOD_CALL pe=primaryExpression gtal=genericTypeArgumentList? args=arguments)
922         -> method_call(primary={$pe.st}, generic_types={$gtal.st}, args={$args.st})
923     |   explicitConstructorCall
924         -> {$explicitConstructorCall.st}
925     |   ^(ARRAY_ELEMENT_ACCESS pe=primaryExpression ex=expressionArrayAccess) {
926             if ($pe.start.symbolType != null && $pe.start.symbolType instanceof PointerType) {
927                 PointerType p = (PointerType)($pe.start.symbolType);
928                 if (p.baseType instanceof ClassSymbol) {
929                     ClassSymbol cs = (ClassSymbol)(p.baseType);
930                     if (cs.templateArgs != null && cs.templateArgs.size() > 1 &&
931                         cs.templateArgs.get(1) instanceof LiteralType) {
932                         LiteralType l = (LiteralType)(cs.templateArgs.get(1));
933                         dims = Integer.valueOf(l.literal);
934                     }
935                 }
936             }
937         }
938         -> {$pe.start.symbolType != null && $pe.start.symbolType instanceof PointerType && dims == 1}?
939                template(pe={$pe.st}, ex={$ex.st}) "(*(<pe>))[<ex>]"
940         -> {$pe.start.symbolType != null && $pe.start.symbolType instanceof PointerType && dims == 2}?
941                template(pe={$pe.st}, ex={$ex.st}) "(*(<pe>)).access(<ex>)"
942         -> template(pe={$pe.st}, ex={$ex.st}) "(<pe>)[<ex>]"
943     |   literal
944         -> {$literal.st}
945     |   newExpression[null]
946         -> {$newExpression.st}
947     |   THIS
948         -> {%{$start.getText()}}
949     |   arrayTypeDeclarator
950         -> {$arrayTypeDeclarator.st}
951     |   SUPER
952         -> {%{$start.getText()}}
953     |   GETNUMPES
954         ->  template() "CkNumPes()"
955     |   GETNUMNODES
956         ->  template() "CkNumNodes()"
957     |   GETMYPE
958         ->  template() "CkMyPe()"
959     |   GETMYNODE
960         ->  template() "CkMyNode()"
961     |   GETMYRANK
962         ->  template() "CkMyRank()"
963         |       THISINDEX
964                 ->      template() "thisIndex"
965         |       THISPROXY
966                 ->      template() "thisProxy"
967     |   domainExpression[null]
968         ->  {$domainExpression.st}
969     ;
970     
971 explicitConstructorCall
972     :   ^(THIS_CONSTRUCTOR_CALL genericTypeArgumentList? arguments)
973         -> template(t={$text}) "<t>"
974     |   ^(SUPER_CONSTRUCTOR_CALL primaryExpression? genericTypeArgumentList? arguments)
975         -> template(t={$text}) "<t>"
976     ;
977
978 arrayTypeDeclarator
979     :   ^(ARRAY_DECLARATOR (arrayTypeDeclarator | qualifiedIdentifier | primitiveType))
980         -> template(t={$text}) "<t>"
981     ;
982
983 newExpression[StringTemplate obtype]
984     :   ^(NEW_EXPRESSION arguments? domainExpression[$arguments.args])
985         -> template(domain={$domainExpression.st},type={$obtype}) "new <type>(<domain>)"
986     |   ^(NEW proxyType arguments)
987         -> template(t={$proxyType.st}, a={$arguments.st}) "<t>::ckNew(<a>)"
988     |   ^(NEW nonProxyType arguments)
989         -> template(q={$nonProxyType.st}, a={$arguments.st}) "new <q>(<a>)"
990     ;
991
992 arguments returns [List<StringTemplate> args]
993 @init {
994     $args = new ArrayList<StringTemplate>();
995 }
996     :   ^(ARGUMENT_LIST (e=expression { $args.add($e.st); } )*)        
997         ->  arguments(exprs={$args})
998     ;
999
1000 literal
1001 @init {
1002 $st = %{$start.getText()};
1003 }
1004     :   HEX_LITERAL
1005     |   OCTAL_LITERAL
1006     |   DECIMAL_LITERAL
1007     |   FLOATING_POINT_LITERAL
1008     |   CHARACTER_LITERAL
1009     |   STRING_LITERAL
1010     |   TRUE
1011     |   FALSE
1012     |   NULL
1013     ;
1014