0f725cc396060eb32af606c6ba69ccca13a433cd
[charm.git] / src / langs / charj / src / charj / translator / CharjEmitter.g
1 /**
2  * ANTLR (v3) Tree Parser for the Charj Language
3  */
4
5 tree grammar CharjEmitter;
6
7 options {
8     backtrack = true; 
9     memoize = true;
10     tokenVocab = Charj;
11     ASTLabelType = CharjAST;
12     output = template;
13 }
14
15
16 @header {
17 package charj.translator;
18 }
19
20
21 @members {
22     SymbolTable symtab_ = null;
23
24     PackageScope currentPackage_ = null;
25     ClassSymbol currentClass_ = null;
26     MethodSymbol currentMethod_ = null;
27     LocalScope currentLocalScope_ = null;
28
29     Translator translator_;
30     OutputMode mode_;
31
32     private boolean emitCC() { return mode_ == OutputMode.cc; }
33     private boolean emitCI() { return mode_ == OutputMode.ci; }
34     private boolean emitH() { return mode_ == OutputMode.h; }
35     private boolean debug() { return translator_.debug(); }
36
37     /**
38      *  Override ANTLR's token mismatch behavior so we throw exceptions early.
39      */
40     protected void mismatch(IntStream input, int ttype, BitSet follow)
41         throws RecognitionException {
42         throw new MismatchedTokenException(ttype, input);
43     }
44
45     /**
46      *  Override ANTLR's set mismatch behavior so we throw exceptions early.
47      */
48     public Object recoverFromMismatchedSet(IntStream input, RecognitionException e, BitSet follow)
49         throws RecognitionException {
50         throw e;
51     }
52
53     /**
54      *  Test a list of CharjAST nodes to see if any of them has the given token
55      *  type.
56      */
57     public boolean listContainsToken(List<CharjAST> list, int tokenType) {
58         if (list == null) return false;
59         for (CharjAST node : list) {
60             if (node.token.getType() == tokenType) {
61                 return true;
62             }
63         }
64         return false;
65     }
66 }
67
68
69 // Replace default ANTLR generated catch clauses with this action, allowing early failure.
70 @rulecatch {
71     catch (RecognitionException re) {
72         reportError(re);
73         throw re;
74     }
75 }
76
77
78 // Starting point for parsing a Charj file.
79 charjSource[SymbolTable symtab, OutputMode m]
80 @init {
81     this.symtab_ = symtab;
82     this.translator_ = symtab.translator;
83     this.mode_ = m;
84     String closingBraces = "";
85 }
86     :   ^(CHARJ_SOURCE (p=packageDeclaration)? 
87         (i+=importDeclaration)* 
88         (t=typeDeclaration))
89         {
90             // construct string of }'s to close namespace 
91             if ($p.st != null) {
92                 String temp_p = $p.st.toString();
93                 for (int idx=0; idx<temp_p.length(); ++idx) {
94                     if (temp_p.charAt(idx) == '{') {
95                         closingBraces += "} ";
96                     }
97                 }
98             }
99         }
100         -> {emitCC()}? charjSource_cc(
101             pd={$p.st}, ids={$i}, tds={$t.st}, cb={closingBraces}, debug={debug()})
102         -> {emitCI()}? charjSource_ci(pd={$p.st}, ids={$i}, tds={$t.st}, debug={debug()})
103         -> {emitH()}? charjSource_h(
104             pd={$p.st}, ids={$i}, tds={$t.st}, cb={closingBraces}, debug={debug()})
105         ->
106     ;
107
108 packageDeclaration
109 @init { 
110     List<String> names = null; 
111 }
112     :   ^('package' qualifiedIdentifier)  {
113             names =  java.util.Arrays.asList(
114                     $qualifiedIdentifier.text.split("[.]"));
115         }
116         -> {(emitCC() || emitH())}? packageDeclaration_cc_h(
117             ids={names})
118         ->
119     ;
120     
121 importDeclaration
122 @init {
123     String importID = null;
124 }
125     :   ^('import' qualifiedIdentifier ds='.*'?)
126         {
127             importID = $qualifiedIdentifier.text;
128             if ($ds != null) {
129             }
130         }
131         {$ds == null}? // TODO: add support for importing x.*
132         -> {(emitCC() || emitH())}? importDeclaration_cc_h(
133             inc_id={importID.replace(".","/")},
134             use_id={importID.replace(".","::")})
135         ->
136     ;
137     
138 typeDeclaration
139     :   ^('class' IDENT (^('extends' su=type))? (^('implements' type+))? (csds+=classScopeDeclaration)*)
140         -> {emitCC()}? classDeclaration_cc(
141                 ident={$IDENT.text}, 
142                 ext={$su.st}, 
143                 csds={$csds})
144         -> {emitCI()}? classDeclaration_ci(
145                 ident={$IDENT.text}, 
146                 ext={$su.st}, 
147                 csds={$csds})
148         -> {emitH()}? classDeclaration_h(
149                 ident={$IDENT.text}, 
150                 ext={$su.st}, 
151                 csds={$csds})
152         ->
153     |   ^('interface' IDENT (^('extends' type+))? interfaceScopeDeclaration*)
154         -> template(t={$text}) "/*INTERFACE-not implemented*/ <t>"
155     |   ^('enum' IDENT (^('implements' type+))? classScopeDeclaration*)
156         -> template(t={$text}) "/*ENUM-not implemented*/ <t>"
157     ;
158
159 enumConstant
160     :   ^(IDENT arguments?)
161         -> template(t={$text}) "/*enumConstant-not implemented*/ <t>"
162     ;
163
164 classScopeDeclaration
165 @init { boolean entry = false; }
166     :   ^(FUNCTION_METHOD_DECL m=modifierList g=genericTypeParameterList? 
167             ty=type IDENT f=formalParameterList a=arrayDeclaratorList? 
168             b=block?)
169         { 
170             // determine whether this is an entry method
171             entry = listContainsToken($m.start.getChildren(), ENTRY);
172         }
173         -> {emitCC()}? funcMethodDecl_cc(
174                 modl={$m.st}, 
175                 gtpl={$g.st}, 
176                 ty={$ty.text},
177                 id={$IDENT.text}, 
178                 fpl={$f.st}, 
179                 adl={$a.st},
180                 block={$b.st})
181         -> {emitH()}? funcMethodDecl_h(
182                 modl={$m.st}, 
183                 gtpl={$g.st}, 
184                 ty={$ty.text},
185                 id={$IDENT.text}, 
186                 fpl={$f.st}, 
187                 adl={$a.st},
188                 block={$b.st})
189         -> {(emitCI() && entry)}? funcMethodDecl_ci(
190                 modl={$m.st}, 
191                 gtpl={$g.st}, 
192                 ty={$ty.text},
193                 id={$IDENT.text}, 
194                 fpl={$f.st}, 
195                 adl={$a.st},
196                 block={$b.st})
197         ->
198     |   ^(VOID_METHOD_DECL m=modifierList g=genericTypeParameterList? IDENT 
199             f=formalParameterList b=block?)
200         { 
201             // determine whether this is an entry method
202             entry = listContainsToken($m.start.getChildren(), ENTRY);
203         }
204         -> {emitCC()}? voidMethodDecl_cc(
205                 modl={$m.st}, 
206                 gtpl={$g.st}, 
207                 id={$IDENT.text}, 
208                 fpl={$f.st}, 
209                 block={$b.st})
210         -> {emitCI() && entry}? voidMethodDecl_ci(
211                 modl={$m.st}, 
212                 gtpl={$g.st}, 
213                 id={$IDENT.text}, 
214                 fpl={$f.st}, 
215                 block={$b.st})
216         -> {emitH()}? voidMethodDecl_h(
217                 modl={$m.st}, 
218                 gtpl={$g.st}, 
219                 id={$IDENT.text}, 
220                 fpl={$f.st}, 
221                 block={$b.st})
222         ->
223     |   ^(PRIMITIVE_VAR_DECLARATION modifierList simpleType variableDeclaratorList)
224         -> {emitCC() || emitH()}? primitive_var_decl(
225             modList={$modifierList.st},
226             type={$simpleType.st},
227             declList={$variableDeclaratorList.st})
228         ->
229     |   ^(OBJECT_VAR_DECLARATION modifierList objectType variableDeclaratorList)
230         -> {emitCC() || emitH()}? object_var_decl(
231             modList={$modifierList.st},
232             type={$objectType.st},
233             declList={$variableDeclaratorList.st})
234         ->
235     |   ^(CONSTRUCTOR_DECL m=modifierList g=genericTypeParameterList? IDENT f=formalParameterList b=block)
236         { 
237             // determine whether this is an entry method
238             entry = listContainsToken($m.start.getChildren(), ENTRY);
239         }
240         -> {emitCC()}? ctorDecl_cc(
241                 modl={$m.st}, 
242                 gtpl={$g.st}, 
243                 id={$IDENT.text}, 
244                 fpl={$f.st}, 
245                 block={$b.st})
246         -> {emitCI() && entry}? ctorDecl_ci(
247                 modl={$m.st}, 
248                 gtpl={$g.st}, 
249                 id={$IDENT.text}, 
250                 fpl={$f.st}, 
251                 block={$b.st})
252         -> {emitH()}? ctorDecl_h(
253                 modl={$m.st}, 
254                 gtpl={$g.st}, 
255                 id={$IDENT.text}, 
256                 fpl={$f.st}, 
257                 block={$b.st})
258         ->
259     ;
260     
261 interfaceScopeDeclaration
262     :   ^(FUNCTION_METHOD_DECL modifierList genericTypeParameterList? type IDENT formalParameterList arrayDeclaratorList?)
263         -> template(t={$text}) "/*interfaceScopeDeclarations-not implemented */ <t>"
264     |   ^(VOID_METHOD_DECL modifierList genericTypeParameterList? IDENT formalParameterList)
265         -> template(t={$text}) "/*interfaceScopeDeclarations-not implemented */ <t>"
266     |   ^(PRIMITIVE_VAR_DECLARATION modifierList simpleType variableDeclaratorList)
267         -> template(t={$text}) "/*interfaceScopeDeclarations-not implemented */ <t>"
268     |   ^(OBJECT_VAR_DECLARATION modifierList objectType variableDeclaratorList)
269         -> template(t={$text}) "/*interfaceScopeDeclarations-not implemented */ <t>"
270     ;
271
272 variableDeclaratorList
273     :   ^(VAR_DECLARATOR_LIST (var_decls+=variableDeclarator)+)
274         -> var_decl_list(var_decls={$var_decls})
275     ;
276
277 variableDeclarator
278     :   ^(VAR_DECLARATOR id=variableDeclaratorId initializer=variableInitializer?)
279         -> var_decl(id={$id.st}, initializer={$initializer.st})
280     ;
281     
282 variableDeclaratorId
283     :   ^(IDENT adl=arrayDeclaratorList?)
284         -> var_decl_id(id={$IDENT.text}, arrayDeclList={$adl.st})
285     ;
286
287 variableInitializer
288     :   arrayInitializer
289         -> {$arrayInitializer.st}
290     |   expression
291         -> {$expression.st}
292     ;
293
294 arrayDeclaratorList
295     :   ^(ARRAY_DECLARATOR_LIST ARRAY_DECLARATOR*)  
296         -> template(t={$text}) "<t>"
297     ;
298     
299 arrayInitializer
300     :   ^(ARRAY_INITIALIZER variableInitializer*)
301         -> template(t={$text}) "/* arrayInitializer-not implemented */ <t>"
302     ;
303
304 genericTypeParameterList
305     :   ^(GENERIC_TYPE_PARAM_LIST genericTypeParameter+)
306         -> template(t={$text}) "/*GENERIC_TYPE_PARAM_LIST-not implemented*/ <t>"
307     ;
308
309 genericTypeParameter
310     :   ^(IDENT bound?)
311         -> template(t={$text}) "/*genericTypeParameter-not implemented*/ <t>"
312     ;
313         
314 bound
315     :   ^(EXTENDS_BOUND_LIST type+)
316         -> template(t={$text}) "/*EXTENDS_BOUND_LIST-not implemented*/ <t>"
317     ;
318
319 throwsClause
320     :   ^(THROWS_CLAUSE qualifiedIdentifier+)
321         -> template(t={$text}) "/* throwsClause-not implemented */ <t>"
322     ;
323
324 modifierList
325     :   ^(MODIFIER_LIST (m+=modifier)*)
326         -> mod_list(mods={$m})
327     ;
328
329 modifier
330 @init {
331 $st = %{$start.getText()};
332 }
333     :   'public'
334     |   'protected'
335     |   'private'
336     |   'entry'
337     |   'abstract'
338     |   'native'
339     |   localModifier
340         -> {$localModifier.st}
341     ;
342
343 localModifierList
344     :   ^(LOCAL_MODIFIER_LIST (m+=localModifier)*)
345         -> local_mod_list(mods={$m})
346     ;
347
348 localModifier
349 @init {
350 $st = %{$start.getText()};
351 }
352     :   'final'
353     |   'static'
354     |   'volatile'
355     ;
356
357     
358 type
359     :   simpleType
360         -> {$simpleType.st}
361     |   objectType 
362         -> {$objectType.st}
363     ;
364
365 simpleType
366     :   ^(TYPE primitiveType arrayDeclaratorList?)
367         -> type(typeID={$primitiveType.st}, arrDeclList={$arrayDeclaratorList.st})
368     ;
369
370 objectType
371     :   ^(TYPE qualifiedTypeIdent arrayDeclaratorList?)
372         -> type(typeID={$qualifiedTypeIdent.st}, arrDeclList={$arrayDeclaratorList.st})
373     ;
374
375 qualifiedTypeIdent
376     :   ^(QUALIFIED_TYPE_IDENT (t+=typeIdent)+) 
377         -> template(types={$t}) "<types; separator=\".\">"
378     ;
379
380 typeIdent
381     :   ^(IDENT genericTypeArgumentList?)
382         -> typeIdent(typeID={$IDENT.text}, generics={$genericTypeArgumentList.st})
383     ;
384
385 primitiveType
386 @init {
387 $st = %{$start.getText()};
388 }
389     :   'boolean'
390     |   'char'
391     |   'byte'
392     |   'short'
393     |   'int'
394     |   'long'
395     |   'float'
396     |   'double'
397     ;
398
399 genericTypeArgumentList
400     :   ^(GENERIC_TYPE_ARG_LIST (gta+=genericTypeArgument)+)
401         -> template(gtal={$gta}) "\<<gtal; separator=\", \">\>"
402     ;
403     
404 genericTypeArgument
405     :   type
406         -> {$type.st}
407     |   '?'
408         -> template(t={$text}) "/* genericTypeArgument: wildcard bound types not implemented */ <t>"
409     ;
410
411 formalParameterList
412     :   ^(FORMAL_PARAM_LIST (fpsd+=formalParameterStandardDecl)* fpvd=formalParameterVarargDecl?)
413         -> formal_param_list(sdecl={$fpsd}, vdecl={$fpvd.st})
414     ;
415     
416 formalParameterStandardDecl
417     :   ^(FORMAL_PARAM_STD_DECL lms=localModifierList t=type vdid=variableDeclaratorId)
418         -> formal_param_decl(modList={$lms.st}, type={$t.st}, declID={$vdid.st})
419     ;
420     
421 formalParameterVarargDecl
422     :   ^(FORMAL_PARAM_VARARG_DECL localModifierList type variableDeclaratorId)
423         -> template(t={$text}) "/*formal parameter varargs not implemented*/ <t>"
424     ;
425     
426 qualifiedIdentifier
427     :   IDENT
428         -> template(t={$text}) "<t>"
429     |   ^('.' qualifiedIdentifier IDENT)
430         -> template(t={$text}) "<t>"
431     ;
432     
433 block
434 @init { boolean emptyBlock = true; }
435     :   ^(BLOCK (b+=blockStatement)*)
436         { emptyBlock = ($b == null || $b.size() == 0); }
437         -> {emitCC() && emptyBlock}? template(bsl={$b}) "{ }"
438         -> {emitCC()}? block_cc(bsl={$b})
439         ->
440     ;
441     
442 blockStatement
443     :   localVariableDeclaration
444         -> {$localVariableDeclaration.st}
445     |   statement
446         -> {$statement.st}
447     ;
448
449
450 localVariableDeclaration
451     :   ^(PRIMITIVE_VAR_DECLARATION localModifierList simpleType variableDeclaratorList)
452         -> primitive_var_decl(
453             modList={null},
454             type={$simpleType.st},
455             declList={$variableDeclaratorList.st})
456     |   ^(OBJECT_VAR_DECLARATION localModifierList objectType variableDeclaratorList)
457         -> object_var_decl(
458             modList={null},
459             type={$objectType.st},
460             declList={$variableDeclaratorList.st})
461     ;
462
463
464 statement
465     :   block
466         -> {$block.st}
467     |   ^('assert' cond=expression msg=expression?)
468         -> assert(cond={$cond.st}, msg={$msg.st})
469     |   ^('if' parenthesizedExpression then=statement else_=statement?)
470         -> if(cond={$parenthesizedExpression.st}, then={$then.st}, else_={$else_.st})
471     |   ^('for' forInit cond=expression? (update+=expression)* s=statement)
472         -> for(initializer={$forInit.st}, cond={$cond.st}, update={$update}, body={$s.st})
473     |   ^(FOR_EACH localModifierList type IDENT expression statement) 
474         -> template(t={$text}) "/* foreach not implemented */ <t>"
475     |   ^('while' pe=parenthesizedExpression s=statement)
476         -> while(cond={$pe.st}, body={$s.st})
477     |   ^('do' s=statement pe=parenthesizedExpression)
478         -> dowhile(cond={$pe.st}, block={$s.st})
479     |   ^('switch' pe=parenthesizedExpression (scls+=switchCaseLabel)*)
480         -> switch(expr={$pe.st}, labels={$scls})
481     |   ^('return' e=expression?)
482         -> return(val={$e.st})
483     |   ^('throw' expression)
484         -> template(t={$text}) "/* throw not implemented */ <t>"
485     |   ^('break' IDENT?)
486         -> template() "break;" // TODO: support labeling
487     |   ^('continue' IDENT?)
488         -> template() "continue;" // TODO: support labeling
489     |   ^(LABELED_STATEMENT i=IDENT s=statement)
490         -> label(text={$i.text}, stmt={$s.st})
491     |   expression
492         -> template(expr={$expression.st}) "<expr>;"
493     |   ^('embed' STRING_LITERAL EMBED_BLOCK)
494         ->  embed_cc(str={$STRING_LITERAL.text}, blk={$EMBED_BLOCK.text})
495     |   ';' // Empty statement.
496         -> {%{$start.getText()}}
497     ;
498         
499 switchCaseLabel
500     :   ^('case' expression (b+=blockStatement)*)
501         -> case(expr={$expression.st}, block={$b})
502     |   ^('default' (b+=blockStatement)*)
503         -> template(block={$b}) "default: <block>"
504     ;
505     
506 forInit
507     :   localVariableDeclaration
508         -> template(lvd={$localVariableDeclaration.st}) "<lvd>"
509     |   (ex+=expression)+
510         -> template(ex={$ex}) "<ex; separator=\", \">"
511     ;
512
513 // EXPRESSIONS
514
515 parenthesizedExpression
516     :   ^(PAREN_EXPR exp=expression)
517         -> template(expr={$exp.st}) "(<expr>)"
518     ;
519     
520 expression
521     :   ^(EXPR expr)
522         -> {$expr.st}
523     ;
524
525 expr
526     :   ^('=' e1=expr e2=expr)
527         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> = <e2>"
528     |   ^('+=' e1=expr e2=expr)
529         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> += <e2>"
530     |   ^('-=' e1=expr e2=expr)
531         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> -= <e2>"
532     |   ^('*=' e1=expr e2=expr)
533         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> *= <e2>"
534     |   ^('/=' e1=expr e2=expr)
535         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> /= <e2>"
536     |   ^('&=' e1=expr e2=expr)
537         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> &= <e2>"
538     |   ^('|=' e1=expr e2=expr)
539         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> |= <e2>"
540     |   ^('^=' e1=expr e2=expr)
541         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> ^= <e2>"
542     |   ^('%=' e1=expr e2=expr)
543         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> %= <e2>"
544     |   ^('>>>=' e1=expr e2=expr)
545         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \>\>\>= <e2>"
546     |   ^('>>=' e1=expr e2=expr)
547         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \>\>= <e2>"
548     |   ^('<<=' e1=expr e2=expr)
549         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \<\<= <e2>"
550     |   ^('?' e1=expr e2=expr e3=expr)
551         -> template(e1={$e1.st}, e2={$e2.st}, e3={$e3.st}) "<e1> ? <e2> : <e3>"
552     |   ^('||' e1=expr e2=expr)
553         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> || <e2>"
554     |   ^('&&' e1=expr e2=expr)
555         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> && <e2>"
556     |   ^('|' e1=expr e2=expr)
557         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> | <e2>"
558     |   ^('^' e1=expr e2=expr)
559         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> ^ <e2>"
560     |   ^('&' e1=expr e2=expr)
561         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> & <e2>"
562     |   ^('==' e1=expr e2=expr)
563         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> == <e2>"
564     |   ^('!=' e1=expr e2=expr)
565         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> != <e2>"
566     |   ^('instanceof' expr type)
567         -> template(t={$text}) "/* instanceof not implemented */ <t>"
568     |   ^('<=' e1=expr e2=expr)
569         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \<= <e2>"
570     |   ^('>=' e1=expr e2=expr)
571         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \>= <e2>"
572     |   ^('>>>' e1=expr e2=expr)
573         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \>\>\> <e2>"
574     |   ^('>>' e1=expr e2=expr)
575         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \>\> <e2>"
576     |   ^('>' e1=expr e2=expr)
577         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \> <e2>"
578     |   ^('<<' e1=expr e2=expr)
579         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \<\< <e2>"
580     |   ^('<' e1=expr e2=expr)
581         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> \< <e2>"
582     |   ^('+' e1=expr e2=expr)
583         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> + <e2>"
584     |   ^('-' e1=expr e2=expr)
585         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> - <e2>"
586     |   ^('*' e1=expr e2=expr)
587         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> * <e2>"
588     |   ^('/' e1=expr e2=expr)
589         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> / <e2>"
590     |   ^('%' e1=expr e2=expr)
591         -> template(e1={$e1.st}, e2={$e2.st}) "<e1> % <e2>"
592     |   ^(UNARY_PLUS e1=expr)
593         -> template(e1={$e1.st}) "+<e1>"
594     |   ^(UNARY_MINUS e1=expr)
595         -> template(e1={$e1.st}) "-<e1>"
596     |   ^(PRE_INC e1=expr)
597         -> template(e1={$e1.st}) "++<e1>"
598     |   ^(PRE_DEC e1=expr)
599         -> template(e1={$e1.st}) "--<e1>"
600     |   ^(POST_INC e1=expr)
601         -> template(e1={$e1.st}) "<e1>++"
602     |   ^(POST_DEC e1=expr)
603         -> template(e1={$e1.st}) "<e1>--"
604     |   ^('~' e1=expr)
605         -> template(e1={$e1.st}) "~<e1>"
606     |   ^('!' e1=expr)
607         -> template(e1={$e1.st}) "!<e1>"
608     |   ^(CAST_EXPR ty=type e1=expr)
609         -> template(ty={$ty.st}, e1={$e1.st}) "(<ty>)<e1>"
610     |   primaryExpression
611         -> {$primaryExpression.st}
612     ;
613     
614 primaryExpression
615     :   ^(  '.' primaryExpression
616             (   IDENT
617             |   'this'
618             |   'super'
619             |   'class'
620             )
621         )
622         -> template(t={$text}) "/* AKB: not sure what's up with this primaryExpression yet */ <t>"
623     |   parenthesizedExpression
624         -> {$parenthesizedExpression.st}
625     |   IDENT
626         -> {%{$start.getText()}}
627     |   ^(METHOD_CALL pe=primaryExpression gtal=genericTypeArgumentList? args=arguments)
628         -> method_call(primary={$pe.st}, generic_types={$gtal.st}, args={$args.st})
629     |   explicitConstructorCall
630         -> {$explicitConstructorCall.st}
631     |   ^(ARRAY_ELEMENT_ACCESS pe=primaryExpression ex=expression)
632         -> template(pe={$pe.st}, ex={$ex.st}) "<pe>[<ex>]"
633     |   literal
634         -> {$literal.st}
635     |   newExpression
636         -> {$newExpression.st}
637     |   'this'
638         -> {%{$start.getText()}}
639     |   arrayTypeDeclarator
640         -> {$arrayTypeDeclarator.st}
641     |   'super'
642         -> {%{$start.getText()}}
643     ;
644     
645 explicitConstructorCall
646     :   ^(THIS_CONSTRUCTOR_CALL genericTypeArgumentList? arguments)
647         -> template(t={$text}) "<t>"
648     |   ^(SUPER_CONSTRUCTOR_CALL primaryExpression? genericTypeArgumentList? arguments)
649         -> template(t={$text}) "<t>"
650     ;
651
652 arrayTypeDeclarator
653     :   ^(ARRAY_DECLARATOR (arrayTypeDeclarator | qualifiedIdentifier | primitiveType))
654         -> template(t={$text}) "<t>"
655     ;
656
657 newExpression
658     :   ^(  STATIC_ARRAY_CREATOR
659             (   primitiveType newArrayConstruction
660             |   genericTypeArgumentList? qualifiedTypeIdent newArrayConstruction
661             )
662         )
663         -> template(t={$text}) "<t>"
664     ;
665
666 newArrayConstruction
667     :   arrayDeclaratorList arrayInitializer
668         -> array_construction_with_init(
669                 array_decls={$arrayDeclaratorList.st},
670                 initializer={$arrayInitializer.st})
671     |   (ex+=expression)+ adl=arrayDeclaratorList?
672         -> array_construction(exprs={$ex}, array_decls={$adl.st})
673     ;
674
675 arguments
676     :   ^(ARGUMENT_LIST (ex+=expression)*)
677         -> arguments(exprs={$ex})
678     ;
679
680 literal
681 @init {
682 $st = %{$start.getText()};
683 }
684     :   HEX_LITERAL
685     |   OCTAL_LITERAL
686     |   DECIMAL_LITERAL
687     |   FLOATING_POINT_LITERAL
688     |   CHARACTER_LITERAL
689     |   STRING_LITERAL
690     |   'true'
691     |   'false'
692     |   'null'
693     ;
694